-
Notifications
You must be signed in to change notification settings - Fork 0
/
flake.nix
127 lines (111 loc) · 4.18 KB
/
flake.nix
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
{
description = "Stryke Force Website built using poetry2nix";
inputs.nixpkgs.url = "github:NixOS/nixpkgs/nixos-unstable";
inputs.flake-utils.url = "github:numtide/flake-utils";
inputs.poetry2nix = {
url = "github:nix-community/poetry2nix";
inputs.nixpkgs.follows = "nixpkgs";
};
outputs = { self, nixpkgs, flake-utils, poetry2nix }:
let
version = "4.2.0"; # also update pyproject.toml
in
flake-utils.lib.eachDefaultSystem
(system:
let
pkgs = nixpkgs.legacyPackages.${system};
poetry2nixPkgs = poetry2nix.lib.mkPoetry2Nix { inherit pkgs; };
inherit (poetry2nixPkgs) mkPoetryEnv mkPoetryApplication;
inherit (pkgs.stdenv) mkDerivation;
inherit (pkgs) writeShellApplication;
inherit (pkgs.lib) lists;
overrides = poetry2nixPkgs.defaultPoetryOverrides.extend
(self: super: {
opencv-python = super.opencv4;
pillow-heif = super.pillow-heif.overridePythonAttrs
(
old: {
# clang-16: error: argument unused during compilation: '-fno-strict-overflow'
NIX_CFLAGS_COMPILE = pkgs.lib.optionalString pkgs.stdenv.cc.isClang "-Wno-unused-command-line-argument";
}
);
psycopg-c = super.psycopg-c.overridePythonAttrs
(
old: {
nativeBuildInputs = old.nativeBuildInputs ++ [ self.setuptools self.pkgs.postgresql_15 ];
}
);
});
in
{
packages = {
website = mkPoetryApplication {
pname = "strykeforce-website";
projectDir = self;
groups = [ "main" ];
inherit overrides;
patchPhase = ''
${pkgs.tailwindcss}/bin/tailwindcss -i website/static/css/base.css -o website/static/css/main.css --minify
'';
postInstall = ''
mkdir -p $out/bin/
cp -vf manage.py $out/bin/
'';
};
static = mkDerivation {
pname = "strykeforce-static";
inherit version;
src = self;
phases = "installPhase";
installPhase = ''
export DJANGO_SETTINGS_MODULE=website.settings.production
export SECRET_KEY=notsecret
export TBA_READ_KEY=
export EMAIL_HOST_USER=
export EMAIL_HOST_PASSWORD=
export STATIC_ROOT=$out
mkdir -p $out
${self.packages.${system}.website}/bin/manage.py collectstatic --no-input
'';
};
manage = writeShellApplication {
name = "strykeforce-manage";
text = ''
export DJANGO_SETTINGS_MODULE=website.settings.production
export SECRET_KEY=notsecret
export TBA_READ_KEY=
export EMAIL_HOST_USER=
export EMAIL_HOST_PASSWORD=
export STATIC_ROOT=${self.packages.${system}.static}
exec ${self.packages.${system}.website}/bin/manage.py "$@"
'';
};
devEnv = mkPoetryEnv {
projectDir = self;
groups = [ "main" "dev" ];
inherit overrides;
};
# refresh venv for Pycharm with: nix build .#venv -o venv
venv = self.packages.${system}.devEnv;
default = self.packages.${system}.website;
};
devShells.default = pkgs.mkShell
{
buildInputs = with pkgs; [
cachix
just
nodejs
poetry
pre-commit
self.packages.${system}.devEnv
tailwindcss
] ++ lib.optional stdenv.isDarwin openssl;
};
}) // {
nixosModules.strykeforce = import ./nix/module.nix self;
nixosModules.default = self.nixosModules.strykeforce;
nixosConfigurations.container = import ./nix/container.nix {
inherit self nixpkgs;
};
};
}