-
Notifications
You must be signed in to change notification settings - Fork 29
/
erlang.vim
1536 lines (1343 loc) · 50.7 KB
/
erlang.vim
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
833
834
835
836
837
838
839
840
841
842
843
844
845
846
847
848
849
850
851
852
853
854
855
856
857
858
859
860
861
862
863
864
865
866
867
868
869
870
871
872
873
874
875
876
877
878
879
880
881
882
883
884
885
886
887
888
889
890
891
892
893
894
895
896
897
898
899
900
901
902
903
904
905
906
907
908
909
910
911
912
913
914
915
916
917
918
919
920
921
922
923
924
925
926
927
928
929
930
931
932
933
934
935
936
937
938
939
940
941
942
943
944
945
946
947
948
949
950
951
952
953
954
955
956
957
958
959
960
961
962
963
964
965
966
967
968
969
970
971
972
973
974
975
976
977
978
979
980
981
982
983
984
985
986
987
988
989
990
991
992
993
994
995
996
997
998
999
1000
" Vim indent file
" Language: Erlang (http://www.erlang.org)
" Author: Csaba Hoch <[email protected]>
" Contributors: Edwin Fine <efine145_nospam01 at usa dot net>
" Pawel 'kTT' Salata <[email protected]>
" Ricardo Catalinas Jiménez <[email protected]>
" Last Update: 2022-Sep-06
" License: Vim license
" URL: https://github.com/vim-erlang/vim-erlang-runtime
" Note About Usage:
" This indentation script works best with the Erlang syntax file created by
" Kreąimir Marľić (Kresimir Marzic) and maintained by Csaba Hoch.
" Notes About Implementation:
"
" - LTI = Line to indent.
" - The index of the first line is 1, but the index of the first column is 0.
" Initialization {{{1
" ==============
" Only load this indent file when no other was loaded
" Vim 7 or later is needed
if exists("b:did_indent") || version < 700
finish
else
let b:did_indent = 1
endif
setlocal indentexpr=ErlangIndent()
setlocal indentkeys+=0=end,0=of,0=catch,0=after,0=else,0=when,0=),0=],0=},0=>>
let b:undo_indent = "setl inde< indk<"
" Only define the functions once
if exists("*ErlangIndent")
finish
endif
let s:cpo_save = &cpo
set cpo&vim
" Logging library {{{1
" ===============
" Purpose:
" Logs the given string using the ErlangIndentLog function if it exists.
" Parameters:
" s: string
function! s:Log(s)
if exists("*ErlangIndentLog")
call ErlangIndentLog(a:s)
endif
endfunction
" Line tokenizer library {{{1
" ======================
" Indtokens are "indentation tokens". See their exact format in the
" documentation of the s:GetTokensFromLine function.
" Purpose:
" Calculate the new virtual column after the given segment of a line.
" Parameters:
" line: string
" first_index: integer -- the index of the first character of the segment
" last_index: integer -- the index of the last character of the segment
" vcol: integer -- the virtual column of the first character of the token
" tabstop: integer -- the value of the 'tabstop' option to be used
" Returns:
" vcol: integer
" Example:
" " index: 0 12 34567
" " vcol: 0 45 89
" s:CalcVCol("\t'\tx', b", 1, 4, 4) -> 10
function! s:CalcVCol(line, first_index, last_index, vcol, tabstop)
" We copy the relevant segment of the line, otherwise if the line were
" e.g. `"\t", term` then the else branch below would consume the `", term`
" part at once.
let line = a:line[a:first_index : a:last_index]
let i = 0
let last_index = a:last_index - a:first_index
let vcol = a:vcol
while 0 <= i && i <= last_index
if line[i] ==# "\t"
" Example (when tabstop == 4):
"
" vcol + tab -> next_vcol
" 0 + tab -> 4
" 1 + tab -> 4
" 2 + tab -> 4
" 3 + tab -> 4
" 4 + tab -> 8
"
" next_i - i == the number of tabs
let next_i = matchend(line, '\t*', i + 1)
let vcol = (vcol / a:tabstop + (next_i - i)) * a:tabstop
call s:Log('new vcol after tab: '. vcol)
else
let next_i = matchend(line, '[^\t]*', i + 1)
let vcol += next_i - i
call s:Log('new vcol after other: '. vcol)
endif
let i = next_i
endwhile
return vcol
endfunction
" Purpose:
" Go through the whole line and return the tokens in the line.
" Parameters:
" line: string -- the line to be examined
" string_continuation: bool
" atom_continuation: bool
" Returns:
" indtokens = [indtoken]
" indtoken = [token, vcol, col]
" token = string (examples: 'begin', '<quoted_atom>', '}')
" vcol = integer (the virtual column of the first character of the token;
" counting starts from 0)
" col = integer (counting starts from 0)
function! s:GetTokensFromLine(line, string_continuation, atom_continuation,
\tabstop)
let linelen = strlen(a:line) " The length of the line
let i = 0 " The index of the current character in the line
let vcol = 0 " The virtual column of the current character
let indtokens = []
if a:string_continuation
let i = matchend(a:line, '^\%([^"\\]\|\\.\)*"', 0)
if i ==# -1
call s:Log(' Whole line is string continuation -> ignore')
return []
else
let vcol = s:CalcVCol(a:line, 0, i - 1, 0, a:tabstop)
call add(indtokens, ['<string_end>', vcol, i])
endif
elseif a:atom_continuation
let i = matchend(a:line, "^\\%([^'\\\\]\\|\\\\.\\)*'", 0)
if i ==# -1
call s:Log(' Whole line is quoted atom continuation -> ignore')
return []
else
let vcol = s:CalcVCol(a:line, 0, i - 1, 0, a:tabstop)
call add(indtokens, ['<quoted_atom_end>', vcol, i])
endif
endif
while 0 <= i && i < linelen
let next_vcol = ''
" Spaces
if a:line[i] ==# ' '
let next_i = matchend(a:line, ' *', i + 1)
" Tabs
elseif a:line[i] ==# "\t"
let next_i = matchend(a:line, '\t*', i + 1)
" See example in s:CalcVCol
let next_vcol = (vcol / a:tabstop + (next_i - i)) * a:tabstop
" Comment
elseif a:line[i] ==# '%'
let next_i = linelen
" String token: "..."
elseif a:line[i] ==# '"'
let next_i = matchend(a:line, '\%([^"\\]\|\\.\)*"', i + 1)
if next_i ==# -1
call add(indtokens, ['<string_start>', vcol, i])
else
let next_vcol = s:CalcVCol(a:line, i, next_i - 1, vcol, a:tabstop)
call add(indtokens, ['<string>', vcol, i])
endif
" Quoted atom token: '...'
elseif a:line[i] ==# "'"
let next_i = matchend(a:line, "\\%([^'\\\\]\\|\\\\.\\)*'", i + 1)
if next_i ==# -1
call add(indtokens, ['<quoted_atom_start>', vcol, i])
else
let next_vcol = s:CalcVCol(a:line, i, next_i - 1, vcol, a:tabstop)
call add(indtokens, ['<quoted_atom>', vcol, i])
endif
" Keyword or atom or variable token or number
elseif a:line[i] =~# '[a-zA-Z_@0-9]'
let next_i = matchend(a:line,
\'[[:alnum:]_@:]*\%(\s*#\s*[[:alnum:]_@:]*\)\=',
\i + 1)
call add(indtokens, [a:line[(i):(next_i - 1)], vcol, i])
" Character token: $<char> (as in: $a)
elseif a:line[i] ==# '$'
call add(indtokens, ['$.', vcol, i])
let next_i = i + 2
" Dot token: .
elseif a:line[i] ==# '.'
let next_i = i + 1
if i + 1 ==# linelen || a:line[i + 1] =~# '[[:blank:]%]'
" End of clause token: . (as in: f() -> ok.)
call add(indtokens, ['<end_of_clause>', vcol, i])
else
" Possibilities:
" - Dot token in float: . (as in: 3.14)
" - Dot token in record: . (as in: #myrec.myfield)
call add(indtokens, ['.', vcol, i])
endif
" Equal sign
elseif a:line[i] ==# '='
" This is handled separately so that "=<<" will be parsed as
" ['=', '<<'] instead of ['=<', '<']. Although Erlang parses it
" currently in the latter way, that may be fixed some day.
call add(indtokens, [a:line[i], vcol, i])
let next_i = i + 1
" Three-character tokens
elseif i + 1 < linelen &&
\ index(['=:=', '=/='], a:line[i : i + 1]) != -1
call add(indtokens, [a:line[i : i + 1], vcol, i])
let next_i = i + 2
" Two-character tokens
elseif i + 1 < linelen &&
\ index(['->', '<<', '>>', '||', '==', '/=', '=<', '>=', '?=', '++',
\ '--', '::'],
\ a:line[i : i + 1]) != -1
call add(indtokens, [a:line[i : i + 1], vcol, i])
let next_i = i + 2
" Other character: , ; < > ( ) [ ] { } # + - * / : ? = ! |
else
call add(indtokens, [a:line[i], vcol, i])
let next_i = i + 1
endif
if next_vcol ==# ''
let vcol += next_i - i
else
let vcol = next_vcol
endif
let i = next_i
endwhile
return indtokens
endfunction
" TODO: doc, handle "not found" case
function! s:GetIndtokenAtCol(indtokens, col)
let i = 0
while i < len(a:indtokens)
if a:indtokens[i][2] ==# a:col
return [1, i]
elseif a:indtokens[i][2] > a:col
return [0, s:IndentError('No token at col ' . a:col . ', ' .
\'indtokens = ' . string(a:indtokens),
\'', '')]
endif
let i += 1
endwhile
return [0, s:IndentError('No token at col ' . a:col . ', ' .
\'indtokens = ' . string(a:indtokens),
\'', '')]
endfunction
" Stack library {{{1
" =============
" Purpose:
" Push a token onto the parser's stack.
" Parameters:
" stack: [token]
" token: string
function! s:Push(stack, token)
call s:Log(' Stack Push: "' . a:token . '" into ' . string(a:stack))
call insert(a:stack, a:token)
endfunction
" Purpose:
" Pop a token from the parser's stack.
" Parameters:
" stack: [token]
" token: string
" Returns:
" token: string -- the removed element
function! s:Pop(stack)
let head = remove(a:stack, 0)
call s:Log(' Stack Pop: "' . head . '" from ' . string(a:stack))
return head
endfunction
" Library for accessing and storing tokenized lines {{{1
" =================================================
" The Erlang token cache: an `lnum -> indtokens` dictionary that stores the
" tokenized lines.
let s:all_tokens = {}
let s:file_name = ''
let s:last_changedtick = -1
" Purpose:
" Clear the Erlang token cache if we have a different file or the file has
" been changed since the last indentation.
function! s:ClearTokenCacheIfNeeded()
let file_name = expand('%:p')
if file_name != s:file_name ||
\ b:changedtick != s:last_changedtick
let s:file_name = file_name
let s:last_changedtick = b:changedtick
let s:all_tokens = {}
endif
endfunction
" Purpose:
" Return the tokens of line `lnum`, if that line is not empty. If it is
" empty, find the first non-empty line in the given `direction` and return
" the tokens of that line.
" Parameters:
" lnum: integer
" direction: 'up' | 'down'
" Returns:
" result: [] -- the result is an empty list if we hit the beginning or end
" of the file
" | [lnum, indtokens]
" lnum: integer -- the index of the non-empty line that was found and
" tokenized
" indtokens: [indtoken] -- the tokens of line `lnum`
function! s:TokenizeLine(lnum, direction)
call s:Log('Tokenizing starts from line ' . a:lnum)
if a:direction ==# 'up'
let lnum = prevnonblank(a:lnum)
else " a:direction ==# 'down'
let lnum = nextnonblank(a:lnum)
endif
" We hit the beginning or end of the file
if lnum ==# 0
let indtokens = []
call s:Log(' We hit the beginning or end of the file.')
" The line has already been parsed
elseif has_key(s:all_tokens, lnum)
let indtokens = s:all_tokens[lnum]
call s:Log('Cached line ' . lnum . ': ' . getline(lnum))
call s:Log(" Tokens in the line:\n - " . join(indtokens, "\n - "))
" The line should be parsed now
else
" Parse the line
let line = getline(lnum)
let string_continuation = s:IsLineStringContinuation(lnum)
let atom_continuation = s:IsLineAtomContinuation(lnum)
let indtokens = s:GetTokensFromLine(line, string_continuation,
\atom_continuation, &tabstop)
let s:all_tokens[lnum] = indtokens
call s:Log('Tokenizing line ' . lnum . ': ' . line)
call s:Log(" Tokens in the line:\n - " . join(indtokens, "\n - "))
endif
return [lnum, indtokens]
endfunction
" Purpose:
" As a helper function for PrevIndToken and NextIndToken, the FindIndToken
" function finds the first line with at least one token in the given
" direction.
" Parameters:
" lnum: integer
" direction: 'up' | 'down'
" Returns:
" result: [[], 0, 0]
" -- the result is an empty list if we hit the beginning or end of
" the file
" | [indtoken, lnum, i]
" -- the content, lnum and token index of the next (or previous)
" indtoken
function! s:FindIndToken(lnum, dir)
let lnum = a:lnum
while 1
let lnum += (a:dir ==# 'up' ? -1 : 1)
let [lnum, indtokens] = s:TokenizeLine(lnum, a:dir)
if lnum ==# 0
" We hit the beginning or end of the file
return [[], 0, 0]
elseif !empty(indtokens)
" We found a non-empty line. If we were moving up, we return the last
" token of this line. Otherwise we return the first token if this line.
let i = (a:dir ==# 'up' ? len(indtokens) - 1 : 0)
return [indtokens[i], lnum, i]
endif
endwhile
endfunction
" Purpose:
" Find the token that directly precedes the given token.
" Parameters:
" lnum: integer -- the line of the given token
" i: the index of the given token within line `lnum`
" Returns:
" result = [] -- the result is an empty list if the given token is the first
" token of the file
" | indtoken
function! s:PrevIndToken(lnum, i)
call s:Log(' PrevIndToken called: lnum=' . a:lnum . ', i =' . a:i)
" If the current line has a previous token, return that
if a:i > 0
return [s:all_tokens[a:lnum][a:i - 1], a:lnum, a:i - 1]
else
return s:FindIndToken(a:lnum, 'up')
endif
endfunction
" Purpose:
" Find the token that directly succeeds the given token.
" Parameters:
" lnum: integer -- the line of the given token
" i: the index of the given token within line `lnum`
" Returns:
" result = [] -- the result is an empty list if the given token is the last
" token of the file
" | indtoken
function! s:NextIndToken(lnum, i)
call s:Log(' NextIndToken called: lnum=' . a:lnum . ', i =' . a:i)
" If the current line has a next token, return that
if len(s:all_tokens[a:lnum]) > a:i + 1
return [s:all_tokens[a:lnum][a:i + 1], a:lnum, a:i + 1]
else
return s:FindIndToken(a:lnum, 'down')
endif
endfunction
" ErlangCalcIndent helper functions {{{1
" =================================
" Purpose:
" This function is called when the parser encounters a syntax error.
"
" If we encounter a syntax error, we return
" g:erlang_unexpected_token_indent, which is -1 by default. This means that
" the indentation of the LTI will not be changed.
" Parameter:
" msg: string
" token: string
" stack: [token]
" Returns:
" indent: integer
function! s:IndentError(msg, token, stack)
call s:Log('Indent error: ' . a:msg . ' -> return')
call s:Log(' Token = ' . a:token . ', ' .
\' stack = ' . string(a:stack))
return g:erlang_unexpected_token_indent
endfunction
" Purpose:
" This function is called when the parser encounters an unexpected token,
" and the parser will return the number given back by UnexpectedToken.
"
" If we encounter an unexpected token, we return
" g:erlang_unexpected_token_indent, which is -1 by default. This means that
" the indentation of the LTI will not be changed.
" Parameter:
" token: string
" stack: [token]
" Returns:
" indent: integer
function! s:UnexpectedToken(token, stack)
call s:Log(' Unexpected token ' . a:token . ', stack = ' .
\string(a:stack) . ' -> return')
return g:erlang_unexpected_token_indent
endfunction
if !exists('g:erlang_unexpected_token_indent')
let g:erlang_unexpected_token_indent = -1
endif
" Purpose:
" Return whether the given line starts with a string continuation.
" Parameter:
" lnum: integer
" Returns:
" result: bool
" Example:
" f() -> % IsLineStringContinuation = false
" "This is a % IsLineStringContinuation = false
" multiline % IsLineStringContinuation = true
" string". % IsLineStringContinuation = true
function! s:IsLineStringContinuation(lnum)
if has('syntax_items')
return synIDattr(synID(a:lnum, 1, 0), 'name') =~# '^erlangString'
else
return 0
endif
endfunction
" Purpose:
" Return whether the given line starts with an atom continuation.
" Parameter:
" lnum: integer
" Returns:
" result: bool
" Example:
" 'function with % IsLineAtomContinuation = true, but should be false
" weird name'() -> % IsLineAtomContinuation = true
" ok. % IsLineAtomContinuation = false
function! s:IsLineAtomContinuation(lnum)
if has('syntax_items')
let syn_name = synIDattr(synID(a:lnum, 1, 0), 'name')
return syn_name =~# '^erlangQuotedAtom' ||
\ syn_name =~# '^erlangQuotedRecord'
else
return 0
endif
endfunction
" Purpose:
" Return whether the 'catch' token (which should be the `i`th token in line
" `lnum`) is standalone or part of a try-catch block, based on the preceding
" token.
" Parameters:
" lnum: integer
" i: integer
" Return:
" is_standalone: bool
function! s:IsCatchStandalone(lnum, i)
call s:Log(' IsCatchStandalone called: lnum=' . a:lnum . ', i=' . a:i)
let [prev_indtoken, _, _] = s:PrevIndToken(a:lnum, a:i)
" If we hit the beginning of the file, it is not a catch in a try block
if prev_indtoken == []
return 1
endif
let prev_token = prev_indtoken[0]
if prev_token =~# '^[A-Z_@0-9]'
let is_standalone = 0
elseif prev_token =~# '[a-z]'
if index(['after', 'and', 'andalso', 'band', 'begin', 'bnot', 'bor', 'bsl',
\ 'bsr', 'bxor', 'case', 'catch', 'div', 'maybe', 'not', 'or',
\ 'orelse', 'rem', 'try', 'xor'], prev_token) != -1
" If catch is after these keywords, it is standalone
let is_standalone = 1
else
" If catch is after another keyword (e.g. 'end') or an atom, it is
" part of try-catch.
"
" Keywords:
" - may precede 'catch': end
" - may not precede 'catch': else fun if of receive when
" - unused: cond let query
let is_standalone = 0
endif
elseif index([')', ']', '}', '<string>', '<string_end>', '<quoted_atom>',
\ '<quoted_atom_end>', '$.'], prev_token) != -1
let is_standalone = 0
else
" This 'else' branch includes the following tokens:
" -> == /= =< < >= > ?= =:= =/= + - * / ++ -- :: < > ; ( [ { ? = ! . |
let is_standalone = 1
endif
call s:Log(' "catch" preceded by "' . prev_token . '" -> catch ' .
\(is_standalone ? 'is standalone' : 'belongs to try-catch'))
return is_standalone
endfunction
" Purpose:
" This function is called when a begin-type element ('begin', 'case',
" '[', '<<', etc.) is found. It asks the caller to return if the stack
" if already empty.
" Parameters:
" stack: [token]
" token: string
" curr_vcol: integer
" stored_vcol: integer
" sw: integer -- number of spaces to be used after the begin element as
" indentation
" Returns:
" result: [should_return, indent]
" should_return: bool -- if true, the caller should return `indent` to Vim
" indent -- integer
function! s:BeginElementFoundIfEmpty(stack, token, curr_vcol, stored_vcol, sw)
if empty(a:stack)
if a:stored_vcol ==# -1
call s:Log(' "' . a:token . '" directly precedes LTI -> return')
return [1, a:curr_vcol + a:sw]
else
call s:Log(' "' . a:token .
\'" token (whose expression includes LTI) found -> return')
return [1, a:stored_vcol]
endif
else
return [0, 0]
endif
endfunction
" Purpose:
" This function is called when a begin-type element ('begin', 'case', '[',
" '<<', etc.) is found, and in some cases when 'after' and 'when' is found.
" It asks the caller to return if the stack is already empty.
" Parameters:
" stack: [token]
" token: string
" curr_vcol: integer
" stored_vcol: integer
" end_token: end token that belongs to the begin element found (e.g. if the
" begin element is 'begin', the end token is 'end')
" sw: integer -- number of spaces to be used after the begin element as
" indentation
" Returns:
" result: [should_return, indent]
" should_return: bool -- if true, the caller should return `indent` to Vim
" indent -- integer
function! s:BeginElementFound(stack, token, curr_vcol, stored_vcol, end_token, sw)
" Return 'return' if the stack is empty
let [ret, res] = s:BeginElementFoundIfEmpty(a:stack, a:token, a:curr_vcol,
\a:stored_vcol, a:sw)
if ret | return [ret, res] | endif
if a:stack[0] ==# a:end_token
call s:Log(' "' . a:token . '" pops "' . a:end_token . '"')
call s:Pop(a:stack)
if !empty(a:stack) && a:stack[0] ==# 'align_to_begin_element'
call s:Pop(a:stack)
if empty(a:stack)
return [1, a:curr_vcol]
else
return [1, s:UnexpectedToken(a:token, a:stack)]
endif
else
return [0, 0]
endif
else
return [1, s:UnexpectedToken(a:token, a:stack)]
endif
endfunction
" Purpose:
" This function is called when we hit the beginning of a file or an
" end-of-clause token -- i.e. when we found the beginning of the current
" clause.
"
" If the stack contains an '->' or 'when', this means that we can return
" now, since we were looking for the beginning of the clause.
" Parameters:
" stack: [token]
" token: string
" stored_vcol: integer
" lnum: the line number of the "end of clause" mark (or 0 if we hit the
" beginning of the file)
" i: the index of the "end of clause" token within its own line
" Returns:
" result: [should_return, indent]
" should_return: bool -- if true, the caller should return `indent` to Vim
" indent -- integer
function! s:BeginningOfClauseFound(stack, token, stored_vcol, lnum, i)
if !empty(a:stack) && a:stack[0] ==# 'when'
call s:Log(' BeginningOfClauseFound: "when" found in stack')
call s:Pop(a:stack)
if empty(a:stack)
call s:Log(' Stack is ["when"], so LTI is in a guard -> return')
return [1, a:stored_vcol + shiftwidth() + 2]
else
return [1, s:UnexpectedToken(a:token, a:stack)]
endif
elseif !empty(a:stack) && a:stack[0] ==# '->'
call s:Log(' BeginningOfClauseFound: "->" found in stack')
call s:Pop(a:stack)
if empty(a:stack)
call s:Log(' Stack is ["->"], so LTI is in function body -> return')
return [1, a:stored_vcol + shiftwidth()]
elseif a:stack[0] ==# ';'
call s:Pop(a:stack)
if !empty(a:stack)
return [1, s:UnexpectedToken(a:token, a:stack)]
endif
if a:lnum ==# 0
" Set lnum and i to be NextIndToken-friendly
let lnum = 1
let i = -1
else
let lnum = a:lnum
let i = a:i
endif
" Are we after a "-spec func() ...;" clause?
let [next1_indtoken, next1_lnum, next1_i] = s:NextIndToken(lnum, i)
if !empty(next1_indtoken) && next1_indtoken[0] =~# '-'
let [next2_indtoken, next2_lnum, next2_i] =
\s:NextIndToken(next1_lnum, next1_i)
if !empty(next2_indtoken) && next2_indtoken[0] =~# 'spec'
let [next3_indtoken, next3_lnum, next3_i] =
\s:NextIndToken(next2_lnum, next2_i)
if !empty(next3_indtoken)
let [next4_indtoken, next4_lnum, next4_i] =
\s:NextIndToken(next3_lnum, next3_i)
if !empty(next4_indtoken)
" Yes, we are.
call s:Log(' Stack is ["->", ";"], so LTI is in a "-spec" ' .
\'attribute -> return')
return [1, next4_indtoken[1]]
endif
endif
endif
endif
call s:Log(' Stack is ["->", ";"], so LTI is in a function head ' .
\'-> return')
return [1, a:stored_vcol]
else
return [1, s:UnexpectedToken(a:token, a:stack)]
endif
else
return [0, 0]
endif
endfunction
let g:erlang_indent_searchpair_timeout = 2000
" TODO
function! s:SearchPair(lnum, curr_col, start, middle, end)
call cursor(a:lnum, a:curr_col + 1)
let [lnum_new, col1_new] =
\searchpairpos(a:start, a:middle, a:end, 'bW',
\'synIDattr(synID(line("."), col("."), 0), "name") ' .
\'=~? "string\\|quotedatom\\|todo\\|comment\\|' .
\'erlangmodifier"',
\0, g:erlang_indent_searchpair_timeout)
return [lnum_new, col1_new - 1]
endfunction
function! s:SearchEndPair(lnum, curr_col)
return s:SearchPair(
\ a:lnum, a:curr_col,
\ '\C\<\%(case\|try\|begin\|receive\|if\|maybe\)\>\|' .
\ '\<fun\>\%(\s\|\n\|%.*$\|[A-Z_@][a-zA-Z_@]*\)*(',
\ '',
\ '\<end\>')
endfunction
" ErlangCalcIndent {{{1
" ================
" Purpose:
" Calculate the indentation of the given line.
" Parameters:
" lnum: integer -- index of the line for which the indentation should be
" calculated
" stack: [token] -- initial stack
" Return:
" indent: integer -- if -1, that means "don't change the indentation";
" otherwise it means "indent the line with `indent`
" number of spaces or equivalent tabs"
function! s:ErlangCalcIndent(lnum, stack)
let res = s:ErlangCalcIndent2(a:lnum, a:stack)
call s:Log("ErlangCalcIndent returned: " . res)
return res
endfunction
function! s:ErlangCalcIndent2(lnum, stack)
let lnum = a:lnum
let stored_vcol = -1 " Virtual column of the first character of the token that
" we currently think we might align to.
let mode = 'normal'
let stack = a:stack
let semicolon_abscol = ''
" Walk through the lines of the buffer backwards (starting from the
" previous line) until we can decide how to indent the current line.
while 1
let [lnum, indtokens] = s:TokenizeLine(lnum, 'up')
" Hit the start of the file
if lnum ==# 0
let [ret, res] = s:BeginningOfClauseFound(stack, 'beginning_of_file',
\stored_vcol, 0, 0)
if ret | return res | endif
return 0
endif
let i = len(indtokens) - 1
let last_token_of_line = 1
while i >= 0
let [token, curr_vcol, curr_col] = indtokens[i]
call s:Log(' Analyzing the following token: ' . string(indtokens[i]))
if len(stack) > 256 " TODO: magic number
return s:IndentError('Stack too long', token, stack)
endif
if token ==# '<end_of_clause>'
let [ret, res] = s:BeginningOfClauseFound(stack, token, stored_vcol,
\lnum, i)
if ret | return res | endif
if stored_vcol ==# -1
call s:Log(' End of clause directly precedes LTI -> return')
return 0
else
call s:Log(' End of clause (but not end of line) -> return')
return stored_vcol
endif
elseif stack == ['prev_term_plus']
if token =~# '[a-zA-Z_@#]' ||
\ token ==# '<string>' || token ==# '<string_start>' ||
\ token ==# '<quoted_atom>' || token ==# '<quoted_atom_start>'
call s:Log(' previous token found: curr_vcol + plus = ' .
\curr_vcol . " + " . plus)
return curr_vcol + plus
endif
elseif token ==# 'begin'
let [ret, res] = s:BeginElementFound(stack, token, curr_vcol,
\stored_vcol, 'end', shiftwidth())
if ret | return res | endif
" case EXPR of BRANCHES end
" if BRANCHES end
" try EXPR catch BRANCHES end
" try EXPR after BODY end
" try EXPR catch BRANCHES after BODY end
" try EXPR of BRANCHES catch BRANCHES end
" try EXPR of BRANCHES after BODY end
" try EXPR of BRANCHES catch BRANCHES after BODY end
" receive BRANCHES end
" receive BRANCHES after BRANCHES end
" maybe EXPR end
" maybe EXPR else BRANCHES end
" This branch is not Emacs-compatible
elseif (index(['of', 'receive', 'after', 'if', 'else'], token) != -1 ||
\ (token ==# 'catch' && !s:IsCatchStandalone(lnum, i))) &&
\ !last_token_of_line &&
\ (empty(stack) || stack ==# ['when'] || stack ==# ['->'] ||
\ stack ==# ['->', ';'])
" If we are after of/receive/etc, but these are not the last
" tokens of the line, we want to indent like this:
"
" % stack == []
" receive stored_vcol,
" LTI
"
" % stack == ['->', ';']
" receive stored_vcol ->
" B;
" LTI
"
" % stack == ['->']
" receive stored_vcol ->
" LTI
"
" % stack == ['when']
" receive stored_vcol when
" LTI
" stack = [] => LTI is a condition
" stack = ['->'] => LTI is a branch
" stack = ['->', ';'] => LTI is a condition
" stack = ['when'] => LTI is a guard
if empty(stack) || stack == ['->', ';']
call s:Log(' LTI is in a condition after ' .
\'"of/receive/after/if/else/catch" -> return')
return stored_vcol
elseif stack == ['->']
call s:Log(' LTI is in a branch after ' .
\'"of/receive/after/if/else/catch" -> return')
return stored_vcol + shiftwidth()
elseif stack == ['when']
call s:Log(' LTI is in a guard after ' .
\'"of/receive/after/if/else/catch" -> return')
return stored_vcol + shiftwidth()
else
return s:UnexpectedToken(token, stack)
endif
elseif index(['case', 'if', 'try', 'receive', 'maybe'], token) != -1
" stack = [] => LTI is a condition
" stack = ['->'] => LTI is a branch
" stack = ['->', ';'] => LTI is a condition
" stack = ['when'] => LTI is in a guard
if empty(stack)
" pass
elseif (token ==# 'case' && stack[0] ==# 'of') ||
\ (token ==# 'if') ||
\ (token ==# 'maybe' && stack[0] ==# 'else') ||
\ (token ==# 'try' && (stack[0] ==# 'of' ||
\ stack[0] ==# 'catch' ||
\ stack[0] ==# 'after')) ||
\ (token ==# 'receive')
" From the indentation point of view, the keyword
" (of/catch/after/else/end) before the LTI is what counts, so
" when we reached these tokens, and the stack already had
" a catch/after/else/end, we didn't modify it.
"
" This way when we reach case/try/receive/maybe (i.e. now),
" there is at most one of/catch/after/else/end token in the
" stack.
if token ==# 'case' || token ==# 'try' ||
\ (token ==# 'receive' && stack[0] ==# 'after') ||
\ (token ==# 'maybe' && stack[0] ==# 'else')
call s:Pop(stack)
endif
if empty(stack)
call s:Log(' LTI is in a condition; matching ' .
\'"case/if/try/receive/maybe" found')
let stored_vcol = curr_vcol + shiftwidth()
elseif stack[0] ==# 'align_to_begin_element'
call s:Pop(stack)
let stored_vcol = curr_vcol
elseif len(stack) > 1 && stack[0] ==# '->' && stack[1] ==# ';'
call s:Log(' LTI is in a condition; matching ' .
\'"case/if/try/receive/maybe" found')
call s:Pop(stack)
call s:Pop(stack)
let stored_vcol = curr_vcol + shiftwidth()
elseif stack[0] ==# '->'
call s:Log(' LTI is in a branch; matching ' .
\'"case/if/try/receive/maybe" found')
call s:Pop(stack)
let stored_vcol = curr_vcol + 2 * shiftwidth()
elseif stack[0] ==# 'when'
call s:Log(' LTI is in a guard; matching ' .
\'"case/if/try/receive/maybe" found')
call s:Pop(stack)
let stored_vcol = curr_vcol + 2 * shiftwidth() + 2
endif
endif
let [ret, res] = s:BeginElementFound(stack, token, curr_vcol,
\stored_vcol, 'end', shiftwidth())
if ret | return res | endif
elseif token ==# 'fun'
let [next_indtoken, next_lnum, next_i] = s:NextIndToken(lnum, i)
call s:Log(' Next indtoken = ' . string(next_indtoken))
if !empty(next_indtoken) && next_indtoken[0] =~# '^[A-Z_@]'
" The "fun" is followed by a variable, so we might have a named fun:
" "fun Fun() -> ok end". Thus we take the next token to decide
" whether this is a function definition ("fun()") or just a function
" reference ("fun Mod:Fun").
let [next_indtoken, _, _] = s:NextIndToken(next_lnum, next_i)
call s:Log(' Next indtoken = ' . string(next_indtoken))
endif
if !empty(next_indtoken) && next_indtoken[0] ==# '('
" We have an anonymous function definition
" (e.g. "fun () -> ok end")
" stack = [] => LTI is a condition
" stack = ['->'] => LTI is a branch
" stack = ['->', ';'] => LTI is a condition
" stack = ['when'] => LTI is in a guard
if empty(stack)
call s:Log(' LTI is in a condition; matching "fun" found')
let stored_vcol = curr_vcol + shiftwidth()
elseif len(stack) > 1 && stack[0] ==# '->' && stack[1] ==# ';'
call s:Log(' LTI is in a condition; matching "fun" found')
call s:Pop(stack)
call s:Pop(stack)