NetDiscovery Hikvision device

[b-keller]

Documentation & bug reporting acknowledgment

Yes, I read it

Describe your problem

Hi,

have some trouble to discover and import some hikvision devices with glpi-agent (1.10-1 on Rocky Linux 8.10)

I make a snmpwalk (see below)
Hikvision.txt

[root@xxxx ~]# glpi-netdiscovery --host xxx.xxx.xxx.225 --community MyCommunity --v2c --debug --debug --control -i -s /root/Glpi/Inventory
netdiscovery XMLs will be saved in: /root/Glpi/Inventory/netdiscovery
netinventory XMLs will be saved in: /root/Glpi/Inventory/netinventory
====
[debug2] /etc/glpi-agent/toolbox.yaml configuration not found
[debug] initializing job 1
[debug] initializing block xxx.xxx.xxx.225-xxx.xxx.xxx.225
[debug] Current netdiscovery run expiration timeout: 15 minutes
[debug] using 1 netdiscovery worker
[debug] starting job 1 with 1 ip to scan using 1 worker
[debug] #1, scanning xxx.xxx.xxx.225
[debug] #1, - scanning xxx.xxx.xxx.225 with SNMP, credentials 1: success
[debug] #1, - scanning xxx.xxx.xxx.225 with netbios: no result
[debug] #1, - scanning xxx.xxx.xxx.225 with echo ping: success
[debug2] #1, executing arp -a xxx.xxx.xxx.225
[debug] #1, - scanning xxx.xxx.xxx.225 in arp table: no result
[info] #1, Netdiscovery result for xxx.xxx.xxx.225 saved in /root/Glpi/Inventory/netdiscovery/xxx.xxx.xxx.255.xml
[debug] #1, Current netinventory run expiration timeout: 1.0 hour
[debug] #1, using 1 netinventory worker
[debug] #1, full snmp scan of xxx.xxx.xxx.225 with credentials 1
[info] #1, Netinventory result for xxx.xxx.xxx.225 saved in /root/Glpi/Inventory/netinventory/xxx.xxx.xxx.255.xml
[debug] #1, Netinventory worker terminated
[debug] #1, #1, worker termination
[debug] #1, Netdiscovery worker terminated

The result file is like this

<?xml version="1.0" encoding="UTF-8"?>
<REQUEST>
  <CONTENT>
    <DEVICE>
      <AUTHSNMP>1</AUTHSNMP>
      <DNSHOSTNAME>xxx.xxx.xxx.225</DNSHOSTNAME>
      <IP>xxx.xxx.xxx.225</IP>
    </DEVICE>
    <MODULEVERSION>6.3</MODULEVERSION>
    <PROCESSNUMBER>1</PROCESSNUMBER>
  </CONTENT>
  <DEVICEID>foo</DEVICEID>
  <QUERY>NETDISCOVERY</QUERY>
</REQUEST>

So I made a new MibSupport module Hikvision.pm like a made before for Hwg devices fusioninventory/fusioninventory-agent#824

Same situation for this kind of device which have no serial number exposed through snmp

package GLPI::Agent::SNMP::MibSupport::Hikvision;

use strict;
use warnings;

use parent 'GLPI::Agent::SNMP::MibSupportTemplate';

use GLPI::Agent::Tools;
use GLPI::Agent::Tools::SNMP;

# See Hikvision-MIB

use constant hikvision  => '.1.3.6.1.4.1.39165';
use constant hikvisionModel   => hikvision . '1.1';
use constant hikvisionMac  => hikvision . '1.4';

our $mibSupport = [
    {
        name    => "hikvision",
        sysobjectid => getRegexpOidMatch(hikvision)
    }
];

sub getType {
    return 'NETWORKING';
}

sub getManufacturer {
    return 'Hikvision';
}

sub getSerial {
    my ($self) = @_;

    my $serial = getCanonicalMacAddress(getCanonicalString($self->get(hikvisionMac)));
    $serial =~ s/-//g;

    return $serial;
}

sub getMacAddress {
    my ($self) = @_;

    return getCanonicalMacAddress(getCanonicalString($self->get(hikvisionMac)));
}

sub getModel {
    my ($self) = @_;

    return $self->get(hikvisionModel);
}

1;

__END__

=head1 NAME

GLPI::Agent::SNMP::MibSupport::Hikvision - Inventory module for Hikvision

=head1 DESCRIPTION

This module enhances Hikvision devices support.

But discovery result is exactly the same... nothing

can you tell me what's wrong ?

Thx

[g-bougard]

Hi @b-keller

your snmpwalk only reports private parts, so I can't confirm the our $mibSupport definition is correct: there sysobjectid means the regexp have to match on .1.3.6.1.2.1.1.2.0 OID and I don't see it in your walk extract.

In your code, I would eventually change getMacAddress() method to this one as - is not recognize in mac address:

