-
Notifications
You must be signed in to change notification settings - Fork 0
/
CMakeLists.txt
125 lines (101 loc) · 3.53 KB
/
CMakeLists.txt
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
# CMake 3.12.0 CPack uses the project version instead of requiring a variable to be set
cmake_minimum_required(VERSION 3.12.0)
project(GSL LANGUAGES CXX VERSION 0.0.1)
list(APPEND CMAKE_MODULE_PATH "${CMAKE_CURRENT_LIST_DIR}/CMake")
include(GNUInstallDirs)
include(CMakePackageConfigHelpers)
include(CTest)
option(GSL_CMAKE_CXX_CLANG_TIDY OFF)
set_property(GLOBAL PROPERTY USE_FOLDERS ON)
if(${GSL_CMAKE_CXX_CLANG_TIDY} AND ${BUILD_TESTING})
find_program(GSL_CLANG_TIDY_FIND_RESULT "clang-tidy")
if(EXISTS ${GSL_CLANG_TIDY_FIND_RESULT})
message(STATUS "Enabling clang-tidy")
set(CMAKE_CXX_CLANG_TIDY "${GSL_CLANG_TIDY_FIND_RESULT};-checks=-*")
set(CMAKE_CXX_CLANG_TIDY "${CMAKE_CXX_CLANG_TIDY},bugprone-*")
set(CMAKE_CXX_CLANG_TIDY "${CMAKE_CXX_CLANG_TIDY},cppcoreguidelines-*")
set(CMAKE_CXX_CLANG_TIDY "${CMAKE_CXX_CLANG_TIDY},clang-analyzer-*")
set(CMAKE_CXX_CLANG_TIDY "${CMAKE_CXX_CLANG_TIDY},misc-*")
set(CMAKE_CXX_CLANG_TIDY "${CMAKE_CXX_CLANG_TIDY},modernize-*")
set(CMAKE_CXX_CLANG_TIDY "${CMAKE_CXX_CLANG_TIDY},performance-*")
set(CMAKE_CXX_CLANG_TIDY "${CMAKE_CXX_CLANG_TIDY},portability-*")
set(CMAKE_CXX_CLANG_TIDY "${CMAKE_CXX_CLANG_TIDY},readability-*")
else()
message(STATUS "clang-tidy requested, but no clang-tidy installation found")
endif()
endif()
add_library(gsl INTERFACE)
target_compile_features(gsl INTERFACE cxx_std_17)
target_include_directories(
gsl
INTERFACE
$<BUILD_INTERFACE:${CMAKE_CURRENT_LIST_DIR}/include>
$<INSTALL_INTERFACE:${CMAKE_INSTALL_INCLUDEDIR}/GSL/include>
)
if(BUILD_TESTING)
find_package(Catch2 REQUIRED)
message(STATUS "Found Catch2, creating test target")
add_executable(test_span ${CMAKE_CURRENT_LIST_DIR}/test/test_span.cpp)
target_link_libraries(test_span gsl)
target_link_libraries(test_span Catch2::Catch2)
add_test(
NAME
test_span
COMMAND
test_span --out ${CMAKE_CURRENT_LIST_DIR}/test/test_span.catch2log
)
endif()
################
# Installation #
################
add_library(GSL::gsl ALIAS gsl)
set(GSL_CMAKE_CONFIG_DESTINATION "${CMAKE_INSTALL_LIBDIR}/cmake/GSL")
configure_package_config_file(
${CMAKE_CURRENT_LIST_DIR}/CMake/GSLConfig.cmake.in
${CMAKE_CURRENT_BINARY_DIR}/GSLConfig.cmake
INSTALL_DESTINATION
${GSL_CMAKE_CONFIG_DESTINATION}
)
install(TARGETS gsl EXPORT GSLTargets DESTINATION ${CMAKE_INSTALL_LIBDIR})
install(
EXPORT
GSLTargets
NAMESPACE
GSL::
DESTINATION
${GSL_CMAKE_CONFIG_DESTINATION}
)
set(GSL_CMAKE_SIZEOF_VOID_P ${CMAKE_SIZEOF_VOID_P})
set(CMAKE_SIZEOF_VOID_P "")
write_basic_package_version_file(
"${CMAKE_CURRENT_BINARY_DIR}/GSLConfigVersion.cmake"
COMPATIBILITY
SameMajorVersion
)
set(CMAKE_SIZEOF_VOID_P ${GSL_CMAKE_SIZEOF_VOID_P})
install(DIRECTORY "include/" DESTINATION "${CMAKE_INSTALL_INCLUDEDIR}/GSL")
install(
FILES
"${CMAKE_CURRENT_BINARY_DIR}/GSLConfig.cmake"
"${CMAKE_CURRENT_BINARY_DIR}/GSLConfigVersion.cmake"
DESTINATION
${GSL_CMAKE_CONFIG_DESTINATION}
)
set(
PKGCONFIG_INSTALL_DIR
${CMAKE_INSTALL_DATAROOTDIR}/pkgconfig
CACHE PATH "Path to installed gsl.pc"
)
configure_file(
${CMAKE_CURRENT_SOURCE_DIR}/CMake/gsl.pc.in
${CMAKE_CURRENT_BINARY_DIR}/gsl.pc
@ONLY
)
install(
FILES
"${CMAKE_CURRENT_BINARY_DIR}/gsl.pc"
DESTINATION
${PKGCONFIG_INSTALL_DIR}
)
set(CPACK_PACKAGE_CONTACT "https://github.com/zhu48/GSL/")
include(CPack)