when/flake.nix at master · redxtech/when · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
{
  description =
    "A website that tells you when tv shows are coming out - to the second.";

  inputs = {
    flake-parts.url = "github:hercules-ci/flake-parts";
    nixpkgs.url = "github:NixOS/nixpkgs/nixos-unstable";
  };

  outputs = inputs@{ flake-parts, ... }:
    flake-parts.lib.mkFlake { inherit inputs; } {
      systems =
        [ "x86_64-linux" "aarch64-linux" "aarch64-darwin" "x86_64-darwin" ];

      perSystem = { config, self', inputs', pkgs, system, ... }: {
        packages = {
          when = pkgs.buildNpmPackage {
            pname = "when";
            version = "0.0.0";

            src = ./.;

            npmDepsHash = "sha256-AcHPhtmb89lBUQEDHgcJ33xK7VqBiQEOLcVXI5zhU0E=";
            forceGitDeps = true;
            makeCacheWritable = true;

            installPhase = ''
              mkdir -p $out/share/when
              cp -r dist/* $out/share/when
            '';
          };

          default = self'.packages.when;
        };

        apps = {
          when = {
            type = "app";
            program = pkgs.writeShellApplication {
              name = "when";
              runtimeInputs = with pkgs; [ nodejs wrangler ];
              text = ''
                wrangler pages dev dist
              '';
            };
          };

          default = self'.apps.when;
        };

        devShells.default =
          pkgs.mkShell { packages = with pkgs; [ nodejs wrangler ]; };
      };
    };
}