-
Notifications
You must be signed in to change notification settings - Fork 2
/
Copy pathwiz500.b
2917 lines (2846 loc) · 71.4 KB
/
wiz500.b
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
833
834
835
836
837
838
839
840
841
842
843
844
845
846
847
848
849
850
851
852
853
854
855
856
857
858
859
860
861
862
863
864
865
866
867
868
869
870
871
872
873
874
875
876
877
878
879
880
881
882
883
884
885
886
887
888
889
890
891
892
893
894
895
896
897
898
899
900
901
902
903
904
905
906
907
908
909
910
911
912
913
914
915
916
917
918
919
920
921
922
923
924
925
926
927
928
929
930
931
932
933
934
935
936
937
938
939
940
941
942
943
944
945
946
947
948
949
950
951
952
953
954
955
956
957
958
959
960
961
962
963
964
965
966
967
968
969
970
971
972
973
974
975
976
977
978
979
980
981
982
983
984
985
986
987
988
989
990
991
992
993
994
995
996
997
998
999
1000
; Disassembled by Vossi 05/2020
; Prepared for ACME reassembling
; Comments, Labels by Vossi 06/2020
; Converted for P500 by Vossi 06/2020
!cpu 6502
; switches
!ct pet
!to "wiz500.prg", cbm
!cpu 6502
; ########################################### TODO ################################################
;
;
; ########################################### BUGS ################################################
; sometimes the 'worlok' doesn't appears and you stuck without monster ;)
; ######################################### P500 MODS #############################################
; Indirect reg is always = 15, all other indirect operations with ora(),y lda(,x) sta(,x)
; ******************************************* INFO ************************************************
; ESC in start screen enables 'never die' cheat - only allowed for testing the levels !!!
; ***************************************** CONSTANTS *********************************************
FILL = $aa ; fills free memory areas with $aa
NOPCODE = $ea ; nop instruction for fill
GAMEBANK = 0 ; Game code bank
SYSTEMBANK = $f ; systembank
LIVES = 3 ; start lives
; directions
WALL = 0
UP = 1
DOWN = 2
LEFT = 3
RIGHT = 4
; table codes
ADR = $fe ; new target address follows
LIN = $fd ; new line (target +40)
END = $ff ; end of data
; color codes
BLACK = $00
WHITE = $01
RED = $02
CYAN = $03
MAGENTA = $04
GREEN = $05
BLUE = $06
YELLOW = $07
ORANGE = $08
BROWN = $09
LIGHTRED = $0a
GRAY1 = $0b
GRAY2 = $0c
LIGHTGREEN = $0d
LIGHTBLUE = $0e
GRAY3 = $0f
MCM = $08 ; bit#3 for multicolor character
; game
; ***************************************** REGISTER **********************************************
; vic
MOBX = $00 ; mob pos
MOBY = $01
MOBMSB = $10
MODEY = $11 ; mode
RASTER = $12
MOBENA = $15
MCMCSX = $16
MOBYEX = $17
MEMPT = $18
IRQ = $19 ; irq
EIRQ = $1a
MOBPRI = $1b ; mob
MOBMC = $1c
MOBXEX = $1d
MOBMOB = $1e
MOBBGR = $1f
EXTCOL = $20 ; colors
BGRCOL = $21
BGRCO1 = $22
BGRCO2 = $23
BGRCO3 = $24
MOBMC0 = $25
MOBMC1 = $26
MOBCOL = $27
; sid
V1LO = $00 ; osc1
V1HI = $01
V1CTRL = $04
V1AD = $05
V1SR = $06
V2LO = $07 ; osc2
V2HI = $08
V2CTRL = $0b
V2AD = $0c
V2SR = $0d
V3LO = $0e ; osc3
V3HI = $0f
V3CTRL = $12
V3AD = $13
V3SR = $14
FCLO = $15 ; filter
FCHI = $16
RESFIL = $17
MODVOL = $18 ; mode / volume
RANDOM = $1b ; osc3 out
ENV3 = $1c
; cia
PRA = $0 ; Data reg A
PRB = $1 ; Data reg B
DDRA = $2 ; Direction reg a
DDRB = $3 ; Direction reg b
TALO = $4 ; Timer A low byte
TAHI = $5 ; Timer A high byte
TBLO = $6 ; Timer B low byte
TBHI = $7 ; Timer B high byte
TOD10 = $8 ; 10ths of seconds
TODSEC = $9 ; Seconds
TODMIN = $A ; Minutes
TODHR = $B ; Hours
SDR = $C ; Serial data register
ICR = $D ; Interrupt control register
CRA = $E ; Control register A
CRB = $F ; Control register B
; tpi
PA = $0 ; Port register A
PB = $1 ; Port register B
PC = $2 ; Port register C
LIR = $2 ; Interrupt latch register mc=1
DDPA = $3 ; Data direction register A
DDPB = $4 ; Data direction register B
DDPC = $5 ; Data direction register C
MIR = $5 ; Interrupt mask register mc=1
CREG = $6 ; Control reg: #0 mc=IRQ mode / #1 ip= IRQ parity / #2-3 edge i3,i4
AIR = $7 ; Active interrupt register
; ************************************** P500 ADDRESSES *******************************************
!addr CodeBank = $00 ; code bank register
!addr IndirectBank = $01 ; indirect bank register
!addr ScreenRAMbase = $c400 ; screen matrix
!addr SpritePointer = $c7f8 ; sprite data pointer
!addr CharROMbase = $c000 ; Character ROM
!addr ColorRAMbase = $d400 ; Color RAM
!addr VICbase = $d800 ; VIC
!addr SIDbase = $da00 ; SID
!addr CIAbase = $dc00 ; CIA
!addr TPI1base = $de00 ; TPI1
!addr TPI2base = $df00 ; TPI2
!addr HW_IRQ = $fffe ; System IRQ Vector
!addr HW_NMI = $fffa ; System NMI Vector
SH = >ScreenRAMbase ; Highbyte Screen RAM base
; ***************************************** ZERO PAGE *********************************************
!addr score = $02 ; 3bytes score
!addr highscore = $05 ; 3bytes highscore
!addr key = $08 ; pressed key/joystick
!addr ptr1 = $09 ; 16bit pointer
!addr ptr2 = $0b ; 16bit pointer
!addr temp1 = $0d ; temporary screen copy, debounce, indirect adaptation
!addr temp2 = $0e ; temporary screen copy, indirect adaptation
; double usage: collision
!addr coll1_x = $09
!addr coll1_y = $0b
!addr coll2_x = $0c
!addr coll2_y = $0e
!addr temp3 = $0f ; temporary collision
!addr temp4 = $10 ; temporary collision, move monster
!addr temp5 = $11 ; temporary collision
!addr data_ctr = $12 ; data counter
!addr timer = $13 ; game timer - inc with every irq / CIA timer b
!addr color = $14
!addr sprite_state = $1e ; 8 bytes state: $ff=off, $00=on, $80-$d0 player explosion
; start-screen: monster direction
!addr finished = $26 ; sum of all targets to go: 0 = level finished
!addr ttarget = $27 ; targets
!addr players = $28 ; lives
!addr state = $29 ; state 0=new level, neg.=player died
!addr timer2 = $2a
!addr delay = $2b ; delay for monster movment on satrt screen
!addr fire = $2c ; fire pressed bit#7=1
!addr worrior_shot_dir = $2d
!addr worrior_dir = $2e
!addr sprite_xreg = $30 ; actual sprite x register
!addr sprite_xmsb = $31 ; actual sprite x-msb
!addr sprite_dir = $32 ; actual sprite direction 1-4
!addr move_dir = $35
!addr draw_column = $36 ; draw column
!addr draw_line = $37 ; draw line
!addr draw_char = $38 ; draw char/tile
!addr draw_ptr = $39 ; pointer to print maze on screen
!addr level = $3b ; level 1-4
!addr maze_column = $3c ; actual maze column
!addr maze_line = $3d ; actual maze line
!addr move_x = $3f ; sprite mov sub x
!addr move_y = $40 ; sprite mov sub y
!addr move_xmsb = $41 ; sprite mov sub xmsb
!addr mazedata_ptr = $44 ; pointer to mazedata
!addr joykey_dir = $46 ; worrior direction after joy/key check
!addr target = $47 ; 4 bytes targets to destroy
!addr hit_target3 = $4b ; neg after hit target 3
!addr move = $4c ; movement 0=none, 1=up, 2=down, 3=left, 4=right
!addr sprite_data = $4d ; 8 bytes sprite data
!addr collision_mob = $55 ; mob-mob collision
!addr collision_bgr = $56 ; mob-bgr collision
!addr monster_value = $57 ; 5 bytes monster values
!addr monster_cnt = $60 ; 5 bytes monster counter
!addr monster_dir = $68 ; 5 bytes monster directions
!addr sound_no = $6f
!addr sound_ptr = $70 ; pointer to sound data
!addr sound1 = $72
!addr sound2 = $73
!addr sound3 = $74
!addr sound4 = $75
!addr bonus_player = $76
!addr monster_shot_dir = $77
!addr cheat = $78 ; >0 = never die
; ************************************** P500 ZERO PAGE *******************************************
!addr ColorRAM0 = $e6
!addr ColorRAM1 = $e8
!addr ColorRAM2 = $ea
!addr ColorRAM3 = $ec
!addr VIC = $ee
!addr VIC_MOBY = $f0
!addr VIC_MOBCOL = $f2
!addr SID = $f4
!addr CIA = $f6
!addr TPI1 = $f8
!addr TPI2 = $fa
; ****************************************** MACROS ***********************************************
; ***************************************** ZONE CODE *********************************************
!zone code
!initmem FILL
*= $e000
; init
start: sei ; disable interrupts
cld
ldx #$ff ; init stack
txs
; clear ram
ldx #$00
txa
clramlp:sta $02,x ; zp
sta $0200,x ; page 2
sta $0300,x ; page 3
inx
bne clramlp
jsr Init ; init IO Pointer, IO-regs
; init vic regs
ldy #0
viclp: lda VICRegs,y
sta (VIC),y
iny
cpy #SIDRegs-VICRegs
bne viclp
; init sid regs
ldy #0
sidlp: lda SIDRegs,y
sta (SID),y
iny
cpy #Maze1-SIDRegs
bne sidlp
cli ; enable irq
StartNew:
jsr StartScreen ; shows start screen and waits for F1
jsr InitGame ; reset score, level, init lives and sprite colors
NextLevel:
jsr SetupGame ; inc level, setup targets, init sprite states, state = 0
TryAgain:
jsr SetupGameScreen ; draw game screen
jsr SetupWorrior ; setup player sprite
lda #$1f
ldy #MODVOL
sta (SID),y ; full volume, filter low pass
ldx #1
lda state
bpl newlev ; start sound 1, if new level (state=0)
ldx #2 ; if not, start with sound 2
newlev: txa
jsr PlaySound ; play start sound
GameLoop:
lda timer
and #$fc
bne GameLoop ; wait 1 loop of timer
jsr CopySpritePointer ; copies all sprites data pointers to the vic pointers
ldy #MOBMOB
lda (VIC),y
sta collision_mob ; save mob-mob collision
iny ; MOBBGR
lda (VIC),y
sta collision_bgr ; save mob-bgr collision
inc timer2 ; inc timer2
lda timer2
bne nosound ; skip if not time for sound
inc delay ; inc delay
lda #$05
cmp delay
bne nosound ; skip if not time for sound
lda #2
jsr PlaySound ; Play sound 2
dec state ; state = neg for sound 2
nosound:lda delay
cmp #$10
bcc slowmon ; slow monsters
jsr MoveMonsters ; move monsters extra for fast-mode
slowmon:jsr WorriorShot ; check and move worrior shot
jsr MoveWorrior ; move worrior
jsr MoveMonsters ; move monsters
jsr StartMonsters ; check if monsters are off and start new monsters
jsr MonsterShot ; start monster shot ?
jsr MoveMonsterShot ; move monster shot and disable if reaching wall
jsr CheckCollision ; check for hits
jsr CheckExplosions ; Explosions: switch patterns, sound, score, finished ?
jsr UpdateSound ; update game sound
lda sprite_state
cmp #$ff
beq decwor ; branch if player sprite off (dead)
lda finished ; level finished ? (0=finished)
bne GameLoop ; next cycle
lda sprite_state
bmi decwor ; branch if player sprite off (dead)
jmp LevelFinished ; level finished
decwor: lda cheat ; check cheat
bne TryAgain ; never die
dec players ; decrease lives
bne TryAgain ; next try if live > 0
jmp GameOver ; game over
; -------------------------------------------------------------------------------------------------
; Checks F1 key for game start
; returns .a = 0 if F1 pressed
CheckF1Key:
ldx #$fe
jsr chkkey ; output .x to keyboard 0-7 and returns input in .x
txa
and #$01 ; isolate bit#1 F1
beq chkf1x ; F1 pressed
; check cheat
txa
and #$02 ; check ESC
bne chkbut
stx cheat ; never die
; check button
chkbut: ldy #PRA
lda (CIA),y ; load cia port a - bit#6 button joystick 1
and #$40 ; isolate button joy1 bit #6
chkf1x: rts
; -------------------------------------------------------------------------------------------------
; $e0db Check joystick and keyboard movement/fire
CheckJoyKey:
lda #$ff ; init key value
ldx #$7f
jsr chkkey
cpx #$2f ; check ',' = left
bne chkrght
and #$fb ; clear bit #2
bne chkx ; always
chkrght:cpx #$1f ; check '.' = right
bne chkup
and #$f7 ; clear bit #3
bne chkx ; always
chkup: ldx #$fd
jsr chkkey
cpx #$3b ; check 'Q' = up
bne chkdown
and #$fe ; clear bit #0
bne chkx ; always
chkdown:cpx #$37 ; check 'A' = down
bne chkfire
and #$fd ; clear bit #1
bne chkx ; always
chkfire:ldx #$bf
jsr chkkey
cpx #$1f ; check spc = fire
bne chkx
and #$bf ; clear bit #6
chkx: sta key ; store key
jmp chkjoy
; check tpi2
chkkey: pha ; remember key var
txa ; move output key value to .a
ldy #PB
sta (TPI2),y ; set TPI2 port B keyboard out 0-7
iny ; pc
debounc:lda (TPI2),y ; load TPI2 port C
sta temp1
lda (TPI2),y
cmp temp1
bne debounc ; debounce
and #$3f ; isolate keyboard bits 0-5
tax ; key input to .x
pla ; restore key var
rts
; check joystick
chkjoy: ldy #PRA
lda (CIA),y ; load cia port a - bit#6 button joystick 1
ora #$bf ; set all other bits
sta temp1
iny ; prb
lda (CIA),y ; load cia port b - bit#0-3 joystick 1 movement
ora #$f0 ; set other bit
and temp1 ; and button
and key ; and pressed key (bit# = 0)
; store joystick/keyboard movement/fire
ldx #0 ; direction var
tay
and #$40 ; check fire
bne jkdown
lda #$80
sta fire ; store fire
bne jkx
jkdown: tya
and #$02 ; check down
bne jkup
ldx #DOWN
bne jkx
jkup: tya
and #$01 ; check up
bne jkleft
ldx #UP
bne jkx
jkleft: tya
and #$04 ; check left
bne jkright
ldx #LEFT
bne jkx
jkright:tya
and #$08 ; check right
bne jkx
ldx #RIGHT
jkx: stx joykey_dir ; store move direction
rts
; -------------------------------------------------------------------------------------------------
; $e170 Game Cycle: do .x cycles
GameUpdate:
lda timer
and #$fc
bne GameUpdate ; wait timer
tya ; save regs
pha
txa
pha
jsr UpdateSound ; update sound
pla ; restore regs
tax
pla
tay
guwait: lda timer
and #$fc
bne guwait ; wait timer
dex
bne GameUpdate ; next cyle if .x > 0
rts
; -------------------------------------------------------------------------------------------------
; $e187 Clears screen with color
ClearScreen:
ldy #$00
clscrlp:lda color ; color
sta (ColorRAM0),y
sta (ColorRAM1),y
sta (ColorRAM2),y
sta (ColorRAM3),y
lda #$00 ; space
sta ScreenRAMbase,y
sta ScreenRAMbase+$100,y
sta ScreenRAMbase+$200,y
sta ScreenRAMbase+$2e8,y
iny
bne clscrlp
rts
; -------------------------------------------------------------------------------------------------
; $e1a9 Copies all sprites data pointers to the vic pointers
CopySpritePointer:
ldx #8 ; 8 sprites
cpsprlp:lda sprite_data-1,x
sta SpritePointer-1,x ; store pointer
dex
bne cpsprlp
; check pointers
ldx #8 ; 8 sprites
chksplp:lda sprite_data-1,x
cmp SpritePointer-1,x
bne CopySpritePointer ; copy again if not copied
dex
bne chksplp ; check next
rts
; -------------------------------------------------------------------------------------------------
; $e1c0 Copies data from xy to address in first two bytes till $ff
; $fd = new line, $fe = new target address, $ff = end
ScreenCopy: ; copies from .x, .y
stx ptr1
sty ptr1+1
scrnewt:ldy #0 ; set pointer1 to new source
sty temp2
tya ; clear .a
ora (ptr1),y
sta ptr2
tya ; clear .a
iny
ora (ptr1),y
sta ptr2+1
scrcplp:iny
lda #$00 ; clear .a
ora (ptr1),y ; load data byte
cmp #$ff
beq scrcpyx ; $ff = end
cmp #$fe
beq scrtarg ; $fe = new target address
cmp #$fd
beq scrline
sty temp1
pha ; save data
clc
lda ptr2 ; calc ptr2+temp2
adc temp2
sta draw_ptr
lda ptr2+1
adc #0 ; add carry
sta draw_ptr+1
pla
ldx #0
sta (draw_ptr,x)
inc temp2
ldy temp1
lda move
beq scrcplp ; next if no movement
ldx #10
jsr GameUpdate ; 10 game updates
jmp scrcplp
; $e1f6 byte $fe = new target address
scrtarg:iny
clc
tya
adc ptr1 ; add counter .y to pointer 1
sta ptr1
lda ptr1+1
adc #$00
sta ptr1+1
jmp scrnewt ; copy to new target address
; $e206 byte $fd = new line (target +40)
scrline:clc
lda ptr2
adc #40 ; pointer2 +40 = new line
sta ptr2
lda ptr2+1
adc #$00
sta ptr2+1
lda #$00
sta temp2
beq scrcplp ; always next
scrcpyx:lda #0
sta move ; store no movement
rts
; -------------------------------------------------------------------------------------------------
; $e21e Draw game screen
SetupGameScreen:
lda #CYAN
sta color
jsr ClearScreen ; clear game screen
ldx #<GameScreenData
ldy #>GameScreenData
jsr ScreenCopy ; copy game screen
lda level
and #$03 ; maximum maze 3
asl ; x2 for mazedata address
tax
lda MazePointer,x ; init pointer to mazedata level 1-4
sta mazedata_ptr
lda MazePointer+1,x
sta mazedata_ptr+1
; decode and print maze
lda #0
sta data_ctr ; reset data counter
sta maze_line ; reset screen line
sta maze_column ; reset screem column
mazelp: ldy data_ctr
lda #$00 ; clear .a
ora (mazedata_ptr),y ; load data byte
cmp #$19
bne mzchkv
jsr mzhtile ; draw horizontal line
mzchkv: cmp #$18
bne mzchkhv
jsr mzvtile ; draw vertical line
mzchkhv:cmp #$1a
bne mzblank
jsr mzhvtil ; draw h+v line
mzblank:inc data_ctr ; increase data pointer
lda #3
clc
adc maze_column ; add actual column + 3
sta maze_column ; ...and store to draw column
cmp #39
bne mazelp ; next field if not end of line
lda #0
sta maze_column ; reset column
lda #3
clc
adc maze_line ; add 3 lines
sta maze_line
cmp #21
bne mazelp ; repeat if < line 21
; print score
lda #$00
jsr AddScore ; print zero score
; print players
ldx players
stx draw_char ; store player char
lda #30
sta draw_column ; store column 30, line 24
lda #24
sta draw_line
jsr DrawMazeTile ; draw player count
; print highscore
ldx #$d0+5 ; set screen pointer to highscore
ldy #SH+3
stx ptr1
sty ptr1+1
ldy #$03
jsr PrintScore ; print highscore (score+3)
rts
; -------------------------------------------------------------------------------------------------
; $e29b Maze addresses level 1 - 4
MazePointer:
!word Maze1
!word Maze2
!word Maze3
!word Maze4
; -------------------------------------------------------------------------------------------------
; $e2a3 Draw 3x horizontal line
mzhtile:ldx #0
mzhlp: lda maze_line
clc
adc #2 ; add 2 lines
sta draw_line ; ...and store to draw line
txa
clc
adc maze_column ; load actual column
sta draw_column ; ...and add to draw column
lda #$2b
sta draw_char
jsr DrawMazeTile ; draw tile $2b
inx
cpx #3
bne mzhlp ; print 3 column
lda #$05
rts
; -------------------------------------------------------------------------------------------------
; $e2c1 Draw 3x vertical line
mzvtile:ldx #0
mzvlp: lda maze_column ; load actual column
sta draw_column ; ...and store to draw column
txa
clc
adc maze_line ; load actual line+carry
sta draw_line ; ...and store to draw line
lda #$2a
sta draw_char
jsr DrawMazeTile ; draw tile $2a
inx
cpx #3
bne mzvlp ; print 3 lines
lda #$05
rts
; -------------------------------------------------------------------------------------------------
; $e2dc Draw left-low corner
mzhvtil:jsr mzhtile ; draw 3x horizontal line
jsr mzvtile ; draw 3x vertical line
lda #2
clc
adc maze_line ; add actual line + 2
sta draw_line ; ...and store to draw line
lda maze_column
sta draw_column ; store actual column
lda #$2c
sta draw_char
jsr DrawMazeTile ; draw low-left corner 'L'-tile
rts
; -------------------------------------------------------------------------------------------------
; $e2f5 Reset score, level, init lives and sprite colors
InitGame:
ldy #0
sty score
sty score+1
sty score+2
sty level ; reset level
sty bonus_player ; clear bonus player
lda #LIVES ; 3 lives
sta players
lda #BLUE ; all sprites blue
ldy #MOBCOL
incollp:sta (VIC),y
iny
cpy #MOBCOL+8
bne incollp
rts
; -------------------------------------------------------------------------------------------------
; $e310 Inc level, setup targets, init sprite states
SetupGame:
lda #$00
tax
ldy #MOBENA
sta (VIC),y ; disable sprites
sg1elp: lda #$ff
sta sprite_state,x ; clear state for all sprites
inx
cpx #8
bne sg1elp
ldy #$00 ; clear timer
sty delay
sty timer2
sty state ; state = 0
inc level ; raise level (1-4)
ldx level
cpx #4 ; maximum 4
bcc levmax4
ldx #4
levmax4:lda TargetTable-1,x ; setup targets
sta ttarget
lda TargetTable-1+4,x
sta target
lda TargetTable-1+8,x
sta target+1
lda TargetTable-1+12,x
sta target+2
lda TargetTable-1+16,x
sta target+3
lda TargetTable-1+20,x
sta finished
lda #$00
sta hit_target3
rts
; -------------------------------------------------------------------------------------------------
; Targets level 1-4
TargetTable:
; Level 1 2 3 4
!byte $04, $05, $06, $06 ; Burwors
!byte $03, $04, $05, $06 ; Gorwors
!byte $02, $04, $06, $06 ; Thorwors
!byte $01, $02, $03, $04 ; Worloks
!byte $00, $01, $00, $02 ; Wizard Of Wars
!byte $0a, $10, $14, $18 ; Total monsters to kill in level
; -------------------------------------------------------------------------------------------------
; $e36b Setup worrior sprite
SetupWorrior:
lda #$e6 ; init worrior sprite
sta sprite_data
sta SpritePointer
lda #$03
sta worrior_dir
lda #$01 ; set worrior start position
ldy #MOBMSB
sta (VIC),y
lda #$37
ldy #MOBX
sta (VIC),y
lda #$ab
sta (VIC_MOBY),y
lda #$fd
sta sprite_data+7 ; set shot horizontal pattern
ldx #$ff
stx sprite_state+7 ; shot sprites off
stx sprite_state+6
inx
stx sprite_state ; player sprite on
stx worrior_shot_dir ; clear worrior shot dir
ldy #MOBENA
lda (VIC),y
ora #$01 ; enable worrior sprite
and #$7f ; disable player shot
sta (VIC),y
rts
; -------------------------------------------------------------------------------------------------
; $e39f Monster start positions
MonsterStartX:
!byte $35, $4d, $65, $7d, $95, $ad, $c5, $f5
; $e3a7
MonsterStartY:
!byte $7b, $63, $7b, $93, $ab, $c3, $7b, $ab
; -------------------------------------------------------------------------------------------------
; $e3af Level finished
LevelFinished:
lda #$00
ldy #MOBENA
sta (VIC),y ; disable sprites
ldx #<TextBonus3000
ldy #>TextBonus3000
jsr ScreenCopy ; print 'BONUS 3000'
lda #7
jsr PlaySound ; play bonus sound
lda #$30
jsr AddScore
ldx #0
jsr GameUpdate ; 1 game update
jmp NextLevel
TextBonus3000:
!byte $24, $05, $0c, $19, $18, $1e, $1c, $00 ; 'BONUS 3000'
!byte $04, $01, $01, $01, $ff
; Game over
GameOver:
ldx #2
chkhisc:lda highscore,x
cmp score,x ; check if new high score
bcc newhisc
bne nohisc
dex
bpl chkhisc
; new highscore
newhisc:lda score ; store new highscore
sta highscore
lda score+1
sta highscore+1
lda score+2
sta highscore+2
ldx #$d0+5 ; set screen ptr to highscore
ldy #SH+3
stx ptr1
sty ptr1+1
ldy #3
jsr PrintScore
; game over - no highscore
nohisc: lda #$00
ldy #MODVOL
sta (SID),y
inc move
ldx #<TextGameOver
ldy #>TextGameOver
jsr ScreenCopy ; print 'G A M E O V E R'
ldx #80
jsr GameUpdate ; do 80 Game updates
jmp StartNew ; start new
TextGameOver:
!byte $24,SH+1, $11, $00, $0b, $00, $17, $00
!byte $0f, $00, $00, $19, $00, $1f, $00, $0f
!byte $00, $1b, END
; Add and print score
AddScore:
clc
sed
adc score+1 ; add score
sta score+1
lda score+2
adc #0
sta score+2
cld
ldx #$c4+5 ; set screen pointer to score
ldy #SH+3
stx ptr1
sty ptr1+1
ldy #0 ; print score
; Print score
PrintScore:
ldx #0
pslp: lda score,y
and #$0f ; clear hinibble
clc
adc #1
sta (ptr1,x)
dec ptr1
lda score,y
lsr
lsr
lsr
lsr
clc
adc #1
sta (ptr1,x)
dec ptr1
iny
cpy #6 ; end highscore
beq chkbon
cpy #3 ; end score
bne pslp
; check bonus player
chkbon: lda score+2
cmp #2 ; check score
bcc psx ; not enough
lda bonus_player
bne psx ; already bonus player
inc bonus_player
inc players
ldx players
stx ScreenRAMbase+$03de ; print bonus player
lda #7
jsr PlaySound ; play bonus sound
psx: rts
; -------------------------------------------------------------------------------------------------
; $e474 Start screen - exit with F1 only
StartScreen:
lda #$00
ldy #MOBENA
sta (VIC),y ; disable all sprites
lda #BLUE
sta color
jsr ClearScreen ; clear screen with blue chars
lda #CYAN
ldy #EXTCOL
sta (VIC),y ; set ext cyan
lda #WHITE
iny
sta (VIC),y ; set bgr white
ldy #>StartScreenData
ldx #<StartScreenData
jsr ScreenCopy ; Copies start screen
ldx #$04
ssinspr:txa
asl
clc
adc #2 ; start with sprite 1
tay
lda #$d7 ; sprite start h pos
sta sprite_state+1,x ; set right direction = $d7
sta (VIC),y ; setup monsters sprites 1-5
lda StartScreenMonsterVpos,x
sta (VIC_MOBY),y
lda StartScreenMonsterData,x
sta SpritePointer+1,x
txa
clc
adc #MOBCOL+1 ; calc monster sprite color reg
tay
lda MonsterColorTable,x
sta (VIC),y
dex
bpl ssinspr ; setup next sprite
lda #$00
ldy #MOBMSB
sta (VIC),y ; clear sprite x-msb
lda #$3e
ldy #MOBENA
sta (VIC),y ; enable monsters
sssprlp:lda timer
and #$fc
bne sssprlp ; wait
sswait: lda timer
and #$fc
bne sswait ; wait
inc delay
lda delay
and #$3f ; delay next movement
bne sschkf1
; move monsters
ldx #4 ; move 5 monsters
ssright:txa
asl
clc
adc #2 ; start with sprite 1
tay
lda sprite_state+1,x
beq ssleft
lda (VIC),y
clc
adc #1 ; move monsters right
sta (VIC),y
cmp StartScreenMonsterRLimit,x ; check if right limit
bcc ssnxspr
lda #$00
sta sprite_state+1,x ; set left direction
cpx #3
beq ssnxspr ; skip if monster #3 (unidir monster)
inc SpritePointer+1,x ; turn monster sprite left
bne ssnxspr
ssleft: lda (VIC),y
sec
sbc #1 ; move monster left
sta (VIC),y
cmp #$d7
bcs ssnxspr ; skip if left limit not reached
sta sprite_state+1,x ; set right dir
cpx #3
beq ssnxspr ; skip if monster #3 (unidir monster)