build.gradle

plugins {
    id 'java'
    id 'org.springframework.boot' version '3.2.0'
    id 'io.spring.dependency-management' version '1.1.4'
    id "com.diffplug.spotless" version "6.23.3"
}

bootJar.enabled = false

subprojects {
    group = 'com.github.whatasame'
    version = '1.0.0'
    sourceCompatibility = '21'

    apply plugin: 'java'
    apply plugin: 'org.springframework.boot'
    apply plugin: 'io.spring.dependency-management'
    apply plugin: 'com.diffplug.spotless'

    dependencies {
        implementation 'org.springframework.boot:spring-boot-starter'
        testImplementation 'org.springframework.boot:spring-boot-starter-test'

        compileOnly 'org.projectlombok:lombok'
        annotationProcessor 'org.projectlombok:lombok'
    }

    repositories {
        mavenCentral()
    }

    test {
        useJUnitPlatform()
    }

    spotless {
        java {
            importOrder()

            removeUnusedImports()

            cleanthat()

            palantirJavaFormat()
//            formatAnnotations()
        }
    }
}

task updateGitHooks(type: Copy) {
    from './scripts/pre-commit'
    into './.git/hooks'
}
compileJava.dependsOn(updateGitHooks)