sub getMacAddress {
    my ($self) = @_;

    my $mac = getCanonicalString($self->get(hikvisionMac))
        or return;
    $mac =~ s/-/:/g;

    return getCanonicalMacAddress($mac);
}

That said, I just saw one little mistake in your constant definition... one dot is missing at the beginning of the string part and this should be this:

use constant hikvisionModel   => hikvision . '.1.1';
use constant hikvisionMac  => hikvision . '.1.4';

[b-keller]

@g-bougard

The snmpwalk was run like this

snmpwalk -v 2c -c MyCommunity-t 15 -Cc -On -Ox xxx.xxx.xxx.225 .1 > Hikvision.txt

if I run like that

snmpwalk -v 2c -c MyCommunity -t 15 -Cc -On -Ox xxx.xxx.xxx.225 .1.3.6.1.2.1.1.9.1.2
.1.3.6.1.2.1.1.9.1.2 = No Such Object available on this agent at this OID

so i must add entry to sysobject.ids ?

[g-bougard]

Did you test my constants fix ? This should be the essential reason of your not working module.

But if snmpwalk only report private oids... that's a bigger deal. Try eventually to set our $mibSupport like this:

our $mibSupport = [
    {
        name    => "hikvision",
        sysobjectid => getRegexpOidMatch(hikvision)
    },{
        name    => "hikvision-model",
        privateoid => hikvisionModel
    },
];

But you may also want to check some security set in your device could prevent standard oid to be exported for the used community.

[b-keller]

Yes I made all constants fix

package GLPI::Agent::SNMP::MibSupport::Hikvision;

use strict;
use warnings;

use parent 'GLPI::Agent::SNMP::MibSupportTemplate';

use GLPI::Agent::Tools;
use GLPI::Agent::Tools::SNMP;

# See Hikvision-MIB

use constant hikvision  => '.1.3.6.1.4.1.39165';
use constant hikvisionModel   => hikvision . '.1.1';
use constant hikvisionMac  => hikvision . '.1.4';

our $mibSupport = [
    {
        name    => "hikvision",
        sysobjectid => getRegexpOidMatch(hikvision)
    },{
        name    => "hikvision-model",
        privateoid => hikvisionModel
    },
];

sub getType {
    return 'NETWORKING';
}

sub getManufacturer {
    return 'Hikvision';
}

sub getSerial {
    my ($self) = @_;

    my $serial = getCanonicalMacAddress(getCanonicalString($self->get(hikvisionMac)));
    $serial =~ s/-//g;

    return $serial;
}

sub getMacAddress {
    my ($self) = @_;

    my $mac = getCanonicalString($self->get(hikvisionMac))
        or return;
    $mac =~ s/-/:/g;

    return getCanonicalMacAddress($mac);
}

sub getModel {
    my ($self) = @_;

    return $self->get(hikvisionModel);
}

1;

__END__

=head1 NAME

GLPI::Agent::SNMP::MibSupport::Hikvision - Inventory module for Hikvision

=head1 DESCRIPTION

This module enhances Hikvision devices support.

I double check snmp security setting, all is correct
But, nothing more...

So, the root problem is sysobjectID not match nothing in our $mibSupport ?

[g-bougard]

About getSerial() method, you should probably change it to:

sub getSerial {
    my ($self) = @_;

    my $serial = getCanonicalString($self->get(hikvisionMac))
        or return;
    $serial =~ s/-//g;

    return $serial;
}

But it still should work as is.

Can you share the glpi-netdiscovery command start output with your updated module ? And share the generated XML files ?

[g-bougard]

Last point I remember now, you may also need to implement getSnmpHostname() method like in that case:

glpi-agent/lib/GLPI/Agent/SNMP/MibSupport/Multitech.pm

Line 37 in 14f0c68

