Trying to load a RDF graph into a Grax schema

[carlotm]

Hi all,

my goal is to load a Grax schema from an RDF Graph as described here:
https://rdf-elixir.dev/grax/api.html#loading-from-rdf-graphs

This is what I did so far:

1. Load the schema.org vocabulary into a namespace

iex(4)> Foo.Vocabs.SchemaOrg.name
~I<https://schema.org/name>

2. Create an RDF.Graph from a json-ld source. The graph (it's a https://schema.org/JobPosting) looks like:

#RDF.Graph<name: nil
  @prefix rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#> .
  @prefix rdfs: <http://www.w3.org/2000/01/rdf-schema#> .
  @prefix xsd: <http://www.w3.org/2001/XMLSchema#> .

  [
      a <http://schema.org/JobPosting> ;
      <http://schema.org/datePosted> "2024-12-01"^^<http://schema.org/Date> ;
      <http://schema.org/description> "Das Repair Café der Jugendpalette ..." ;
      <http://schema.org/directApply> false ;
      <http://schema.org/industry> "" ;
      <http://schema.org/occupationalCategory> "Natur und Nachhaltigkeit, Bildung, Nachbarschaftshilfe" ;
      <http://schema.org/responsibilities> "Hilfe an der Bar, Handwerken und Reparieren" ;
      <http://schema.org/title> "Repair Café Traun" ;
      <http://schema.org/validThrough> "2024-08-01"^^<http://schema.org/Date>
  ] .
>

3. Define a Grax schema for the job posting

defmodule Foo.Schema.Job do
  use Grax.Schema

  alias Foo.Vocabs.SchemaOrg

  schema SchemaOrg.JobPosting do
    property :title, SchemaOrg.title
    property :description, SchemaOrg.description
    property :occupationalCategory, SchemaOrg.occupationalCategory
    property :validThrough, SchemaOrg.validThrough
    property :datePosted, SchemaOrg.datePosted
    property :industry, SchemaOrg.industry
    property :responsibilities, SchemaOrg.responsibilities
    property :directApply, SchemaOrg.directApply
  end
end

4. Load the graph into the schema with

iex(2)> Grax.load(g, Foo.Vocabs.SchemaOrg.JobPosting, Foo.Schema.Job)
{:ok,
 %Foo.Schema.Job{
   __additional_statements__: %{
     ~I<http://www.w3.org/1999/02/22-rdf-syntax-ns#type> => %{
       ~I<https://schema.org/JobPosting> => nil
     }
   },
   __id__: ~I<https://schema.org/JobPosting>,
   datePosted: nil,
   description: nil,
   directApply: nil,
   industry: nil,
   occupationalCategory: nil,
   responsibilities: nil,
   title: nil,
   validThrough: nil
 }}

But I see all nils

I wonder what am I doing wrong.

Thank you!
Cheers

[marcelotto]

You're actually trying to load the class instead of the resource described in your data.

The challenge here is that we can't see the actual node identifier when using Turtle's blank node description syntax ([ ]), which means there's no direct subject node reference we can use for loading. Here's how to handle this:

1. Preferred approach: If you control the data, use proper URIs for your job postings instead of blank nodes.

2. Solution for unknown blank nodes: To work with the current structure, you'll need to find the job posting nodes in your graph first:

alias Foo.Vocabs.SchemaOrg

graph
|> RDF.Graph.query({:job_posting_id?, RDF.type(), SchemaOrg.JobPosting})
|> Enum.map(fn %{job_posting_id?: job_posting_id} -> 
  # This uses the shorter load/2 function generated on schema modules, 
  # which sets the schema argument implicitly
  Foo.Schema.Job.load!(graph, job_posting_id)
end)