Skip to content
New issue

Have a question about this project? Sign up for a free GitHub account to open an issue and contact its maintainers and the community.

Sign up for GitHub

By clicking “Sign up for GitHub”, you agree to our terms of service and privacy statement. We’ll occasionally send you account related emails.

Already on GitHub? Sign in to your account

Jump to bottom

CMake: use ccache and sccache for compiler caching #3947

Open
wants to merge 1 commit into
base: master
Choose a base branch
from
+64 −0
Open

CMake: use ccache and sccache for compiler caching #3947

Show file tree
Hide file tree
Changes from all commits
Commits
Show all changes
1 commit
Select commit
File filter

Filter by extension

Filter by extension
Conversations
Failed to load comments.
Loading
Jump to
Jump to file
Failed to load files.
Loading
Diff view
Diff view
63 changes: 63 additions & 0 deletions cmake/modules/CompilerCaching.cmake
View file
Open in desktop
Original file line number Diff line number Diff line change
@@ -0,0 +1,63 @@
# SPDX-FileCopyrightText: 2021 Tenacity Audio Editor contributors
#
# SPDX-License-Identifier: BSD-3-Clause
#[=======================================================================[.rst:
CompilerCaching
---------------

Search for sccache and ccache and use them for compiler caching for C & C++.
ccache is preferred if both are found, but the user can override this by
explicitly setting CCACHE=OFF to use sccache when both are installed.
#]=======================================================================]

# ccache does not support MSVC
if(NOT CMAKE_CXX_COMPILER_ID MATCHES "MSVC")
find_program(CCACHE_PROGRAM ccache)
mark_as_advanced(FORCE CCACHE_PROGRAM)
if("${CCACHE_PROGRAM}" STREQUAL "CCACHE_PROGRAM-NOTFOUND")
message(STATUS "Could NOT find ccache")
else()
message(STATUS "Found ccache: ${CCACHE_PROGRAM}")
option(CCACHE "Use ccache for compiler caching to speed up rebuilds." ON)
endif()
endif()

find_program(SCCACHE_PROGRAM sccache)
mark_as_advanced(FORCE SCCACHE_PROGRAM)
if("${SCCACHE_PROGRAM}" STREQUAL "SCCACHE_PROGRAM-NOTFOUND")
message(STATUS "Could NOT find sccache")
else()
message(STATUS "Found sccache: ${SCCACHE_PROGRAM}")
option(SCCACHE "Use sccache for compiler caching to speed up rebuilds." ON)
endif()

if(CCACHE)
message(STATUS "Using ccache for compiler caching to speed up rebuilds")
set(CMAKE_C_COMPILER_LAUNCHER "${CCACHE_PROGRAM}")
set(CMAKE_CXX_COMPILER_LAUNCHER "${CCACHE_PROGRAM}")
elseif(SCCACHE)
message(STATUS "Using sccache for compiler caching to speed up rebuilds")
set(CMAKE_C_COMPILER_LAUNCHER "${SCCACHE_PROGRAM}")
set(CMAKE_CXX_COMPILER_LAUNCHER "${SCCACHE_PROGRAM}")

# Instruct MSVC to generate symbolic debug information within object files for sccache
if(CMAKE_CXX_COMPILER_ID MATCHES "MSVC")
if(IS_MULTI_CONFIG)
foreach(CONFIG ${CMAKE_CONFIGURATION_TYPES})
string(TOUPPER "${CONFIG}" CONFIG)
string(REPLACE "/Zi" "/Z7" CMAKE_CXX_FLAGS_${CONFIG} "${CMAKE_CXX_FLAGS_${CONFIG}}")
string(REPLACE "/Zi" "/Z7" CMAKE_C_FLAGS_${CONFIG} "${CMAKE_C_FLAGS_${CONFIG}}")
endforeach()
else()
string(TOUPPER "${CMAKE_BUILD_TYPE}" CONFIG)
string(REPLACE "/Zi" "/Z7" CMAKE_CXX_FLAGS_${CONFIG} "${CMAKE_CXX_FLAGS_${CONFIG}}")
string(REPLACE "/Zi" "/Z7" CMAKE_C_FLAGS_${CONFIG} "${CMAKE_C_FLAGS_${CONFIG}}")
endif()
endif()
else()
if(CMAKE_CXX_COMPILER_ID MATCHES "MSVC")
message(STATUS "No compiler caching enabled. Install sccache to speed up rebuilds.")
else()
message(STATUS "No compiler caching enabled. Install ccache or sccache to speed up rebuilds.")
endif()
endif()
1 change: 1 addition & 0 deletions src/CMakeLists.txt
View file
Open in desktop
Original file line number Diff line number Diff line change
@@ -1,4 +1,5 @@
include(ECMEnableSanitizers)
include(CompilerCaching)

set(REQUIRED_QT_VERSION "6.5.0")

Expand Down
Loading