Any 'read' function always returns '1' or 'true'

[paulwrath1223]

There is a massive possibility that I am doing something immensely stupid, but the fact that no one else seems to have ever encountered this problem seems like I have done something uniquely wrong. I am able to write to the database perfectly too, making me all the more confused. Any response would be greatly appreciated.

code below for anyone insane enough to read my incomprehensible gibberish

#include <Adafruit_NeoPixel.h>
#include <ESP8266WiFi.h>
#include <FirebaseESP8266.h>

#include <addons/TokenHelper.h>

#include <addons/RTDBHelper.h>

#define WIFI_SSID "definitely correct but I'm not puttin it online"
#define WIFI_PASSWORD "definitely correct but I'm not puttin it online"



/* 3. Define the RTDB URL */
#define DATABASE_URL "definitely correct but I'm not puttin it online"
#define DATABASE_SECRET "definitely correct but I'm not puttin it online"


//Define Firebase Data object
FirebaseData fbdo;

FirebaseAuth auth;
FirebaseConfig config;

unsigned long dataMillis = 0;



String basePath = "/Arduino0";


#define PIN 2


Adafruit_NeoPixel pixels(1, PIN, NEO_GRB + NEO_KHZ800);


float speed = 0; // 0 means solic color, 1 means wave.
int numPixels = 1;
int r;
int g;
int b;
int numColors;
int updateCounter;
int lastNumColors;
float timing = 0;
int update = 1;

String path;
String speedPath;
String lightLengthPath;
String colorLengthPath;
String colorPath;
String updatePath;

int waveOffset = 0;

uint32_t* colorList = 0;

void updateCloud()
{
    Serial.println("timing shit idek");
    while(!(millis() - dataMillis > 5000))
    {
      delay(1);
      Serial.print(".");
    }
    dataMillis = millis();
    Serial.println("database query began");
    update = Firebase.getInt(fbdo, updatePath);
    if(update == 1)
    {
        Serial.println("update is true");
        speed = Firebase.getInt(fbdo, speedPath);            

        Serial.printf("Set speed to 69 %s\n", Firebase.setInt(fbdo, speedPath, 69) ? "ok" : fbdo.errorReason().c_str());
        lastNumColors = numColors;
        numColors = Firebase.getInt(fbdo, colorLengthPath);
        if( ! (lastNumColors == numColors))
        {
            if (colorList != 0)
            {
              delete [] colorList;
            }
            colorList = new uint32_t [numPixels];
        }
        numPixels = Firebase.getInt(fbdo, lightLengthPath);
        pixels.updateLength(numPixels);

        for(int counter = 0; counter<numColors; counter++)
        {
          path = colorPath + String(counter) + "/";
          r = Firebase.getInt(fbdo, path+"r/");
          g = Firebase.getInt(fbdo, path+"g/");
          b = Firebase.getInt(fbdo, path+"b/");
          colorList[counter] = pixels.Color(r, g, b);
        }
        Firebase.setInt(fbdo, updatePath, false);
    }
    Serial.println("database query done :");
    Serial.print("speed: ");
    Serial.println(speed);
    Serial.print("numColors: ");
    Serial.println(numColors);
    Serial.print("numPixels: ");
    Serial.println(numPixels);

}


void setup()
{
  updatePath = basePath + "/update";
  speedPath = basePath + "/speed";
  lightLengthPath = basePath + "/numLights";
  colorLengthPath = basePath + "/colorLength";
  colorPath = basePath+"/colors";

  pixels.begin(); // INITIALIZE NeoPixel strip object (REQUIRED)
  Serial.begin(115200);

  WiFi.begin(WIFI_SSID, WIFI_PASSWORD);
  Serial.print("Connecting to Wi-Fi");
  while (WiFi.status() != WL_CONNECTED)
  {
    Serial.print(".");
    delay(300);
  }
  Serial.println();
  Serial.print("Connected with IP: ");
  Serial.println(WiFi.localIP());
  Serial.println();

  Serial.printf("Firebase Client v%s\n\n", FIREBASE_CLIENT_VERSION);


  /* Assign the RTDB URL (required) */
  config.database_url = DATABASE_URL;
  config.signer.tokens.legacy_token = DATABASE_SECRET;

  /* Assign the callback function for the long running token generation task */
  config.token_status_callback = tokenStatusCallback; //see addons/TokenHelper.h

  Firebase.setMaxRetry(fbdo, 3);

  Firebase.reconnectWiFi(true);

  Firebase.begin(&config, &auth);


  updateCloud();
  Serial.println("Finished with setup");

}

