new file: Math/gaussian_integers.sf

Author: trizen

Math/gaussian_integers.sf

@@ -0,0 +1,95 @@
+#!/usr/bin/ruby
+
+# Simple implementation of Gaussian integers.
+
+# See also:
+#   https://en.wikipedia.org/wiki/Gaussian_integer
+
+class Gaussian(a, b) {   # represents: a + b*i
+
+    method to_s {
+        "Gaussian(#{a}, #{b})"
+    }
+
+    method reals {
+        (a,b)
+    }
+
+    method ==(Gaussian c) {
+        (a == c.a) && (b == c.b)
+    }
+
+    method conjugate {
+        Gaussian(a, -b)
+    }
+
+    method norm {
+        a*a + b*b
+    }
+
+    method add (Gaussian z) {
+        var (c,d) = (z.a, z.b)
+        Gaussian(a+c, b+d)
+    }
+
+    __CLASS__.alias_method(:add, '+')
+
+    method sub (Gaussian z) {
+        var (c,d) = (z.a, z.b)
+        Gaussian(a-c, b-d)
+    }
+
+    __CLASS__.alias_method(:sub, '-')
+
+    method mul (Gaussian z) {
+        var (c,d) = (z.a, z.b)
+        Gaussian(a*c - b*d, a*d + b*c)
+    }
+
+    __CLASS__.alias_method(:mul, '*')
+
+    method mod (Number m) {
+        Gaussian(a % m, b % m)
+    }
+
+    __CLASS__.alias_method(:mod, '%')
+
+    method pow(Number n) {
+        var x = self
+        var c = Gaussian(1, 0)
+
+        for bit in (n.digits(2)) {
+            c *= x if bit
+            x *= x
+        }
+
+        return c
+    }
+
+    __CLASS__.alias_method(:pow, '**')
+
+    method powmod(Number n, Number m) {
+
+        var x = self
+        var c = Gaussian(1, 0)
+
+        for bit in (n.digits(2)) {
+            (c *= x) %= m if bit        #=
+            (x *= x) %= m               #=
+        }
+
+        return c
+    }
+}
+
+var a = Gaussian(3,4)**10
+var b = Gaussian(3,4).powmod(97, 1234)
+
+say a
+say b
+
+# Run some tests
+assert_eq([a.reals], [reals(Gauss(3,4)**10)])
+assert_eq([b.reals], [reals(Gauss(3,4).powmod(97, 1234))])
+assert_eq([reals(a+b)], [reals(Gauss(reals(a)) + Gauss(reals(b)))])
+assert_eq([reals(a-b)], [reals(Gauss(reals(a)) - Gauss(reals(b)))])

Math/tribonacci_primality_test.sf

@@ -32,6 +32,9 @@
 # Several counter-examples to the strong version (with possible gaps):
 #   29111881, 213035761, 1312332001, 1750412161, 8585937361, 9856290601, 19036199881, 26244842401, 35252113601, 39897898921, 58318467481, ...
 
+# See also:
+#   https://trizenx.blogspot.com/2020/01/primality-testing-algorithms.html
+
 # Matrix for p == {1,3} (mod 8)
 const A123 = Matrix(
                 [1, 0, 0],

README.md

@@ -229,6 +229,7 @@ A nice collection of day-to-day Sidef scripts.
     * [Gamma function](./Math/gamma_function.sf)
     * [Gauss logarithm approx](./Math/gauss_logarithm_approx.sf)
     * [Gaussian elimination GF2 matrix](./Math/gaussian_elimination_GF2_matrix.sf)
+    * [Gaussian integers](./Math/gaussian_integers.sf)
     * [Generalized continued fraction](./Math/generalized_continued_fraction.sf)
     * [Generalized continued fraction parts iter](./Math/generalized_continued_fraction_parts_iter.sf)
     * [Generalized expansion](./Math/generalized_expansion.sf)