sub getSnmpHostname {

[g-bougard]

You should probably also contact Hikvision support to know why their device may not report standard OIDs.

[b-keller]

I update Hikvision.pm code with your recommandations getSerial() and getSnmpHostname()

package GLPI::Agent::SNMP::MibSupport::Hikvision;

use strict;
use warnings;

use parent 'GLPI::Agent::SNMP::MibSupportTemplate';

use GLPI::Agent::Tools;
use GLPI::Agent::Tools::SNMP;

# See Hikvision-MIB

use constant hikvision  => '.1.3.6.1.4.1.39165';
use constant hikvisionModel   => hikvision . '.1.1';
use constant hikvisionMac  => hikvision . '.1.4';

our $mibSupport = [
    {
        name    => "hikvision",
        sysobjectid => getRegexpOidMatch(hikvision)
    },{
        name    => "hikvision-model",
        privateoid => hikvisionModel
    },
];

sub getType {
    return 'NETWORKING';
}

sub getManufacturer {
    return 'Hikvision';
}

sub getSerial {
    my ($self) = @_;

    my $serial = getCanonicalString($self->get(hikvisionMac))
        or return;
    $serial =~ s/-//g;

    return $serial;
}

sub getMacAddress {
    my ($self) = @_;

    my $mac = getCanonicalString($self->get(hikvisionMac))
        or return;
    $mac =~ s/-/:/g;

    return getCanonicalMacAddress($mac);
}

sub getSnmpHostname {
    my ($self) = @_;

    my $serial = $self->getSerial()
        or return;

    my $device = $self->device
        or return;

    return $device->{MODEL}.'_'.$serial;
}

sub getModel {
    my ($self) = @_;

    return $self->get(hikvisionModel);
}

1;

__END__

=head1 NAME

GLPI::Agent::SNMP::MibSupport::Hikvision - Inventory module for Hikvision

=head1 DESCRIPTION

This module enhances Hikvision devices support.

and glpi-netdiscovery command start output

[root@xxxx ~]# glpi-netdiscovery --host xxx.xxx.xxx.225 --community MyCommunity --v2c --debug --debug
[debug2] /etc/glpi-agent/toolbox.yaml configuration not found
[debug] initializing job 1
[debug] initializing block xxx.xxx.xxx.225-xxx.xxx.xxx.225
[debug] Current netdiscovery run expiration timeout: few minutes
[debug] using 1 netdiscovery worker
[debug] starting job 1 with 1 ip to scan using 1 worker
[debug] #1, scanning xxx.xxx.xxx.225
[debug] #1, - scanning xxx.xxx.xxx.225 with SNMP, credentials 1: success
[debug] #1, - scanning xxx.xxx.xxx.225 with netbios: no result
[debug] #1, - scanning xxx.xxx.xxx.225 with echo ping: success
[debug2] #1, executing arp -a xxx.xxx.xxx.225
[debug] #1, - scanning xxx.xxx.xxx.225 in arp table: no result
<?xml version="1.0" encoding="UTF-8"?>
<REQUEST>
  <CONTENT>
    <DEVICE>
      <AUTHSNMP>1</AUTHSNMP>
      <DNSHOSTNAME>xxx.xxx.xxx.225</DNSHOSTNAME>
      <IP>xxx.xxx.xxx.225</IP>
    </DEVICE>
    <MODULEVERSION>6.3</MODULEVERSION>
    <PROCESSNUMBER>1</PROCESSNUMBER>
  </CONTENT>
  <DEVICEID>foo</DEVICEID>
  <QUERY>NETDISCOVERY</QUERY>
</REQUEST>
[debug] #1, #1, worker termination
[debug] #1, Netdiscovery worker terminated

[b-keller]

So, I must update constants like this for have an output

use constant hikvisionModel   => hikvision . '.1.1.0';
use constant hikvisionMac  => hikvision . '.1.4.0';

[root@xxxx ~]# glpi-netdiscovery --host xxx.xxx.xxx.225 --community SiEEEnNetWork --v2c --debug --debug
[debug2] /etc/glpi-agent/toolbox.yaml configuration not found
[debug] initializing job 1
[debug] initializing block xxx.xxx.xxx.225-xxx.xxx.xxx.225
[debug] Current netdiscovery run expiration timeout: few minutes
[debug] using 1 netdiscovery worker
[debug] starting job 1 with 1 ip to scan using 1 worker
[debug] #1, scanning xxx.xxx.xxx.225
[debug] #1, PrivateOID match: hikvision-model mib support enabled
[debug] #1, - scanning xxx.xxx.xxx.225 with SNMP, credentials 1: success
[debug] #1, - scanning xxx.xxx.xxx.225 with netbios: no result
[debug] #1, - scanning xxx.xxx.xxx.225 with echo ping: success
[debug2] #1, executing arp -a xxx.xxx.xxx.225
[debug] #1, - scanning xxx.xxx.xxx.225 in arp table: no result
<?xml version="1.0" encoding="UTF-8"?>
<REQUEST>
  <CONTENT>
    <DEVICE>
      <AUTHSNMP>1</AUTHSNMP>
      <DNSHOSTNAME>xxx.xxx.xxx.225</DNSHOSTNAME>
      <IP>xxx.xxx.xxx.225</IP>
      <MAC>e8:a0:ed:ef:75:46</MAC>
      <MANUFACTURER>Hikvision</MANUFACTURER>
      <MODEL>PTZ-N2404I-DE3</MODEL>
      <SERIAL>e8a0edef7546</SERIAL>
      <SNMPHOSTNAME>PTZ-N2404I-DE3_e8a0edef7546</SNMPHOSTNAME>
      <TYPE>NETWORKING</TYPE>
    </DEVICE>
    <MODULEVERSION>6.3</MODULEVERSION>
    <PROCESSNUMBER>1</PROCESSNUMBER>
  </CONTENT>
  <DEVICEID>foo</DEVICEID>
  <QUERY>NETDISCOVERY</QUERY>
</REQUEST>
[debug] #1, #1, worker termination
[debug] #1, Netdiscovery worker terminated

[g-bougard]

Nice.

I leave you create a PR if you want it integrated.

[b-keller]

I made #746

thx