applying a shader on the desktop

[absolutelynothelix]

well, since the name of this category is "show and tell" and the description is "show off something you've made", let me share an interesting use of ability to apply certain shaders on certain windows.

using the --window-shader-fg-rule command line option you can apply a shader on the desktop window and create a nice animated overlay on your wallpaper (or even replace your wallpaper with a shader so you'll have an animated wallpaper).

depending on the shader you're going to use, the style of your desktop and your wallpaper, it could become a nice addition to your desktop.

see the example:

output.mp4

command line:

$ picom --window-shader-fg-rule="desktop_shader.glsl:window_type='desktop'"

the shader used:

don't quote me on it, it's just an adaptation of a shader i found on shadertoy, source: https://www.shadertoy.com/view/lldyDs

#version 130

in vec2 texcoord;
uniform sampler2D tex;
uniform float time;

vec4 default_post_processing(vec4 c);

float stime = time / 3000.0;

float distLine(vec2 p, vec2 a, vec2 b) {
  vec2 ap = p - a;
  vec2 ab = b - a;
  float aDotB = clamp(dot(ap, ab) / dot(ab, ab), 0.0, 1.0);
  return length(ap - ab * aDotB);
}

float drawLine(vec2 uv, vec2 a, vec2 b) {
  float line = smoothstep(0.014, 0.01, distLine(uv, a, b));
  float dist = length(b - a);
  return line * (smoothstep(1.3, 0.8, dist) * 0.5 +
                 smoothstep(0.04, 0.03, abs(dist - 0.75)));
}

float n21(vec2 i) {
  i += fract(i * vec2(223.64, 823.12));
  i += dot(i, i + 23.14);
  return fract(i.x * i.y);
}

vec2 n22(vec2 i) {
  float x = n21(i);
  return vec2(x, n21(i + x));
}

vec2 getPoint(vec2 id, vec2 offset) {
  return offset + sin(n22(id + offset) * stime * 1.0) * 0.4;
}

float layer(vec2 uv) {
  float m = 0.0;
  float t = stime * 2.0;

  vec2 gv = fract(uv) - 0.5;
  vec2 id = floor(uv) - 0.5;

  vec2 p[9];
  int i = 0;
  for (float y = -1.0; y <= 1.0; y++) {
    for (float x = -1.0; x <= 1.0; x++) {
      p[i++] = getPoint(id, vec2(x, y));
    }
  }

  for (int i = 0; i < 9; i++) {
    m += drawLine(gv, p[4], p[i]);
    float sparkle = 1.0 / pow(length(gv - p[i]), 1.5) * 0.005;
    m += sparkle * (sin(t + fract(p[i].x) * 12.23) * 0.4 + 0.6);
  }

  m += drawLine(gv, p[1], p[3]);
  m += drawLine(gv, p[1], p[5]);
  m += drawLine(gv, p[7], p[3]);
  m += drawLine(gv, p[7], p[5]);

  return m;
}

vec4 window_shader() {
  vec2 texsize = textureSize(tex, 0);
  vec4 cc = texture2D(tex, texcoord / texsize, 0);

  vec2 uv = (texcoord - 0.5 * texsize.xy) / texsize.y;
  vec3 c = sin(stime * 2.0 * vec3(.234, .324, .768)) * 0.4 + 0.6;
  vec3 col = vec3(0);
  float fft = texelFetch(tex, ivec2(76.0, 0.), 0).x / 2.0 + 0.5;
  c.x += (uv.x + 0.5);
  col += pow(-uv.y + 0.5, 5.0) * fft * c;

  float m = 0.0;
  float x = sin(stime * 0.1);
  float y = cos(stime * 0.2);

  mat2 rotMat = mat2(x, y, -y, x);
  uv *= rotMat;

  for (float i = 0.0; i <= 1.0; i += 0.25) {
    float z = fract(i + stime * 0.05);
    float size = mix(15.0, 0.1, z) * 1.50;
    float fade = smoothstep(0.0, 1.0, z) * smoothstep(1.0, 0.9, z);
    m += layer((size * uv) + i * 10.0) * fade;
  }

  col += m * c;
  cc = vec4(col, 0.25);

  return default_post_processing(cc);
}