build.gradle

plugins {
    id 'fabric-loom' version '1.6-SNAPSHOT'
    id 'maven-publish'
    id "com.modrinth.minotaur" version "2.+"
    id "io.github.dexman545.outlet" version "1.6.1"
}


sourceCompatibility = JavaVersion.VERSION_21
targetCompatibility = JavaVersion.VERSION_21

version = project.mod_version
group = project.maven_group

repositories {
    maven {
        url 'https://masa.dy.fi/maven'
    }
}

dependencies {
    // To change the versions see the gradle.properties file
    minecraft "com.mojang:minecraft:${project.minecraft_version}"
    mappings "net.fabricmc:yarn:${project.yarn_mappings}:v2"
    modImplementation "net.fabricmc:fabric-loader:${project.loader_version}"
    modImplementation "carpet:fabric-carpet:${project.carpet_minecraft_version}-${project.carpet_core_version}"
    
    [
            "org.eclipse.jetty:jetty-server:${project.jetty_version}",
            "org.eclipse.jetty:jetty-util:${project.jetty_version}",
            "org.eclipse.jetty:jetty-http:${project.jetty_version}",
            "org.eclipse.jetty:jetty-io:${project.jetty_version}",
    ].forEach {
        dep -> include(implementation(dep)) {
            transitive = false // include non-transitively to make sure everything that's implemented is also included
        }
    }
}

processResources {
    inputs.property "version", project.version
    inputs.property "minecraft_version", project.minecraft_version
    inputs.property "loader_version", project.loader_version
    filteringCharset "UTF-8"

    filesMatching("fabric.mod.json") {
        expand "version": project.version,
                "minecraft_version": project.minecraft_version,
                "loader_version": project.loader_version
    }
}


tasks.withType(JavaCompile).configureEach {
    it.options.encoding = "UTF-8"
    it.options.release = 21
}


java {
    withSourcesJar()
}

jar {
    from("LICENSE") {
        rename { "${it}_${project.archivesBaseName}"}
    }
    from("NOTICE") {
        rename { "${it}_${project.archivesBaseName}"}
    }
}


import com.modrinth.minotaur.dependencies.ModDependency

modrinth {
    token = System.getenv("MODRINTH_TOKEN")
    projectId = "1BG4YFps"
    versionNumber = project.mod_version
    outlet.mcVersionRange = ">=1.20.5" // Java 21+
    gameVersions = outlet.mcVersions()
    versionType = "beta"
    uploadFile = remapJar
    loaders = ["fabric"]
    dependencies = [
            // carpet
            new ModDependency("TQTTVgYE" ,"required")
    ]
    changelog = rootProject.file("changelog.md").text
    syncBodyFrom = rootProject.file("README.md").text
}