Make OMR an installable library

This is the start of a series of changes intended to make OMR more
easily consumable.  This change is prototyped using the standalone AVL
and omrsig libraries, although it should be trivial to add support for
other libraries. Some of the ways we hope OMR can be consumed are as
follows:

 1. Installable OMR.  By creating proper install targets for OMR using
    standard paths, it should be trivial to package OMR for any linux
    distribution.
2. CMake User Registry.  With a little bit of care, we can support the
   CMake User Registry.  This means that a user can build OMR anywhere
   on their system, and the build directory will be registered in
   `~/.cmake/packages/Omr`.  This will allow users to consume OMR using
   `find_package(Omr)`, without having to install OMR.
 3. As a subproject.  Having OMR as a subdirectory is the most common
    way to consume OMR.  We intend to continue to support and enhance
    this method of consumption.

We also hope to add versioning support to OMR in the future.

Signed-off-by: Andrew Young <[email protected]>

Author: youngar

CMakeLists.txt

@@ -52,21 +52,15 @@ endif()
 set(CMAKE_POSITION_INDEPENDENT_CODE ON)
 
 ###
-### Set up install path stuff
+### Set up install paths
 ###
-# Note the paths are a bit odd compared to standard gnu install paths
-# This is because we arent expecting to actually be installing globally
-# since we don't have a good story for installing OMR system-wide
-set(CMAKE_INSTALL_BINDIR ".")
-set(CMAKE_INSTALL_LIBDIR ".")
-set(OMR_INSTALL_PREFIX "${CMAKE_CURRENT_BINARY_DIR}" CACHE PATH "Root path where to install OMR")
-set(CMAKE_INSTALL_PREFIX "${OMR_INSTALL_PREFIX}")
 include(GNUInstallDirs)
-set(CMAKE_INSTALL_RPATH "\$ORIGIN")
-add_custom_target(omr_install_tooling
-	COMMAND ${CMAKE_COMMAND} --build tools --target preinstall
-	COMMAND ${CMAKE_COMMAND} -DCMAKE_INSTALL_COMPONENT=tooling -P "${CMAKE_BINARY_DIR}/cmake_install.cmake"
-)
+
+set(OMR_INSTALL_BIN_DIR ${CMAKE_INSTALL_BINDIR} CACHE PATH "Installation directory for executables")
+set(OMR_INSTALL_LIB_DIR ${CMAKE_INSTALL_LIBDIR} CACHE PATH "Installation directory for libraries")
+set(OMR_INSTALL_ARCHIVE_DIR ${CMAKE_INSTALL_LIBDIR} CACHE PATH "Installation directory for libraries")
+set(OMR_INSTALL_INC_DIR ${CMAKE_INSTALL_INCLUDEDIR} CACHE PATH "Installation directory for headers")
+set(OMR_INSTALL_DATA_DIR ${CMAKE_INSTALL_DATADIR}/${PROJECT_NAME} CACHE PATH "Installation directory for data files")
 
 ###
 ### Versions and stuff
@@ -161,3 +155,26 @@ endif(OMR_JITBUILDER)
 if(OMR_FVTEST)
 	add_subdirectory(fvtest)
 endif()
+
+
+# Export CMake Module
+
+# This file must be copied into the build directory so that
+# the cmake user package registry functions properly
+configure_file(OmrConfig.cmake
+  "${CMAKE_CURRENT_BINARY_DIR}/OmrConfig.cmake"
+  COPYONLY
+)
+
+export(EXPORT OmrTargets FILE OmrTargets.cmake)
+
+install(EXPORT OmrTargets
+  FILE OmrTargets.cmake
+  DESTINATION ${OMR_INSTALL_LIB_DIR}/cmake/Omr
+)
+
+install(FILES "${CMAKE_CURRENT_BINARY_DIR}/OmrConfig.cmake"
+	DESTINATION ${OMR_INSTALL_LIB_DIR}/cmake/Omr
+)
+
+export(PACKAGE Omr)

OmrConfig.cmake

@@ -0,0 +1 @@
+include("${CMAKE_CURRENT_LIST_DIR}/OmrTargets.cmake")

omrsigcompat/CMakeLists.txt

@@ -116,7 +116,12 @@ endif()
 #ifneq (,$(findstring osx,$(OMR_HOST_OS)))
 	#MODULE_SHARED_LIBS += pthread
 #endif
-install(TARGETS omrsig
-	LIBRARY DESTINATION ${CMAKE_INSTALL_LIBDIR}
-	RUNTIME DESTINATION ${CMAKE_INSTALL_LIBDIR}
+
+install(
+	TARGETS omrsig
+	EXPORT OmrTargets
+	PUBLIC_HEADER DESTINATION ${OMR_INSTALL_INC_DIR}/
+	ARCHIVE DESTINATION ${OMR_INSTALL_ARCHIVE_DIR}/
+	LIBRARY DESTINATION ${OMR_INSTALL_LIB_DIR}/
 )
+

util/avl/CMakeLists.txt

@@ -20,15 +20,26 @@
 # SPDX-License-Identifier: EPL-2.0 OR Apache-2.0 OR GPL-2.0 WITH Classpath-exception-2.0 OR LicenseRef-GPL-2.0 WITH Assembly-exception
 ###############################################################################
 
-include_directories(${CMAKE_CURRENT_BINARY_DIR})
-
 add_tracegen(avl.tdf)
 
+set(j9avl_public_headers
+	"${omr_SOURCE_DIR}/include_core/avl_api.h"
+)
+
 add_library(j9avl STATIC
 	avlsup.c
 	ut_avl.c
 )
 
+target_include_directories(j9avl
+	PUBLIC
+		$<BUILD_INTERFACE:${OMR_SOURCE_DIR}/include_core>
+		$<INSTALL_INTERFACE:${OMR_INSTALL_INC_DIR}>
+	PRIVATE
+		.
+		${CMAKE_CURRENT_BINARY_DIR}
+)
+
 if(OMR_WARNINGS_AS_ERRORS)
 	target_compile_options(j9avl PRIVATE ${OMR_WARNING_AS_ERROR_FLAG})
 endif()
@@ -37,9 +48,14 @@ if(OMR_ENHANCED_WARNINGS)
 	target_compile_options(j9avl PRIVATE ${OMR_ENHANCED_WARNING_FLAG})
 endif()
 
-target_include_directories(j9avl
-	PUBLIC
-		.
-)
-
 set_property(TARGET j9avl PROPERTY FOLDER util)
+
+set_target_properties(j9avl PROPERTIES PUBLIC_HEADER ${j9avl_public_headers})
+
+install(
+	TARGETS j9avl
+	EXPORT OmrTargets
+	PUBLIC_HEADER DESTINATION ${OMR_INSTALL_INC_DIR}/
+	ARCHIVE DESTINATION ${OMR_INSTALL_ARCHIVE_DIR}/
+	LIBRARY DESTINATION ${OMR_INSTALL_LIB_DIR}/
+)