build.gradle

buildscript {
    ext.keystore = (project.hasProperty('androidKeystore') ?
            project.property('androidKeystore') : '/fake/path/to/keystore')
    ext.keystorePassword = (project.hasProperty('androidKeystorePassword') ?
            project.property('androidKeystorePassword') : 'fakepassword')
    ext.releaseKeyAlias = (project.hasProperty('androidReleaseKeyAlias') ?
            project.property('androidReleaseKeyAlias') : 'fakealias')
    ext.releaseKeyPassword = (project.hasProperty('androidReleaseKeyPassword') ?
            project.property('androidReleaseKeyPassword') : 'fakepassword')
    ext.firebaseAppId = (project.hasProperty('firebaseAppId') ?
            project.property('firebaseAppId') : 'fakeappid')

    ext.getPropertyValue =  { propertyKey ->
        def property  = System.getenv(propertyKey)
        if (property == null) {
            logger.log(LogLevel.INFO, "Could not locate $propertyKey as environment variable. " +
                    "Trying local.properties")
            Properties properties = new Properties()
            if (project.rootProject.file('local.properties').exists()) {
                properties.load(project.rootProject.file('local.properties').newDataInputStream())
                property = properties.getProperty(propertyKey)
            }
        }
        if (property == null) {
            logger.log(LogLevel.WARN, "$propertyKey unavailable.")
        }
        return property
    }

    repositories {
        google()
        mavenCentral()
        maven {
            url  "https://twilio.jfrog.io/artifactory/internal-releases"
            credentials {
                username "${getPropertyValue('ARTIFACTORY_USERNAME')}"
                password "${getPropertyValue('ARTIFACTORY_PASSWORD')}"
            }
            metadataSources {
                mavenPom()
                artifact()
            }
        }
    }
    dependencies {
        classpath 'com.android.tools.build:gradle:8.3.1'
        classpath "com.google.gms:google-services:4.4.2"
        classpath 'org.jetbrains.kotlin:kotlin-gradle-plugin:1.6.21'
        classpath 'com.google.firebase:firebase-crashlytics-gradle:3.0.2'
        classpath 'com.google.dagger:hilt-android-gradle-plugin:2.40.1'
        classpath 'com.google.firebase:firebase-appdistribution-gradle:5.0.0'
    }
}

plugins {
    id "com.diffplug.spotless" version '6.19.0'
}
apply plugin: "com.diffplug.spotless"
spotless {
    format 'misc', {
        target '**/*.gradle', '**/*.md', '**/.gitignore'

        trimTrailingWhitespace()
        indentWithSpaces()
        endWithNewline()
    }
    java {
        target '**/*.java'
        googleJavaFormat().aosp()
    }
    kotlin {
        target '**/*.kt'
        ktlint()
    }
}

task incrementVersionCode {
    description = 'Increment the version code'
    group = 'Git'

    doLast {
        def githubToken = System.getenv("GITHUB_TOKEN")
        def repoSlug = "${System.env.CIRCLE_PROJECT_USERNAME}/${System.env.CIRCLE_PROJECT_REPONAME}"
        def gitRef = "https://${githubToken}@github.com/${repoSlug}.git"
        def remote = "upstream"
        def pushNullFile = new FileOutputStream("/dev/null")
        def versionCode = project.property("versionCode")
        def versionCodeTag = "v0.$versionCode"
        def newVersionCode = (versionCode as Integer) + 1
        // Create build directory if not created
        if (!getLayout().getBuildDirectory().asFile.get().exists()) {
            getLayout().getBuildDirectory().asFile.get().mkdir()
        }

        exec {
            workingDir "${rootDir}"
            commandLine "git", "remote", "add", "${remote}", "${gitRef}"
            // Ignore exit value because remote may have been added in previous task
            ignoreExitValue true
        }

        exec {
            workingDir "${rootDir}"
            commandLine "git", "fetch", "${remote}"
        }

        exec {
            workingDir "${rootDir}"
            commandLine "git", "tag", "-a", "$versionCodeTag", "-m", "$versionCodeTag"
        }

        exec {
            workingDir "${rootDir}"
            commandLine "sed",
                    "s@versionCode=.*@versionCode=${newVersionCode}@",
                    "gradle.properties"
            standardOutput new FileOutputStream("${buildDir}/gradle.properties")
        }

        exec {
            workingDir "${rootDir}"
            commandLine "mv", "${buildDir}/gradle.properties", "gradle.properties"
        }

        exec {
            workingDir "${rootDir}"
            commandLine "echo", "New version code:"
        }

        exec {
            workingDir "${rootDir}"
            commandLine "cat", "gradle.properties"
        }

        exec {
            workingDir "${rootDir}"
            commandLine "git", "add", "gradle.properties"
        }

        exec {
            workingDir "${rootDir}"
            commandLine "git", "commit", "gradle.properties", "-m", "Bump version code [skip ci]"
        }

        exec {
            workingDir "${rootDir}"
            commandLine "git", "push", "--quiet", "${remote}", "${System.env.CIRCLE_BRANCH}"
            standardOutput pushNullFile
        }

        exec {
            workingDir "${rootDir}"
            commandLine "git", "push", "--quiet", "${remote}", "$versionCodeTag"
            standardOutput pushNullFile
        }
    }
}

allprojects {
    repositories {
        google()
        mavenCentral()
        maven {
            url 'https://oss.jfrog.org/artifactory/libs-snapshot/'
        }
        maven {
            url  "https://twilio.jfrog.io/artifactory/internal-releases"
            credentials {
                username "${getPropertyValue('ARTIFACTORY_USERNAME')}"
                password "${getPropertyValue('ARTIFACTORY_PASSWORD')}"
            }
            metadataSources {
                mavenPom()
                artifact()
            }
        }
        maven {
            url 'https://jitpack.io'
        }
        maven {
            url = uri("https://oss.sonatype.org/content/repositories/snapshots")
        }
    }
}