-
Notifications
You must be signed in to change notification settings - Fork 0
/
flake.nix
226 lines (191 loc) · 6.03 KB
/
flake.nix
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
{
description = ''
Reproducible and Deployable Asciidoctor Template:
https://github.com/trueNAHO/asciidoctor.nix
'';
inputs = {
flakeUtils.url = "github:numtide/flake-utils";
nixpkgs.url = "github:NixOS/nixpkgs/nixos-unstable";
preCommitHooks = {
inputs = {
nixpkgs-stable.follows = "preCommitHooks/nixpkgs";
nixpkgs.follows = "nixpkgs";
};
url = "github:cachix/pre-commit-hooks.nix";
};
revealJs = {
flake = false;
url = "github:hakimel/reveal.js";
};
};
outputs = {
self,
flakeUtils,
nixpkgs,
preCommitHooks,
revealJs,
...
}:
flakeUtils.lib.eachDefaultSystem (
system: let
packagesExcludingDefaults =
builtins.removeAttrs
self.packages.${system}
["default" "defaultExternal" "defaultLocal"];
pkgs = nixpkgs.legacyPackages.${system};
in {
checks =
(
pkgs.lib.attrsets.concatMapAttrs
(k: v: {"${k}Package" = v;})
packagesExcludingDefaults
)
// {
preCommitHooks = preCommitHooks.lib.${system}.run {
hooks = {
alejandra = {
enable = true;
settings.verbosity = "quiet";
};
typos.enable = true;
yamllint.enable = true;
};
src = ./.;
};
};
devShells.default = pkgs.mkShell {
inherit (self.checks.${system}.preCommitHooks) shellHook;
packages = with pkgs;
[asciidoctor-with-extensions bundix]
++ [self.checks.${system}.preCommitHooks.enabledPackages];
};
packages = let
asciidoctor = {
command,
extraOptions ? {},
inputFile ? "main.adoc",
name,
out ? "${builtins.placeholder "out"}/share/doc",
outputFile,
src ? ./src,
}:
pkgs.stdenv.mkDerivation ({
inherit src;
buildPhase = ''
${pkgs.lib.removeSuffix "\n" command} \
--attribute ditaa-format=svg \
--attribute mathematical-format=svg \
--attribute plantuml-format=svg \
--destination-dir "${out}" \
--out-file "${outputFile}" \
"${inputFile}"
'';
installPhase = ''mkdir --parents "$out" "${out}"'';
name = packageName name;
nativeBuildInputs = with pkgs; [
asciidoctor-with-extensions
graphviz
];
}
// extraOptions);
asciidoctorRequire =
pkgs.lib.concatMapStringsSep
" "
(library: "--require asciidoctor-${library}")
["diagram" "mathematical"];
packageName = name: "truenaho-asciidoctor-nix-${name}";
presentation = {
attribute,
name,
outputFile,
}:
asciidoctor {
inherit name outputFile;
command = ''
bundle \
exec \
asciidoctor-revealjs \
--attribute revealjsdir=${attribute}
'';
extraOptions.nativeBuildInputs = [
(
pkgs.bundlerEnv
{
gemdir = ./.;
name = packageName "bundler-env";
}
)
];
};
in {
default = pkgs.buildEnv {
name = packageName "default";
paths = pkgs.lib.attrsets.attrValues packagesExcludingDefaults;
};
defaultExternal = pkgs.buildEnv {
name = packageName "default-external";
paths = pkgs.lib.attrsets.attrValues (
pkgs.lib.attrsets.filterAttrs
(k: _: k != "presentationLocal")
packagesExcludingDefaults
);
};
defaultLocal = pkgs.buildEnv {
name = packageName "default-local";
paths = pkgs.lib.attrsets.attrValues (
pkgs.lib.attrsets.filterAttrs
(k: _: k != "presentationExternal")
packagesExcludingDefaults
);
};
docbook = asciidoctor {
command = ''
${pkgs.asciidoctor.meta.mainProgram} ${asciidoctorRequire}
'';
name = "docbook";
outputFile = "main.xml";
};
html = asciidoctor {
command = ''
${pkgs.asciidoctor.meta.mainProgram} ${asciidoctorRequire}
'';
name = "html";
outputFile = "index.html";
};
manpage = let
sectionNumber = toString 7;
in
asciidoctor {
command = ''
${pkgs.asciidoctor.meta.mainProgram} \
--backend manpage \
${asciidoctorRequire}
'';
extraOptions.outputs = ["out" "man"];
name = "manpage";
out = "${
builtins.placeholder "man"
}/share/man/man${sectionNumber}";
outputFile = "main.${sectionNumber}";
};
pdf = asciidoctor {
command = ''
${pkgs.asciidoctor.meta.mainProgram}-pdf ${asciidoctorRequire}
'';
name = "pdf";
outputFile = "main.pdf";
};
presentationExternal = presentation {
attribute = "https://cdn.jsdelivr.net/npm/[email protected]";
name = "presentation-external";
outputFile = "presentation_external.html";
};
presentationLocal = presentation {
attribute = revealJs.outPath;
name = "presentation-local";
outputFile = "presentation_local.html";
};
};
}
);
}