build.gradle

buildscript {
    repositories {
        mavenCentral() { metadataSources { mavenPom(); ignoreGradleMetadataRedirection() } }
        gradlePluginPortal() { metadataSources { mavenPom(); ignoreGradleMetadataRedirection() } }
    }

    dependencies {
        classpath 'com.palantir.jakartapackagealignment:jakarta-package-alignment:0.6.0'
        classpath 'com.gradle.publish:plugin-publish-plugin:1.3.1'
        classpath 'com.palantir.baseline:gradle-baseline-java:6.20.0'
        classpath 'com.palantir.gradle.consistentversions:gradle-consistent-versions:2.31.0'
        classpath 'com.palantir.gradle.externalpublish:gradle-external-publish-plugin:1.19.0'
        classpath 'com.palantir.gradle.failure-reports:gradle-failure-reports:1.13.0'
        classpath 'com.palantir.gradle.gitversion:gradle-git-version:3.1.0'
        classpath 'com.palantir.gradle.jdks:gradle-jdks:0.62.0'
        classpath 'com.palantir.gradle.jdkslatest:gradle-jdks-latest:0.17.0'
        classpath 'com.palantir.gradle.plugintesting:gradle-plugin-testing:0.6.0'
        classpath 'com.palantir.javaformat:gradle-palantir-java-format:2.58.0'
        classpath 'com.palantir.gradle.revapi:gradle-revapi:1.8.0'
        classpath 'com.palantir.suppressible-error-prone:gradle-suppressible-error-prone:2.5.0'
        classpath 'gradle.plugin.org.inferred:gradle-processors:3.7.0'
        classpath 'me.champeau.jmh:jmh-gradle-plugin:0.7.3'
    }
}

apply plugin: 'com.palantir.external-publish'
apply plugin: 'com.palantir.failure-reports'
apply plugin: 'com.palantir.git-version'
apply plugin: 'com.palantir.jdks'
apply plugin: 'com.palantir.jdks.latest'
apply plugin: 'com.palantir.baseline'
apply plugin: 'com.palantir.baseline-java-versions'
apply plugin: 'com.palantir.consistent-versions'
apply plugin: 'com.palantir.baseline-java-versions'

version System.env.CIRCLE_TAG ?: gitVersion()

allprojects {
    apply plugin: 'com.palantir.baseline-null-away'
    apply plugin: 'com.palantir.java-format'
    apply plugin: 'com.palantir.jakarta-package-alignment'
    group = 'com.palantir.javaformat'
    version = rootProject.version

    repositories {
        mavenCentral() { metadataSources { mavenPom(); ignoreGradleMetadataRedirection() } }
    }
}

subprojects {
    apply plugin: 'java-library'
    apply plugin: 'org.inferred.processors'

    tasks.withType(Checkstyle).configureEach {
        enabled = false
    }

    tasks.withType(JavaCompile).configureEach {
        options.errorprone.disable 'PreconditionsConstantMessage', 'PreferSafeLoggableExceptions', 'PreferSafeLoggingPreconditions'
        options.errorprone.disable 'StrictUnusedVariable'
    }

    // Run `./gradlew test -Drecreate=true` to recreate all the expected
    // generated code that we have checked into the repo.
    tasks.withType(Test).configureEach {
        systemProperty 'recreate', System.getProperty('recreate', 'false')
    }
}

javaVersions {
    libraryTarget = 17
    runtime = 21
}

jdks {
    daemonTarget = 17

    jdk(23) {
        distribution = 'graalvm-ce'
        jdkVersion = '23.0.1'
    }

}