flake: add public nixvimConfigurations flake-module

Can be used by end-users to define `perSystem.nixvimConfigurations`
using flake-parts.

flake-modules/default.nix

@@ -2,15 +2,22 @@
 {
   imports = [
     ./dev
+    ./public
     ./lib.nix
     ./legacy-packages.nix
+    ./nixvim-configurations.nix
     ./overlays.nix
     ./packages.nix
     ./templates.nix
     ./tests.nix
     ./wrappers.nix
+    inputs.flake-parts.flakeModules.flakeModules
   ];
 
+  flake.flakeModules = {
+    default = ./public;
+  };
+
   perSystem =
     { system, ... }:
     {

flake-modules/legacy-packages.nix

@@ -1,19 +1,15 @@
-{ helpers, ... }:
 {
   perSystem =
     {
+      config,
       makeNixvimWithModule,
-      system,
       ...
     }:
     {
       legacyPackages = rec {
         inherit makeNixvimWithModule;
         makeNixvim = module: makeNixvimWithModule { inherit module; };
-
-        nixvimConfiguration = helpers.modules.evalNixvim {
-          inherit system;
-        };
+        nixvimConfiguration = config.nixvimConfigurations.default;
       };
     };
 }

flake-modules/nixvim-configurations.nix

@@ -0,0 +1,14 @@
+{ helpers, ... }:
+{
+  flake.flakeModules = {
+    nixvimConfigurations = ./public/nixvimConfigurations.nix;
+  };
+
+  perSystem =
+    { system, ... }:
+    {
+      nixvimConfigurations.default = helpers.modules.evalNixvim {
+        inherit system;
+      };
+    };
+}

flake-modules/public/default.nix

@@ -0,0 +1,5 @@
+{
+  imports = [
+    ./nixvimConfigurations.nix
+  ];
+}

flake-modules/public/nixvimConfigurations.nix

@@ -0,0 +1,22 @@
+{ lib, flake-parts-lib, ... }:
+let
+  inherit (lib) types;
+  configurationType = lib.mkOptionType {
+    name = "configuration";
+    description = "configuration";
+    descriptionClass = "noun";
+    merge = lib.options.mergeOneOption;
+    check = x: x._type or null == "configuration";
+  };
+in
+flake-parts-lib.mkTransposedPerSystemModule {
+  name = "nixvimConfigurations";
+  option = lib.mkOption {
+    type = types.lazyAttrsOf configurationType;
+    default = { };
+    description = ''
+      An attribute set of Nixvim configurations.
+    '';
+  };
+  file = ./nixvimConfigurations.nix;
+}