RLX: cgguess etternamn/fornamn

apertium · Oct 6, 2022 · 6821199 · 6821199
1 parent 90a85f6
commit 6821199
Showing 1 changed file with 73 additions and 0 deletions.
diff --git a/apertium-nob.nob.rlx b/apertium-nob.nob.rlx
@@ -1316,6 +1316,79 @@ APPEND:np-guess-nom ("$1"v np org cgguess)     TARGET ("<(\\p{Lu}{2}[\\p{L}\\p{N
         (1 np OR ukjent + storbokstav);
 "<Mc>"i REMOVE:unlikely np;
 
+# Arabiske etternamn på al-/Al- eller bin-/Bin-, genitiv: "Al-Amiris familie", "al-Nahyans familie"
+APPEND:np-guess-nom ("$1"v np cog cgguess gen) TARGET ("<((al|Al|bin|Bin)-\\p{Lu}\\p{Ll}+)(s|'|’)>"r) IF
+        (0 ukjent + forbokstavord-blanda)
+        (-1 np + ant OR np + cog)
+        (1 n + ind OR adj + def)
+        ;
+# Arabiske etternamn på al-/Al- eller bin-/Bin-: "(Jim) Al-Khalili", "(Walid) al-Kubaisi", "Mohammed bin Zayed"
+APPEND:np-guess-nom ("$1"v np cog cgguess)     TARGET ("<((al|Al|bin|Bin)-\\p{Lu}\\p{Ll}+)>"r) IF
+        (0 ukjent + forbokstavord-blanda)
+        (-1 np + ant OR np + cog)
+        ;
+# Arabiske namn på al-/Al- eller bin-/Bin-, genitiv: "Al-Qaidas soldater", "al-Nahyans tale"
+APPEND:np-guess-nom ("$1"v np cgguess gen) TARGET ("<((al|Al|bin|Bin)-\\p{Lu}\\p{Ll}+)(s|'|’)>"r) IF
+        (0 ukjent + forbokstavord-blanda)
+        (1 n + ind OR adj + def)
+        ;
+# Arabiske namn på al-/Al- eller bin-/Bin- utan kontekst: "al-Nusra", "Al-Amiri"
+APPEND:np-guess-nom ("$1"v np cgguess)     TARGET ("<((al|Al|bin|Bin)-\\p{Lu}\\p{Ll}+)>"r) IF
+        (0 ukjent + forbokstavord-blanda)
+        ;
+# Arabiske namn etter al/Al eller bin/Bin, genitiv: "al Nahyans familie", "Al Qaidas soldater", også "Al Gores kampanje"
+APPEND:np-guess-nom ("$1"v np cog cgguess gen) TARGET ("<(\\p{Lu}\\p{Ll}+)(s|'|’)>"r) IF
+        (0 ukjent + titlecase)
+        (-1 ("al") + np + attr OR ("bin") + np + attr)
+        (-2 np + ant OR np + cog)
+        (1 n + ind OR adj + def)
+        ;
+# Arabiske namn  al/Al eller bin/Bin: "al Noor", "Al Amiri", "al Nusra", "bin Khaled"
+APPEND:np-guess-nom ("$1"v np cog cgguess)     TARGET ("<(\\p{Lu}\\p{Ll}+)>"r) IF
+        (0 ukjent + titlecase)
+        (-1 ("al") + np + attr OR ("bin") + np + attr)
+        (-2 np + ant OR np + cog)
+        ;
+# Arabiske namn etter al/Al eller bin/Bin, genitiv: "al Nahyans familie", "Al Qaidas soldater", også "Al Gores kampanje"
+APPEND:np-guess-nom ("$1"v np cgguess gen) TARGET ("<(\\p{Lu}\\p{Ll}+)(s|'|’)>"r) IF
+        (0 ukjent + titlecase)
+        (-1 ("al") + np + attr OR ("bin") + np + attr)
+        (1 n + ind OR adj + def)
+        ;
+# Arabiske namn  al/Al eller bin/Bin: "al Noor", "Al Amiri", "al Nusra", "bin Khaled"
+APPEND:np-guess-nom ("$1"v np cgguess)     TARGET ("<(\\p{Lu}\\p{Ll}+)>"r) IF
+        (0 ukjent + titlecase)
+        (-1 ("al") + np + attr OR ("bin") + np + attr)
+        ;
+
+# Etternamn med samanskrive attributt, genitiv: "DeNiros film", "DiCaprios rolle"
+APPEND:np-guess-nom ("$1"v np cog cgguess gen) TARGET ("<((De|Di|Mac|Mc)\\p{Lu}\\p{Ll}+)(s|'|’)>"r) IF
+        (0 ukjent + forbokstavord-blanda-genitiv)
+        (1 n + ind OR adj + def)
+        ;
+# Etternamn med samanskrive attributt, genitiv: "DeNiro", "DiCaprio"
+APPEND:np-guess-nom ("$1"v np cog cgguess)     TARGET ("<((De|Di|Mac|Mc)\\p{Lu}\\p{Ll}+)>"r) IF
+        (0 ukjent + forbokstavord-blanda)
+        ;
+
+# Etternamn etter fornamn, etternanm, initial eller attributt, genitiv: "De Biasis' familie", "von der Leyens tale", "Mac Allisters skåring", "H.G. Wells' mesterverk"
+APPEND:np-guess-nom ("$1"v np cog cgguess gen) TARGET ("<(\\p{Lu}\\p{Ll}+(-\\p{Lu}\\p{Ll}+)?)(s|'|’)>"r) IF
+        (0 ukjent + forbokstavord-blanda)
+        (-1 np + attr OR np + cog OR np + ant OR np + init)
+        (1 n + ind OR adj + def)
+        ;
+# Etternamn etter fornamn, etternamn, initial eller attributt: "Roger Valhmmer", "Garcia Vilsanches", "Di Maio", "van den Berg", "W.H. Auden", "Norbert Walter-Borjans"
+APPEND:np-guess-nom ("$1"v np cog cgguess)     TARGET ("<(\\p{Lu}\\p{Ll}+(-\\p{Lu}\\p{Ll}+)?)>"r) IF
+        (0 ukjent + forbokstavord-blanda)
+        (-1 np + attr OR np + cog OR np + ant OR np + init)
+        ;
+
+# Fornamn før fornamn, etternanm, initial eller attributt (aldri genitiv): "Aretha Franklin", "Garcia Vilsanches", "Tilmann von Soest", "Esteban Garcia Vilsanches", "Terrence K. Williams"
+APPEND:np-guess-nom ("$1"v np ant cgguess)     TARGET ("<(\\p{Lu}\\p{Ll}+(-\\p{Lu}\\p{Ll}+)?)>"r) IF
+        (0 ukjent + forbokstavord-blanda)
+        (1 np + attr OR np + cog OR np + ant OR np + init)
+        ;
+
 # sec 1
 CONSTRAINTS