-
-
Notifications
You must be signed in to change notification settings - Fork 85
/
telega-match.el
1337 lines (1178 loc) · 49.7 KB
/
telega-match.el
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
833
834
835
836
837
838
839
840
841
842
843
844
845
846
847
848
849
850
851
852
853
854
855
856
857
858
859
860
861
862
863
864
865
866
867
868
869
870
871
872
873
874
875
876
877
878
879
880
881
882
883
884
885
886
887
888
889
890
891
892
893
894
895
896
897
898
899
900
901
902
903
904
905
906
907
908
909
910
911
912
913
914
915
916
917
918
919
920
921
922
923
924
925
926
927
928
929
930
931
932
933
934
935
936
937
938
939
940
941
942
943
944
945
946
947
948
949
950
951
952
953
954
955
956
957
958
959
960
961
962
963
964
965
966
967
968
969
970
971
972
973
974
975
976
977
978
979
980
981
982
983
984
985
986
987
988
989
990
991
992
993
994
995
996
997
998
999
1000
;;; telega-match.el --- Telega Matching Expressions -*- lexical-binding: t -*-
;; Copyright (C) 2022 by Zajcev Evgeny.
;; Author: Zajcev Evgeny <[email protected]>
;; Created: Mon Feb 14 13:49:33 2022
;; Keywords:
;; telega is free software: you can redistribute it and/or modify
;; it under the terms of the GNU General Public License as published by
;; the Free Software Foundation, either version 3 of the License, or
;; (at your option) any later version.
;; telega is distributed in the hope that it will be useful,
;; but WITHOUT ANY WARRANTY; without even the implied warranty of
;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
;; GNU General Public License for more details.
;; You should have received a copy of the GNU General Public License
;; along with telega. If not, see <http://www.gnu.org/licenses/>.
;;; ellit-org: commentary
;;
;; Telega Match Expression (temex in short) is a verbal expression to
;; match TDLib objects. Temex uses S-exp notation similar to ~rx~
;; package for regexps.
;;
;; Primitive Temex is a named predicate returning non-nil if matches
;; some object. Primitive Temexes can be combined using ~and~, ~or~
;; or ~not~ temexes, so temex is a logical combination of other
;; temexes down to Primitive Temexes.
;;
;; ~telega-match-gen-predicate~ can be used to generate predicate
;; functions out of temex.
;;
;; Chat Temex examples:
;; - ~(return t)~ ::
;; Matches all chats.
;;
;; - ~(or saved-messages (type channel bot))~ ::
;; Matches bots/channels chats or "Saved Messages" chat.
;;
;; - ~(and unmuted (unread 10) (mention 1))~ ::
;; Matches unmuted chats with at least 10 unread messages and at
;; least one message with unread mention.
;;
;; Message Temex examples:
;; - ~(sender me)~ ::
;; Matches all messages sent by me.
;;
;; - ~(or (prop :contains_unread_mention) unread-reactions)~ ::
;; Matches messages containing unread mention or reaction.
;;
;; - ~(and (chat (type channel)) (type text) (contains "\shello\s"))~ ::
;; Matches channel's text messages containing "hello" word.
;;; Code:
(require 'telega-chat)
(require 'telega-msg)
(require 'telega-user)
(require 'telega-info)
(defvar telega-temex-remap-list nil
"List of temex remapping.
Each element is a list in form: (PREFIX TEMEX . REMAP-TEMEX)
Bind it to temporary remap primitive matchers.
Can be used to temporarily change temex behaviour.")
(defvar telega-temex-match-prefix nil
"Symbol to use as temex prefix.
Prefix is an interned symbol, such as `chat', `msg', `user' or `sender'.")
(defmacro define-telega-matcher (prefix name args &rest body)
"Define new Primitive Matcher with NAME.
ARGS specifies additional arguments to the predicate."
(declare (doc-string 4) (indent 3))
(let ((fsym (intern (format "telega-match--primitive-%s%S"
(if prefix
(concat (symbol-name prefix) "-")
"")
name))))
`(progn
(defun ,fsym ,args ,@body)
(setf (alist-get (quote ,name) (get (quote ,prefix) :temex-definitions))
(function ,fsym)))))
(defsubst telega-match--temex-remap (prefix temex)
(cddr (seq-find (lambda (re)
(and (eq (nth 0 re) prefix)
(equal (nth 1 re) temex)))
telega-temex-remap-list)))
(defsubst telega-match--temex-function (prefix temex)
"Return predicate function definition for the primitive TEMEX."
(or (cdr (assq temex (get prefix :temex-definitions)))
(when prefix
;; Try non-prefix matchers
(cdr (assq temex (get nil :temex-definitions))))
(error "Primitive temex `%s%S' is undefined.
Use `define-telega-matcher' to define new matchers."
(if prefix
(concat (symbol-name prefix) "-")
"")
temex)))
(defun telega-match-p (object temex)
"Return non-nil if TEMEX matches OBJECT.
Takes `telega-temex-remap-alist' into account."
(when temex
;; Try whole TEMEX remapping
(setq temex (or (telega-match--temex-remap telega-temex-match-prefix temex)
temex))
(let ((temex-name temex)
(temex-args nil))
(when (consp temex)
(setq temex-name (car temex)
temex-args (cdr temex)))
(unless (symbolp temex-name)
(error "telega: Invalid Matcher: %S" temex))
(if-let ((temex-alias (telega-match--temex-remap
telega-temex-match-prefix temex-name)))
;; Try TEMEX remapping by name only
(let ((telega-temex-remap-list nil))
(telega-match-p object temex-alias))
(apply (telega-match--temex-function
telega-temex-match-prefix temex-name)
object temex-args)))))
;;; Logical operations
;;; ellit-org: temex
;; - (return ~RET~) ::
;; {{{temexdoc(nil, return, 2)}}}
(define-telega-matcher nil return (_object ret)
"Matches if RET is non-nil and return RET as a result."
ret)
;;; ellit-org: temex
;; - (eval ~SEXP~) ::
;; {{{temexdoc(nil, eval, 2)}}}
(define-telega-matcher nil eval (_object sexp)
"Matches if SEXP evaluates to non-nil, return result of evaluation."
(eval sexp))
;;; ellit-org: temex
;; - (or ~TEMEX-LIST~...) ::
;; {{{temexdoc(nil, or, 2)}}}
(define-telega-matcher nil or (obj &rest temex-list)
"Matches if any matcher in the TEMEX-LIST matches."
(let ((result nil))
(while temex-list
(when (setq result (telega-match-p obj (car temex-list)))
(setq temex-list nil))
(setq temex-list (cdr temex-list)))
result))
;;; ellit-org: temex
;; - (and ~TEMEX-LIST~...) ::
;; {{{temexdoc(nil, and, 2)}}}
(define-telega-matcher nil and (obj &rest temex-list)
"Matches if all matchers in the TEMEX-LIST matches.
Also matches if TEMEX-LIST is empty."
(let ((result t))
(while temex-list
(unless (setq result (telega-match-p obj (car temex-list)))
(setq temex-list nil))
(setq temex-list (cdr temex-list)))
result))
;; NOTE: For backward compatibility, `all' as alias for `and'
;; In new code use `(return t)' temex
(define-telega-matcher nil all (obj &rest temex-list)
(telega-match-p obj `(and ,@temex-list)))
;;; ellit-org: temex
;; - (not ~TEMEX~) ::
;; {{{temexdoc(nil, not, 2)}}}
(define-telega-matcher nil not (obj temex)
"Matches if TEMEX does not match."
(not (telega-match-p obj temex)))
;;; ellit-org: temex
;; - (prop ~PROPERTY~) ::
;; {{{temexdoc(nil, prop, 2)}}}
(define-telega-matcher nil prop (obj property)
"Matches if given TDLib object has non-nil PROPERTY."
(plist-get obj property))
;;; ellit-org: temex
;; - (call ~PREDICATE~) ::
;; {{{temexdoc(nil, call, 2)}}}
(define-telega-matcher nil call (obj predicate)
"Matches if PREDICATE called with TDLib object as argument returns non-nil."
(funcall predicate obj))
;;; ellit-org: temex
;; - (ids ~ID-LIST~...) ::
;; {{{temexdoc(nil, ids, 2)}}}
(define-telega-matcher nil ids (obj &rest id-list)
"Matches if TDLib object's id is in the ID-LIST."
(memq (plist-get obj :id) id-list))
;;; ellit-org: temex
;; - (tl-type ~TL-TYPE~...) ::
;; {{{temexdoc(nil, tl-type, 2)}}}
(define-telega-matcher nil tl-type (obj &rest types-list)
"Matches if OBJ is a TDLib object and its type is in the TYPES-LIST."
(and obj (memq (telega--tl-type obj) types-list)))
;;; Chat Temexes
;;; ellit-org: chat-temex
;; - (type ~CHAT-TYPE-LIST~), {{{where-is(telega-filter-by-type,telega-root-mode-map)}}} ::
;; {{{temexdoc(chat, type, 2)}}}
;;
;; Every chat has a type. Type is one of:
;; - ~private~ Private chat with a Telegram user
;; - ~secret~ Secret chat with a Telegram user
;; - ~bot~ Chat with a Telegram bot
;; - ~basicgroup~ Small chat group, could be upgraded to supergroup
;; - ~supergroup~ Chat group with all the chat possibilities
;; - ~channel~ Supergroup with unlimited members, where only admins can post messages
(define-telega-matcher chat type (chat &rest chat-type-list)
"Matches if chat type is one of CHAT-TYPE-LIST."
(memq (telega-chat--type chat) chat-type-list))
;;; ellit-org: chat-temex
;; - (name ~REGEXP~) ::
;; {{{temexdoc(chat, name, 2)}}}
(define-telega-matcher chat name (chat regexp)
"Matches if chat's title matches REGEXP."
(or (string-match regexp (telega-chat-title chat))
(let ((info (telega-chat--info chat 'locally)))
(or (string-match regexp (or (telega-tl-str info :first_name) ""))
(string-match regexp (or (telega-tl-str info :last_name) ""))
(when-let ((usernames (plist-get info :usernames)))
(seq-some (lambda (username)
(string-match regexp username))
(plist-get usernames :active_usernames)))))))
;;; ellit-org: chat-temex
;; - (search ~QUERY~), {{{where-is(telega-filter-by-search,telega-root-mode-map)}}} ::
;; {{{temexdoc(chat, search, 2)}}}
(define-telega-matcher chat search (chat _query)
"Matches if chat maches search QUERY."
(memq chat telega--search-chats))
;;; ellit-org: chat-temex
;; - (custom ~NAME~), {{{where-is(telega-filter-by-custom,telega-root-mode-map)}}} ::
;; {{{temexdoc(chat, custom, 2)}}}
(define-telega-matcher chat custom (chat name)
"Matches if custom filter with NAME matches."
(let ((temex (cdr (assoc name telega-filters-custom))))
(unless temex
(error "No such custom chat filter \"%s\"" name))
(telega-chat-match-p chat temex)))
;;; ellit-org: chat-temex
;; - (has-username [ ~USERNAME~ ]) ::
;; {{{temexdoc(chat, has-username, 2)}}}
(define-telega-matcher chat has-username (chat &optional username)
"Matches if chat has username associated with the chat.
If USERNAME is specified, then match only if chat has exact USERNAME."
(when-let ((chat-username (telega-chat-username chat)))
(or (not username)
(equal username chat-username))))
;;; ellit-org: chat-temex
;; - is-public ::
;; {{{temexdoc(chat, is-public, 2)}}}
(define-telega-matcher chat is-public (chat)
"Matches if chat is a public chat.
Chat is considered public if it has a username."
(telega-chat-match-p chat 'has-username))
;;; ellit-org: chat-temex
;; - (unread [ ~N~ ]), {{{where-is(telega-filter-by-unread,telega-root-mode-map)}}} ::
;; {{{temexdoc(chat, unread, 2)}}}
(define-telega-matcher chat unread (chat &optional n)
"Matches if chat has at least N unread messages.
By default N is 1.
Also matches chats marked as unread."
(or (>= (plist-get chat :unread_count) (or n 1))
(plist-get chat :is_marked_as_unread)))
;;; ellit-org: chat-temex
;; - (mention [ ~N~ ]), {{{where-is(telega-filter-by-mention,telega-root-mode-map)}}} ::
;; {{{temexdoc(chat, mention, 2)}}}
(define-telega-matcher chat mention (chat &optional n)
"Matches if chat has least N unread mentions.
By default N is 1."
(>= (plist-get chat :unread_mention_count) (or n 1)))
;;; ellit-org: chat-temex
;; - muted ::
;; {{{temexdoc(chat, muted, 2)}}}
(define-telega-matcher chat muted (chat)
"Matches if chat has disabled notifications."
(> (telega-chat-notification-setting chat :mute_for) 0))
;;; ellit-org: chat-temex
;; - temporary-muted ::
;; {{{temexdoc(chat, temporary-muted, 2)}}}
(define-telega-matcher chat temporary-muted (chat)
"Matches if chat is temporary muted."
(let ((muted-for (telega-chat-notification-setting chat :mute_for)))
(and (> muted-for 0)
(< muted-for telega-mute-for-ever))))
;;; ellit-org: chat-temex
;; - unmuted, {{{where-is(telega-filter-by-unmuted,telega-root-mode-map)}}} ::
;; {{{temexdoc(chat, unmuted, 2)}}}
(define-telega-matcher chat unmuted (chat)
"Matches if chat has enabled notifications."
(telega-chat-match-p chat '(not muted)))
;;; ellit-org: chat-temex
;; - important, {{{where-is(telega-filter-by-important,telega-root-mode-map)}}} ::
;; {{{temexdoc(chat, important, 2)}}}
(define-telega-matcher chat important (chat)
"Matches if chat is important.
Chat is important if it matches `telega-important-chat-temex' chat filter."
(telega-chat-match-p chat telega-important-chat-temex))
;;; ellit-org: chat-temex
;; - (me-is-owner [ ~OR-ADMIN~ ]) ::
;; {{{temexdoc(chat, me-is-owner, 2)}}}
(define-telega-matcher chat me-is-owner (chat &optional or-admin)
"Matches if me is owner of the chat.
Only basicgroup, supergroup and channel can be owned.
If optional OR-ADMIN is specified, then match also if me is
administrator in the chat."
(when-let ((status (telega-chat-member-my-status chat)))
(memq (telega--tl-type status)
(list 'chatMemberStatusCreator
(when or-admin 'chatMemberStatusAdministrator)))))
;;; ellit-org: chat-temex
;; - me-is-member ::
;; {{{temexdoc(chat, me-is-member, 2)}}}
(define-telega-matcher chat me-is-member (chat)
"Matches if me is member of the chat.
Matches only basicgroup, supergroup or a channel."
;; NOTE: me can only be a member of chats that have tdlib chat list
;; position
(unless (seq-empty-p (plist-get chat :positions))
(when-let ((status (telega-chat-member-my-status chat)))
(cl-ecase (telega--tl-type status)
((chatMemberStatusAdministrator chatMemberStatusMember)
t)
((chatMemberStatusCreator chatMemberStatusRestricted)
(plist-get status :is_member))
((chatMemberStatusLeft chatMemberStatusBanned)
nil)))))
;;; ellit-org: chat-temex
;; - me-is-anonymous ::
;; {{{temexdoc(chat, me-is-anonymous, 2)}}}
(define-telega-matcher chat me-is-anonymous (chat)
"Matches if me is anonymous in the chat."
(plist-get (telega-chat-member-my-status chat) :is_anonymous))
;;; ellit-org: chat-temex
;; - (has-avatar [ ~ANIMATED-P~ ])::
;; {{{temexdoc(chat, has-avatar, 2)}}}
(define-telega-matcher chat has-avatar (chat &optional animated-p)
"Matches if chat has chat photo.
For non-nil ANIMATED-P match only if avatar is animated."
(when-let ((chat-photo (plist-get chat :photo)))
(or (not animated-p)
(plist-get chat-photo :has_animation))))
;;; ellit-org: chat-temex
;; - has-chatbuf, {{{where-is(telega-filter-by-has-chatbuf,telega-root-mode-map)}}} ::
;; {{{temexdoc(chat, has-chatbuf, 2)}}}
(define-telega-matcher chat has-chatbuf (chat)
"Matches if chat has corresponding chatbuf."
(with-telega-chatbuf chat
t))
;;; ellit-org: chat-temex
;; - (permission ~PERM~) ::
;; {{{temexdoc(chat, permission, 2)}}}
(define-telega-matcher chat permission (chat perm)
"Matches if chat has PERM set in chat permissions.
PERM could be one of listed in `telega-chat--chat-permissions'."
(plist-get (plist-get chat :permissions) perm))
;;; ellit-org: chat-temex
;; - (my-permission ~PERM~) ::
;; {{{temexdoc(chat, my-permission, 2)}}}
(define-telega-matcher chat my-permission (chat perm)
"Matches if me has PERM permission in the chat.
PERM could be one of in `telega-chat--chat-permissions' list or in
`telega-chat--admin-permissions' list."
(plist-get (telega-chat-member-my-permissions chat) perm))
;;; ellit-org: chat-temex
;; - verified, {{{where-is(telega-filter-by-verified,telega-root-mode-map)}}} ::
;; {{{temexdoc(chat, verified, 2)}}}
(define-telega-matcher chat verified (chat)
"Matches if chat is verified."
(plist-get (telega-chat--info chat 'locally) :is_verified))
;;; ellit-org: chat-temex
;; - (restriction ~SUFFIX-LIST~...), {{{where-is(telega-filter-by-restriction,telega-root-mode-map)}}} ::
;; {{{temexdoc(chat, restriction, 2)}}}
;;
;; Chat restriction reason reported only if chat must be restricted
;; by current client. See
;; [[https://github.com/tdlib/td/issues/1203][TDLib#1203]]
(define-telega-matcher chat restriction (chat &rest suffix-list)
"Matches restricted chats.
SUFFIX-LIST is a list of suffixes to filter on.
Suffix can be one of:
- \"-all\" - All platforms
- \"-ios\" - For iOS devices
- \"-android\" - For Android devices
- \"-wp\" - Windows?
If SUFFIX-LIST is not specified, then match any restriction reason."
(when-let ((reason (telega-tl-str (telega-chat--info chat 'locally)
:restriction_reason)))
(or (not suffix-list)
(cl-find reason suffix-list
:test (lambda (string regexp)
(string-match-p regexp string))))))
;;; ellit-org: chat-temex
;; - top, {{{where-is(telega-filter-by-top,telega-root-mode-map)}}} ::
;; {{{temexdoc(chat, top, 2)}}}
(define-telega-matcher chat top (chat)
"Matches if chat is in top usage."
(let ((category (cl-case (telega-chat--type chat)
(private 'Users)
(bot 'Bots)
((basicgroup supergroup) 'Groups)
(channel 'Channels))))
(memq chat (telega-chats-top category))))
;;; ellit-org: chat-temex
;; - saved-messages ::
;; {{{temexdoc(chat, saved-messages, 2)}}}
(define-telega-matcher chat saved-messages (chat)
"Matches only \"Saved Messages\" chat."
(telega-me-p chat))
;;; ellit-org: chat-temex
;; - replies-messages ::
;; {{{temexdoc(chat, replies-messages, 2)}}}
(define-telega-matcher chat replies-messages (chat)
"Matches only \"Replies\" chat."
(telega-replies-p chat))
;;; ellit-org: chat-temex
;; - tracking, {{{where-is(telega-filter-by-tracking,telega-root-mode-map)}}} ::
;; {{{temexdoc(chat, tracking, 2)}}}
(define-telega-matcher chat tracking (chat)
"Matches if chat is in tracking buffers list."
(with-telega-chatbuf chat
(member (buffer-name) tracking-buffers)))
;;; ellit-org: chat-temex
;; - (last-message ~MSG-TEMEX~)::
;; {{{temexdoc(chat, last-message, 2)}}}
(define-telega-matcher chat last-message (chat msg-temex)
"Matches if chat has last message and last message matches MSG-TEMEX."
(when-let ((last-msg (plist-get chat :last_message)))
(telega-msg-match-p last-msg msg-temex)))
;;; ellit-org: chat-temex
;; - (chat-list ~LIST-NAME~), {{{where-is(telega-filter-by-folder,telega-root-mode-map)}}} ::
;; {{{temexdoc(chat, chat-list, 2)}}}
(define-telega-matcher chat chat-list (chat list-name)
"Matches if chat is in chat list named LIST-NAME.
LIST-NAME is `main' or `archive' symbol, or string naming Chat Folder."
(let (item key)
(cond ((eq list-name 'main)
(setq item '(:@type "chatListMain")
key (telega--tl-prop :list)))
((eq list-name 'archive)
(setq item '(:@type "chatListArchive")
key (telega--tl-prop :list)))
(t
(when-let ((fi (telega-folder--chat-folder-info list-name)))
(setq item (plist-get fi :id)
key (telega--tl-prop :list :chat_folder_id)))))
(when-let ((pos (cl-find item (plist-get chat :positions)
:key key :test #'equal)))
;; NOTE: zero order means "chat has no position"
(not (equal "0" (plist-get pos :order))))))
;;; ellit-org: chat-temex
;; - main ::
;; {{{temexdoc(chat, main, 2)}}}
(define-telega-matcher chat main (chat)
"Matches if chat from \"Main\" chat list."
(telega-chat-match-p chat '(chat-list main)))
;;; ellit-org: chat-temex
;; - archive ::
;; {{{temexdoc(chat, archive, 2)}}}
(define-telega-matcher chat archive (chat)
"Matches if chat is archived, i.e. in \"Archive\" chat list."
(telega-chat-match-p chat '(chat-list archive)))
;;; ellit-org: chat-temex
;; - is-known ::
;; {{{temexdoc(chat, is-known, 2)}}}
(define-telega-matcher chat is-known (chat)
"Matches if chat is known, i.e. in \"Main\" or \"Archive\" chat list."
(telega-chat-match-p chat '(or main archive)))
;;; ellit-org: chat-temex
;; - (folder ~FOLDER-NAME~), {{{where-is(telega-filter-by-folder,telega-root-mode-map)}}} ::
;; {{{temexdoc(chat, folder, 2)}}}
(define-telega-matcher chat folder (chat folder-name)
"Matches if chat belongs to Folder named FOLDER-NAME."
(telega-chat-match-p chat (list 'chat-list folder-name)))
;;; ellit-org: chat-temex
;; - has-scheduled-messages ::
;; {{{temexdoc(chat, has-scheduled-messages, 2)}}}
(define-telega-matcher chat has-scheduled-messages (chat)
"Matches if chat has scheduled messages."
(plist-get chat :has_scheduled_messages))
;;; ellit-org: chat-temex
;; - has-action-bar ::
;; {{{temexdoc(chat, has-action-bar, 2)}}}
(define-telega-matcher chat has-action-bar (chat)
"Matches if chat has active action bar."
(plist-get chat :action_bar))
;;; ellit-org: chat-temex
;; - has-reply-markup ::
;; {{{temexdoc(chat, has-reply-markup, 2)}}}
(define-telega-matcher chat has-reply-markup (chat)
"Matches if chat has reply markup message."
(not (eq 0 (plist-get chat :reply_markup_message_id))))
;;; ellit-org: chat-temex
;; - can-get-statistics ::
;; {{{temexdoc(chat, can-get-statistics, 2)}}}
(define-telega-matcher chat can-get-statistics (chat)
"Matches if statistics available for the chat."
(when (telega-chat-match-p chat '(type supergroup channel))
(let ((full-info (telega--full-info (telega-chat--info chat))))
(plist-get full-info :can_get_statistics))))
;;; ellit-org: chat-temex
;; - has-linked-chat ::
;; {{{temexdoc(chat, has-linked-chat, 2)}}}
(define-telega-matcher chat has-linked-chat (chat)
"Matches if chat is a supergroup and has a linked chat."
(plist-get (telega-chat--info chat) :has_linked_chat))
;;; ellit-org: chat-temex
;; - has-discussion-group ::
;; {{{temexdoc(chat, has-discussion-group, 2)}}}
(define-telega-matcher chat has-discussion-group (chat)
"Matches if chat is a channel with a linked discussion group."
(telega-chat-match-p chat '(and (type channel) has-linked-chat)))
;;; ellit-org: chat-temex
;; - has-location ::
;; {{{temexdoc(chat, has-location, 2)}}}
(define-telega-matcher chat has-location (chat)
"Matches if chat is a location-based supergroup."
(plist-get (telega-chat--info chat) :has_location))
;;; ellit-org: chat-temex
;; - inactive-supergroups , {{{where-is(telega-filter-by-inactive-supergroups,telega-root-mode-map)}}} ::
;; {{{temexdoc(chat, inactive-supergroups, 2)}}}
(define-telega-matcher chat inactive-supergroups (chat)
"Matches if chat is an inactive supergroup."
(memq chat telega--search-chats))
;;; ellit-org: chat-temex
;; - default-disable-notification ::
;; {{{temexdoc(chat, default-disable-notification, 2)}}}
(define-telega-matcher chat default-disable-notification (chat)
"Matches if CHAT has non-nil default disable notification setting."
(plist-get chat :default_disable_notification))
;;; ellit-org: chat-temex
;; - fake-or-scam ::
;; {{{temexdoc(chat, fake-or-scam, 2)}}}
(define-telega-matcher chat fake-or-scam (chat)
"Matches if chat is fake or scam user or group."
(let ((info (telega-chat--info chat)))
(or (plist-get info :is_scam)
(plist-get info :is_fake))))
;;; ellit-org: chat-temex
;; - (has-video-chat [ ~NON-EMPTY~ ]) ::
;; {{{temexdoc(chat, has-video-chat, 2)}}}
(define-telega-matcher chat has-video-chat (chat &optional non-empty)
"Matches if chat contains a live video chat.
If non-nil NON-EMPTY is specified, then match only if video chat is
not empty."
(when-let* ((video-chat (plist-get chat :video_chat))
(group-call-id (plist-get video-chat :group_call_id)))
(and (not (zerop group-call-id))
(or (null non-empty)
(plist-get video-chat :has_participants)))))
;;; ellit-org: chat-temex
;; - has-favorite-messages ::
;; {{{temexdoc(chat, has-favorite-messages, 2)}}}
(define-telega-matcher chat has-favorite-messages (chat)
"Matches if chat has favorite messages."
(cl-find (plist-get chat :id) telega--favorite-messages
:key (telega--tl-prop :chat_id)))
;;; ellit-org: chat-temex
;; - has-message-ttl ::
;; {{{temexdoc(chat, has-message-ttl, 2)}}}
(define-telega-matcher chat has-message-ttl (chat)
"Matches if chat has enabled message auto-delete or self-destruct timer.
Return auto-deletion timer value."
(when-let ((msg-ttl (plist-get chat :message_auto_delete_time)))
(and (> msg-ttl 0) msg-ttl)))
;;; ellit-org: chat-temex
;; - is-broadcast-group ::
;; {{{temexdoc(chat, is-broadcast-group, 2)}}}
(define-telega-matcher chat is-broadcast-group (chat)
"Matches if chat is a broadcast group."
(plist-get (telega-chat--info chat) :is_broadcast_group))
;;; ellit-org: chat-temex
;; - is-forum ::
;; {{{temexdoc(chat, is-forum, 2)}}}
(define-telega-matcher chat is-forum (chat)
"Matches if chat is a forum group."
(plist-get (telega-chat--info chat) :is_forum))
;;; ellit-org: chat-temex
;; - has-sponsored-messages ::
;; {{{temexdoc(chat, has-sponsored-messages, 2)}}}
(define-telega-matcher chat has-sponsored-messages (chat)
"Matches if chat has sponsored messages.
BE AWARE: This filter will do blocking request for every chat."
(when (telega-chat-match-p chat '(type channel))
(let ((csm (telega--getChatSponsoredMessages chat)))
(not (seq-empty-p (plist-get csm :messages))))))
;;; ellit-org: chat-temex
;; - has-protected-content ::
;; {{{temexdoc(chat, has-protected-content, 2)}}}
(define-telega-matcher chat has-protected-content (chat)
"Matches if chat has protected content."
(plist-get chat :has_protected_content))
;;; ellit-org: chat-temex
;; - has-default-sender ::
;; {{{temexdoc(chat, has-default-sender, 2)}}}
(define-telega-matcher chat has-default-sender (chat)
"Matches if chat allows choosing a message sender."
(plist-get chat :message_sender_id))
;;; ellit-org: chat-temex
;; - can-send-or-post ::
;; {{{temexdoc(chat, can-send-or-post, 2)}}}
(define-telega-matcher chat can-send-or-post (chat)
"Matches if you can send or post messages to the chat.
You don't need te be a chat member to be able to send messages.
Chat might not be known (i.e. in your Main or Archive list) to post
messages into it. Use `is-known' chat temex to check chat is known."
(and (or (telega-chat-match-p chat '(type bot private secret))
(telega-chat-match-p chat 'me-is-member)
;; Also, it is possible to send message to discussion group
;; without joining it
(and (telega-chat-match-p chat '(type supergroup))
(not (plist-get (telega-chat--supergroup-locally chat)
:join_to_send_messages))))
(let ((my-perms (telega-chat-member-my-permissions chat)))
(or (plist-get my-perms :can_send_basic_messages)
(plist-get my-perms :can_post_messages)))))
;;; ellit-org: chat-temex
;; - is-inline-bot ::
;; {{{temexdoc(chat, is-inline-bot, 2)}}}
(define-telega-matcher chat is-inline-bot (chat)
"Matches if corresponding bot accepts inline requests."
(when (telega-chat-bot-p chat)
(when-let ((user (telega-chat-user chat)))
(telega--tl-get user :type :is_inline))))
;;; ellit-org: chat-temex
;; - (unread-reactions [ ~N~ ]) ::
;; {{{temexdoc(chat, unread-reactions, 2)}}}
(define-telega-matcher chat unread-reactions (chat &optional n)
"Matches if chat has least N unread reactions.
By default N is 1."
(>= (or (plist-get chat :unread_reaction_count) 0) (or n 1)))
;;; ellit-org: chat-temex
;; - (has-active-stories [ ~UNREAD-P~ ]) ::
;; {{{temexdoc(chat, has-active-stories, 2)}}}
(define-telega-matcher chat has-active-stories (chat &optional unread-p)
"Matches if chat has non-expired stories available to you.
If UNREAD-P is non-nil then match only if there is at least one unread
non-expired story."
(plist-get (telega-chat--info chat) (if unread-p
:has_unread_active_stories
:has_active_stories)))
;;; ellit-org: chat-temex
;; - (active-stories-list ~LIST~) ::
;; {{{temexdoc(chat, active-stories-list, 2)}}}
(define-telega-matcher chat active-stories-list (chat list)
"Matches if chat's active stories belongs to LIST.
LIST is one of `main' or `archive'."
(when-let* ((active-stories (telega-chat--active-stories chat))
(list-type (telega--tl-get active-stories :list :@type)))
(cl-ecase list
(main (equal list-type "storyListMain"))
(archive (equal list-type "storyListArchive")))))
;;; ellit-org: chat-temex
;; - has-pinned-stories ::
;; {{{temexdoc(chat, has-pinned-stories, 2)}}}
(define-telega-matcher chat has-pinned-stories (chat)
"Matches if channel chat has pinned stories."
(when (telega-chat-match-p chat '(type channel))
(let ((full-info (telega--full-info (telega-chat--info chat))))
(plist-get full-info :has_pinned_stories))))
;;; ellit-org: chat-temex
;; - can-send-stories ::
;; {{{temexdoc(chat, can-send-stories, 2)}}}
(define-telega-matcher chat can-send-stories (chat)
"Matches if you can post a story into chat."
(memq chat telega--search-chats))
;;; ellit-org: chat-temex
;; - (my-boost [ ~N~ ]) ::
;; {{{temexdoc(chat, my-boost, 2)}}}
(define-telega-matcher chat my-boost (chat &optional n)
"Matches if supergroup or channel has least N my boosts.
By default N is 1."
(when (telega-chat-match-p chat '(type supergroup channel))
(let ((full-info (telega--full-info (telega-chat--info chat))))
(>= (or (plist-get full-info :my_boost_count) 0) (or n 1)))))
;;; ellit-org: chat-temex
;; - (user ~USER-TEMEX~) ::
;; {{{temexdoc(chat, user, 2)}}}
(define-telega-matcher chat user (chat user-temex)
"Matches non-bot private chat where corresponding user matches USER-TEMEX."
(unless (telega-chat-bot-p chat)
(when-let ((user (telega-chat-user chat)))
(telega-user-match-p user user-temex))))
;;; ellit-org: chat-temex
;; - (bot-user ~USER-TEMEX~) ::
;; {{{temexdoc(chat, bot-user, 2)}}}
(define-telega-matcher chat bot-user (chat user-temex)
"Matches chat where corresponding bot user matches USER-TEMEX."
(when (telega-chat-bot-p chat)
(when-let ((user (telega-chat-user chat)))
(telega-user-match-p user user-temex))))
;;; ellit-org: chat-temex
;; - (is-blocked [ ~BLOCK-LIST~ ]) ::
;; {{{temexdoc(chat, is-blocked, 2)}}}
(define-telega-matcher chat is-blocked (chat &optional block-list)
"Matches chat if chat is blocked in by the BLOCK-LIST.
BLOCK-LIST is one of `blockListMain' or `blockListStories'.
By default `blockListMain' is used."
(when-let ((chat-block-list (plist-get chat :block_list)))
(eq (telega--tl-type chat-block-list)
(or block-list 'blockListMain))))
;;; ellit-org: chat-temex
;; - (boost-level [ ~N~ ]) ::
;; {{{temexdoc(chat, boost-level, 2)}}}
(define-telega-matcher chat boost-level (chat &optional n)
"Matches if chat's boost level is greater or equal to N.
By default N is 1."
(when (telega-chat-match-p chat '(type channel))
(let ((info (telega-chat--info chat 'local)))
(>= (or (plist-get info :boost_level) 0) (or n 1)))))
;;; User Temexes
;;; ellit-org: user-temex
;; - is-deleted ::
;; {{{temexdoc(user, is-deleted, 2)}}}
(define-telega-matcher user is-deleted (user)
"Matches if user account is deleted."
(eq (telega-user--type user) 'deleted))
;;; ellit-org: user-temex
;; - is-bot ::
;; {{{temexdoc(user, is-bot, 2)}}}
(define-telega-matcher user is-bot (user)
"Matches if user is a bot."
(telega-user-bot-p user))
;;; ellit-org: user-temex
;; - (status ~STATUS-LIST~...) ::
;; {{{temexdoc(user, status, 2)}}}
;;
;; Each element in ~STATUS-LIST~ is one of: "Online", "Offline",
;; "Recently", "LastWeek", "LastMonth" or "Empty"
(define-telega-matcher user status (user &rest status-list)
"Matches if user status is one of STATUS-LIST."
(member (telega-user--seen user) status-list))
;;; ellit-org: user-temex
;; - online ::
;; {{{temexdoc(user, is-online, 2)}}}
;;
;; Same as ~(status "Online")~ user temex.
(define-telega-matcher user is-online (user)
"Matches if user is online.
Does not match bots, because bots are always online."
(telega-user-match-p user '(status "Online")))
;;; ellit-org: user-temex
;; - (contact [ ~MUTUAL-P~ ]), {{{where-is(telega-filter-by-contact,telega-root-mode-map)}}} ::
;; {{{temexdoc(user, contact, 2)}}}
(define-telega-matcher user contact (user &optional mutual-p)
"Matches if user is in my contacts list.
If MUTUAL-P is non-nil, then mach only if contact is mutual."
(plist-get user (if mutual-p :is_mutual_contact :is_contact)))
;;; ellit-org: user-temex
;; - is-close-friend ::
;; {{{temexdoc(user, is-close-friend, 2)}}}
(define-telega-matcher user is-close-friend (user)
"Matches if user is my close friend."
(plist-get user :is_close_friend))
;;; ellit-org: user-temex
;; - has-pinned-stories ::
;; {{{temexdoc(user, has-pinned-stories, 2)}}}
(define-telega-matcher user has-pinned-stories (user)
"Matches if user has pinned stories."
(plist-get (telega--full-info user) :has_pinned_stories))
;;; ellit-org: user-temex
;; - (groups-in-common [ ~N~ ]) ::
;; {{{temexdoc(user, groups-in-common, 2)}}}
(define-telega-matcher user groups-in-common (user &optional n)
"Matches if user has at least N groups in common with me.
By default N is 1."
(>= (plist-get (telega--full-info user) :group_in_common_count)
(or n 1)))
;;; ellit-org: user-temex
;; - is-telega-patron ::
;; {{{temexdoc(user, is-telega-patron, 2)}}}
(define-telega-matcher user is-telega-patron (user)
"Matches if corresponding user is a telega patron."
(telega-msg-sender-patron-p user))
;;; ellit-org: user-temex
;; - is-premium ::
;; {{{temexdoc(user, is-premium, 2)}}}
(define-telega-matcher user is-premium (user)
"Matches if corresponding user is a Telegram Premium user."
(plist-get user :is_premium))
;;; ellit-org: user-temex
;; - has-private-forwards ::
;; {{{temexdoc(user, has-private-forwards, 2)}}}
(define-telega-matcher user has-private-forwards (user)
"Matches if user can't be linked in forwarded messages."
(plist-get (telega--full-info user) :has_private_forwards))
;;; ellit-org: user-temex
;; - has-business-info ::
;; {{{temexdoc(user, has-business-info, 2)}}}
(define-telega-matcher user has-business-info (user &optional info-prop)
"Matches if user has business info."
(when-let ((binfo (plist-get (telega--full-info user) :business_info)))
(or (not info-prop)
(plist-get binfo info-prop))))
;;; ellit-org: user-temex
;; - has-birthdate ::
;; {{{temexdoc(user, has-birthdate, 2)}}}
(define-telega-matcher user has-birthdate (user)
"Matches if user has birthdate set."
(plist-get (telega--full-info user) :birthdate))
;;; ellit-org: user-temex
;; - has-personal-chat ::
;; {{{temexdoc(user, has-personal-chat, 2)}}}
(define-telega-matcher user has-personal-chat (user)
"Matches if user has personal chat."
(not (telega-zerop (plist-get (telega--full-info user) :personal_chat_id))))
;;; ellit-org: user-temex
;; - has-emoji-status ::
;; {{{temexdoc(user, has-emoji-status, 2)}}}
(define-telega-matcher user has-emoji-status (user)
"Matches if corresponding user set his current emoji status."
(plist-get user :emoji_status))
;;; ellit-org: user-temex
;; - (username [ ~USERNAME-REGEXP~ ]) ::
;; {{{temexdoc(user, username, 2)}}}
(define-telega-matcher user username (user username-regexp)
"Matches if user's username matches USERNAME-REGEXP."
(when-let ((username (telega-msg-sender-username user)))
(string-match-p username-regexp username)))
;;; ellit-org: user-temex
;; - (chat ~CHAT-TEMEX~) ::
;; {{{temexdoc(user, chat, 2)}}}
(define-telega-matcher user chat (user chat-temex)
"Matches if me has private chat with USER matching CHAT-TEMEX."
(when-let ((chat (telega-chat-get (plist-get user :id) 'offline)))
(telega-chat-match-p chat chat-temex)))
;;; ellit-org: user-temex
;; - (is-blocked [ ~BLOCK-LIST~ ]) ::
;; {{{temexdoc(user, is-blocked, 2)}}}
(define-telega-matcher user is-blocked (user &optional block-list)
"Matches user blocked by the BLOCK-LIST.
BLOCK-LIST is one of `blockListMain' or `blockListStories'.
By default `blockListMain' is used."
(let* ((block-list (or block-list 'blockListMain))
(blocked-user-ids
(cdr (alist-get block-list telega--blocked-user-ids-alist))))
(or (memq (plist-get user :id) (cdr blocked-user-ids))
(when-let ((user-block-list
(plist-get (telega--full-info user) :block_list)))
(eq (telega--tl-type user-block-list) block-list)))))
;;; Message Temexes
;;; ellit-org: msg-temex
;; - (type ~MSG-TYPE-LIST~) ::
;; {{{temexdoc(msg, type, 2)}}}
;;
;; Every message has a content type. Most notable message types
;; are: ~Text~, ~Animation~, ~Audio~, ~Document~, ~Photo~,
;; ~Sticker~, ~Video~, ~VideoNote~, ~VoiceNote~, ~Location~, etc.
(define-telega-matcher msg type (msg &rest msg-type-list)
"Matches if message's content type is one of MSG-TYPE-LIST.
Return message's content if matches."
(let ((content (plist-get msg :content)))
(when (memq (intern (substring (plist-get content :@type)
;; Strip "Message" prefix
7))
msg-type-list)
content)))
;;; ellit-org: msg-temex
;; - seen ::
;; {{{temexdoc(msg, seen, 2)}}}
(define-telega-matcher msg seen (msg)
"Return non-nil if message has been viewed in the chat."
(<= (plist-get msg :id)
(let ((chat (telega-msg-chat msg)))
(or (with-telega-chatbuf chat
(telega-chatbuf--last-read-inbox-msg-id))
(plist-get chat :last_read_inbox_message_id)))))
;;; ellit-org: msg-temex
;; - (unread-reactions [ ~N~ ]) ::
;; {{{temexdoc(msg, unread-reactions, 2)}}}
(define-telega-matcher msg unread-reactions (msg &optional n)
"Matches if message has at least N unread reactions.
By default N is 1."
(>= (length (plist-get msg :unread_reactions)) (or n 1)))
;;; ellit-org: msg-temex
;; - (has-chosen-reaction [ ~REACTION-TYPE~ ]) ::
;; {{{temexdoc(msg, has-chosen-reaction, 2)}}}
(define-telega-matcher msg has-chosen-reaction (msg &optional reaction-type)
"Matches if message has a reaction chosen by me."
(let ((chosen-reaction-types (telega-msg-chosen-reaction-types msg)))
(if reaction-type
(cl-find reaction-type chosen-reaction-types :test #'equal)
chosen-reaction-types)))
;;; ellit-org: msg-temex
;; - is-reply-to-msg ::
;; {{{temexdoc(msg, is-reply-to-msg, 2)}}}
(define-telega-matcher msg is-reply-to-msg (msg)
"Matches if message is a reply to some message."
(when-let ((reply-to (plist-get msg :reply_to)))
(eq 'messageReplyToMessage (telega--tl-type reply-to))))
;;; ellit-org: msg-temex
;; - is-reply-to-quote ::
;; {{{temexdoc(msg, is-reply-to-quote, 2)}}}
(define-telega-matcher msg is-reply-to-quote (msg)
"Matches if message is a reply to a quote from some message."
(when-let ((reply-to (plist-get msg :reply_to)))