void loop()
{
  if(updateCounter > 1000)
  {
    updateCloud();
    updateCounter = 0;
  }
  //Flash string (PROGMEM and  (FPSTR), String,, String C/C++ string, const char, char array, string literal are supported
  //in all Firebase and FirebaseJson functions, unless F() macro is not supported

  timing += speed;
  if(timing > 1)
  {
    timing-=1;
    waveOffset++;    
  }  
  if( !(waveOffset < numColors))  // >=
  {
    waveOffset = 0;
  }
  for(int i=0; i<numPixels; i++)  // For each pixel...
  {
      pixels.setPixelColor(i, colorList[((i + waveOffset) % numColors)]);
      pixels.show();   // Send the updated pixel colors to the hardware.
  }
  updateCounter++;
}

[mobizt]

You should read the document and the examples showed how to use the library correctly.

Returning the value from cloud related function is a bad choice and API design as it may fail in between due to many possibilities, the undesired and unknown value may return.

We should take some reference object to store the operating result to the function to prevent setting undesired value to some variable and it can be reused such as session that keep in that object.

Firebase-ESP8266/examples/Basic/Basic.ino

Lines 128 to 183 in 3df9fd0

	void loop()
	{
	//Flash string (PROGMEM and (FPSTR), String,, String C/C++ string, const char, char array, string literal are supported
	//in all Firebase and FirebaseJson functions, unless F() macro is not supported.
	if (Firebase.ready() && (millis() - sendDataPrevMillis > 15000 || sendDataPrevMillis == 0))
	{
	sendDataPrevMillis = millis();
	Serial.printf("Set bool... %s\n", Firebase.setBool(fbdo, "/test/bool", count % 2 == 0) ? "ok" : fbdo.errorReason().c_str());
	Serial.printf("Get bool... %s\n", Firebase.getBool(fbdo, "/test/bool") ? fbdo.to<bool>() ? "true" : "false" : fbdo.errorReason().c_str());
	bool bVal;
	Serial.printf("Get bool ref... %s\n", Firebase.getBool(fbdo, "/test/bool", &bVal) ? bVal ? "true" : "false" : fbdo.errorReason().c_str());
	Serial.printf("Set int... %s\n", Firebase.setInt(fbdo, "/test/int", count) ? "ok" : fbdo.errorReason().c_str());
	Serial.printf("Get int... %s\n", Firebase.getInt(fbdo, "/test/int") ? String(fbdo.to<int>()).c_str() : fbdo.errorReason().c_str());
	int iVal = 0;
	Serial.printf("Get int ref... %s\n", Firebase.getInt(fbdo, "/test/int", &iVal) ? String(iVal).c_str() : fbdo.errorReason().c_str());
	Serial.printf("Set float... %s\n", Firebase.setFloat(fbdo, "/test/float", count + 10.2) ? "ok" : fbdo.errorReason().c_str());
	Serial.printf("Get float... %s\n", Firebase.getFloat(fbdo, "/test/float") ? String(fbdo.to<float>()).c_str() : fbdo.errorReason().c_str());
	Serial.printf("Set double... %s\n", Firebase.setDouble(fbdo, "/test/double", count + 35.517549723765) ? "ok" : fbdo.errorReason().c_str());
	Serial.printf("Get double... %s\n", Firebase.getDouble(fbdo, "/test/double") ? String(fbdo.to<double>()).c_str() : fbdo.errorReason().c_str());
	Serial.printf("Set string... %s\n", Firebase.setString(fbdo, "/test/string", "Hello World!") ? "ok" : fbdo.errorReason().c_str());
	Serial.printf("Get string... %s\n", Firebase.getString(fbdo, "/test/string") ? fbdo.to<const char *>() : fbdo.errorReason().c_str());
	Serial.println();
	//For generic set/get functions.
	//For generic set, use Firebase.set(fbdo, <path>, <any variable or value>)
	//For generic get, use Firebase.get(fbdo, <path>).
	//And check its type with fbdo.dataType() or fbdo.dataTypeEnum() and
	//cast the value from it e.g. fbdo.to<int>(), fbdo.to<std::string>().
	//The function, fbdo.dataType() returns types String e.g. string, boolean,
	//int, float, double, json, array, blob, file and null.
	//The function, fbdo.dataTypeEnum() returns type enum (number) e.g. fb_esp_rtdb_data_type_null (1),
	//fb_esp_rtdb_data_type_integer, fb_esp_rtdb_data_type_float, fb_esp_rtdb_data_type_double,
	//fb_esp_rtdb_data_type_boolean, fb_esp_rtdb_data_type_string, fb_esp_rtdb_data_type_json,
	//fb_esp_rtdb_data_type_array, fb_esp_rtdb_data_type_blob, and fb_esp_rtdb_data_type_file (10)
	count++;
	}
	}

[paulwrath1223]

Thank you for the response and sorry for my stupid questions, but would I just do this :

Firebase.get(fbdo, <path of an int>)
result = fbdo.to<int>()

(and also put the reading functions in the loop function)