build.gradle

import groovy.json.JsonSlurper

plugins {
    id 'java-library'
    id 'de.undercouch.download' version '4.1.1'
    id "io.freefair.lombok" version "6.5.0.2"
}

group = 'com.unstoppabledomains'
archivesBaseName = 'resolution'

sourceCompatibility=JavaVersion.VERSION_1_8
targetCompatibility=JavaVersion.VERSION_1_8

repositories {
    jcenter()
}

java {
    withSourcesJar()
    withJavadocJar()
}

dependencies {
    implementation 'org.apache.commons:commons-lang3:3.11'
    implementation 'com.esaulpaugh:headlong:3.8.3'
    implementation 'com.google.code.gson:gson:2.8.6'
    implementation 'org.bouncycastle:bcprov-jdk15on:1.65.01'

    testImplementation 'org.junit.jupiter:junit-jupiter-api:5.7.1'
    testImplementation 'org.mock-server:mockserver-netty:5.11.2'
    testImplementation 'org.mock-server:mockserver-client-java:5.11.2'
    testImplementation 'org.mockito:mockito-core:2.19.0'
    testImplementation 'org.mockito:mockito-inline:2.19.0'
    testImplementation 'org.mockito:mockito-junit-jupiter:3.11.2'
    testRuntimeOnly 'org.junit.jupiter:junit-jupiter-engine:5.7.1'
}

test {
    useJUnitPlatform()
    testLogging {
        showStandardStreams = true
    }
}

task getVersion {
    def client = file('src/main/resources/com/unstoppabledomains/config/client/client.json')
    version = new JsonSlurper().parseText(client.text).'version'
}

task pullNetworkConfig(type: Download) {
    src 'https://raw.githubusercontent.com/unstoppabledomains/uns/main/uns-config.json'
    dest 'src/main/resources/com/unstoppabledomains/config/network'
}

task pullResolverKeys(type: Download) {
    src 'https://raw.githubusercontent.com/unstoppabledomains/uns/main/resolver-keys.json'
    dest 'src/main/resources/com/unstoppabledomains/config/knownRecords.json'
}

build {
    dependsOn pullNetworkConfig
    dependsOn pullResolverKeys
}