build.gradle

apply plugin: 'java'
apply plugin: 'maven'

def distFolder = file("dist")
def docFolder = file("dist/doc")
def projectName = 'bloom-filter'

version = "1.05-port-java7"
group = "com.baqend"

repositories {
    mavenCentral()
}

dependencies {
    compile(
            'com.google.code.gson:gson:2.2.4',
            'redis.clients:jedis:2.5.1',
            'org.apache.commons:commons-pool2:2.2'
    )
    testCompile(
            'junit:junit:4.11',
            'org.apache.commons:commons-math:2.2',
            'com.google.guava:guava:11.0.2',
            'org.apache.commons:commons-lang3:3.0'
    )
}

test.ignoreFailures = true
javadoc.destinationDir = docFolder
jar.baseName = projectName
jar.destinationDir = distFolder

task dist(dependsOn: jar, type: Jar) {
    copy {
        from configurations.compile
        into distFolder
    }
    baseName = projectName
    from sourceSets.main.allSource
    destinationDir distFolder
    classifier = 'source'
}

task javadocJar(type: Jar) {
    classifier = 'javadoc'
    from javadoc
}

task sourcesJar(type: Jar) {
    classifier = 'sources'
    from sourceSets.main.allSource
}

artifacts {
    archives javadocJar, sourcesJar
}

uploadArchives {
    repositories {
        mavenDeployer {
            repository(url: "file://$projectDir/maven-repo")
        }
    }
}