-
Notifications
You must be signed in to change notification settings - Fork 1
/
LibreOfficeCalc_Sheet.au3
1631 lines (1379 loc) · 93.3 KB
/
LibreOfficeCalc_Sheet.au3
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
833
834
835
836
837
838
839
840
841
842
843
844
845
846
847
848
849
850
851
852
853
854
855
856
857
858
859
860
861
862
863
864
865
866
867
868
869
870
871
872
873
874
875
876
877
878
879
880
881
882
883
884
885
886
887
888
889
890
891
892
893
894
895
896
897
898
899
900
901
902
903
904
905
906
907
908
909
910
911
912
913
914
915
916
917
918
919
920
921
922
923
924
925
926
927
928
929
930
931
932
933
934
935
936
937
938
939
940
941
942
943
944
945
946
947
948
949
950
951
952
953
954
955
956
957
958
959
960
961
962
963
964
965
966
967
968
969
970
971
972
973
974
975
976
977
978
979
980
981
982
983
984
985
986
987
988
989
990
991
992
993
994
995
996
997
998
999
1000
#AutoIt3Wrapper_Au3Check_Parameters=-d -w 1 -w 2 -w 3 -w 4 -w 5 -w 6 -w 7
;~ #Tidy_Parameters=/sf
#include-once
; Main LibreOffice Includes
#include "LibreOffice_Constants.au3"
; Common includes for Calc
#include "LibreOfficeCalc_Internal.au3"
; Other includes for Calc
#include "LibreOfficeCalc_Doc.au3"
; #INDEX# =======================================================================================================================
; Title .........: LibreOffice UDF
; AutoIt Version : v3.3.16.1
; Description ...: Provides basic functionality through AutoIt for Creating, Modifying, Removing, etc. L.O. Calc document Sheets.
; Author(s) .....: donnyh13, mLipok
; Dll ...........:
;
; ===============================================================================================================================
; #CURRENT# =====================================================================================================================
; _LOCalc_SheetActivate
; _LOCalc_SheetAdd
; _LOCalc_SheetCopy
; _LOCalc_SheetCreateCursor
; _LOCalc_SheetDetectiveClear
; _LOCalc_SheetDetectiveDependent
; _LOCalc_SheetDetectiveInvalidData
; _LOCalc_SheetDetectivePrecedent
; _LOCalc_SheetDetectiveTraceError
; _LOCalc_SheetExists
; _LOCalc_SheetGetActive
; _LOCalc_SheetGetObjByName
; _LOCalc_SheetGetObjByPosition
; _LOCalc_SheetImport
; _LOCalc_SheetIsActive
; _LOCalc_SheetIsProtected
; _LOCalc_SheetLink
; _LOCalc_SheetLinkModify
; _LOCalc_SheetMove
; _LOCalc_SheetName
; _LOCalc_SheetPrintColumnsRepeat
; _LOCalc_SheetPrintRangeModify
; _LOCalc_SheetPrintRowsRepeat
; _LOCalc_SheetProtect
; _LOCalc_SheetRemove
; _LOCalc_SheetsGetCount
; _LOCalc_SheetsGetNames
; _LOCalc_SheetTabColor
; _LOCalc_SheetUnprotect
; _LOCalc_SheetVisible
; ===============================================================================================================================
; #FUNCTION# ====================================================================================================================
; Name ..........: _LOCalc_SheetActivate
; Description ...: Activate a Sheet in a Calc Document.
; Syntax ........: _LOCalc_SheetActivate(ByRef $oDoc, ByRef $oSheet)
; Parameters ....: $oDoc - [in/out] an object. A Document object returned by a previous _LOCalc_DocOpen, _LOCalc_DocConnect, or _LOCalc_DocCreate function.
; $oSheet - [in/out] an object. A Sheet object returned by a previous _LOCalc_SheetAdd, _LOCalc_SheetGetActive, _LOCalc_SheetCopy, or _LOCalc_SheetGetObjByName function.
; Return values .: Success: 1
; Failure: 0 and sets the @Error and @Extended flags to non-zero.
; --Input Errors--
; @Error 1 @Extended 1 Return 0 = $oDoc not an Object.
; @Error 1 @Extended 2 Return 0 = $oSheet not an Object.
; --Success--
; @Error 0 @Extended 0 Return 1 = Success. Sheet was successfully activated.
; Author ........: donnyh13
; Modified ......:
; Remarks .......:
; Related .......: _LOCalc_SheetIsActive
; Link ..........:
; Example .......: Yes
; ===============================================================================================================================
Func _LOCalc_SheetActivate(ByRef $oDoc, ByRef $oSheet)
Local $oCOM_ErrorHandler = ObjEvent("AutoIt.Error", __LOCalc_InternalComErrorHandler)
#forceref $oCOM_ErrorHandler
If Not IsObj($oDoc) Then Return SetError($__LO_STATUS_INPUT_ERROR, 1, 0)
If Not IsObj($oSheet) Then Return SetError($__LO_STATUS_INPUT_ERROR, 2, 0)
$oDoc.CurrentController.setActiveSheet($oSheet)
Return SetError($__LO_STATUS_SUCCESS, 0, 1)
EndFunc ;==>_LOCalc_SheetActivate
; #FUNCTION# ====================================================================================================================
; Name ..........: _LOCalc_SheetAdd
; Description ...: Insert a new Sheet into a Calc Document.
; Syntax ........: _LOCalc_SheetAdd(ByRef $oDoc[, $sName = Null[, $iPosition = Null]])
; Parameters ....: $oDoc - [in/out] an object. A Document object returned by a previous _LOCalc_DocOpen, _LOCalc_DocConnect, or _LOCalc_DocCreate function.
; $sName - [optional] a string value. Default is Null. The Name of the new Sheet. See remarks.
; $iPosition - [optional] an integer value. Default is Null. The position to insert the new sheet. If left as Null, new sheet is inserted at the end. See remarks.
; Return values .: Success: Object
; Failure: 0 and sets the @Error and @Extended flags to non-zero.
; --Input Errors--
; @Error 1 @Extended 1 Return 0 = $oDoc not an Object.
; @Error 1 @Extended 2 Return 0 = $sName not a String.
; @Error 1 @Extended 3 Return 0 = Document already contains a Sheet named the same as called in $sName.
; @Error 1 @Extended 4 Return 0 = $iPosition not an Integer, less than 0 or greater than number of sheets present in the document.
; --Processing Errors--
; @Error 3 @Extended 1 Return 0 = Failed to retrieve Sheets Object.
; @Error 3 @Extended 2 Return 0 = Failed to retrieve new Sheet's Object. New Sheet may not have been inserted successfully.
; --Success--
; @Error 0 @Extended 0 Return Object = Success. New sheet was successfully inserted, returning its Object.
; Author ........: donnyh13
; Modified ......:
; Remarks .......: If $sName is left as Null, the sheet will be automatically named "Sheet?" where "?" is a digit.
; If $iPosition is left as Null, the sheet will be inserted at the end of the list of Sheets.
; Calling $iPosition with the number of Sheets in the Document will place the added sheet at the end of the sheet list.
; Related .......: _LOCalc_SheetRemove, _LOCalc_SheetExists
; Link ..........:
; Example .......: Yes
; ===============================================================================================================================
Func _LOCalc_SheetAdd(ByRef $oDoc, $sName = Null, $iPosition = Null)
Local $oCOM_ErrorHandler = ObjEvent("AutoIt.Error", __LOCalc_InternalComErrorHandler)
#forceref $oCOM_ErrorHandler
Local $oSheets, $oSheet
Local $iCount = 0
If Not IsObj($oDoc) Then Return SetError($__LO_STATUS_INPUT_ERROR, 1, 0)
$oSheets = $oDoc.Sheets()
If Not IsObj($oSheets) Then Return SetError($__LO_STATUS_PROCESSING_ERROR, 1, 0)
If ($sName = Null) Then
$sName = "Sheet" & ($oSheets.Count() + 1)
If $oSheets.hasByName($sName) Then
$iCount = $oSheets.Count()
While $oSheets.hasByName($sName)
$iCount += 1
$sName = "Sheet" & $iCount
WEnd
EndIf
EndIf
If Not IsString($sName) Then Return SetError($__LO_STATUS_INPUT_ERROR, 2, 0)
If $oSheets.hasByName($sName) Then Return SetError($__LO_STATUS_INPUT_ERROR, 3, 0)
If ($iPosition = Null) Then $iPosition = $oSheets.Count()
If Not __LOCalc_IntIsBetween($iPosition, 0, $oSheets.Count()) Then Return SetError($__LO_STATUS_INPUT_ERROR, 4, 0)
$oSheets.insertNewByName($sName, $iPosition)
$oSheet = $oSheets.getByName($sName)
Return (IsObj($oSheet)) ? (SetError($__LO_STATUS_SUCCESS, 0, $oSheet)) : (SetError($__LO_STATUS_PROCESSING_ERROR, 2, 0))
EndFunc ;==>_LOCalc_SheetAdd
; #FUNCTION# ====================================================================================================================
; Name ..........: _LOCalc_SheetCopy
; Description ...: Create a copy of a particular Sheet.
; Syntax ........: _LOCalc_SheetCopy(ByRef $oDoc, ByRef $oSheet[, $sNewName = Null[, $iPosition = Null]])
; Parameters ....: $oDoc - [in/out] an object. A Document object returned by a previous _LOCalc_DocOpen, _LOCalc_DocConnect, or _LOCalc_DocCreate function.
; $oSheet - [in/out] an object. A Sheet object returned by a previous _LOCalc_SheetAdd, _LOCalc_SheetGetActive, _LOCalc_SheetCopy, or _LOCalc_SheetGetObjByName function.
; $sNewName - [optional] a string value. Default is Null. The name to assign to the newly copied Sheet.
; $iPosition - [optional] an integer value. Default is Null. The position to place the copied sheet at. 0 = the beginning.
; Return values .: Success: Object
; Failure: 0 and sets the @Error and @Extended flags to non-zero.
; --Input Errors--
; @Error 1 @Extended 1 Return 0 = $oDoc not an Object.
; @Error 1 @Extended 2 Return 0 = $oSheet not an Object.
; @Error 1 @Extended 3 Return 0 = $sNewName not a String.
; @Error 1 @Extended 4 Return 0 = Document already contains a Sheet with the same name as called in $sNewName.
; @Error 1 @Extended 5 Return 0 = $iPosition not an Integer, less than 0, or greater than number of Sheets contained in the document.
; --Processing Errors--
; @Error 3 @Extended 1 Return 0 = Failed to retrieve Sheets Object.
; @Error 3 @Extended 2 Return 0 = Failed to retrieve original Sheet's name.
; @Error 3 @Extended 3 Return 0 = Failed to retrieve Object for new Sheet.
; --Success--
; @Error 0 @Extended 0 Return Object = Success. Successfully copied the Sheet. Returning the new Sheet's Object.
; Author ........: donnyh13
; Modified ......:
; Remarks .......: If $sNewName is left as Null, the original Sheet's name is used, with "_" and a digit appended.
; If $iPosition is left as Null, the copied sheet will be placed at the end of the list.
; Calling $iPosition with the number of Sheets in the Document will place the copied sheet at the end of the sheet list.
; Related .......: _LOCalc_SheetExists, _LOCalc_SheetMove
; Link ..........:
; Example .......: Yes
; ===============================================================================================================================
Func _LOCalc_SheetCopy(ByRef $oDoc, ByRef $oSheet, $sNewName = Null, $iPosition = Null)
Local $oCOM_ErrorHandler = ObjEvent("AutoIt.Error", __LOCalc_InternalComErrorHandler)
#forceref $oCOM_ErrorHandler
Local $oSheets, $oNewSheet
Local $sName
Local $iCount
If Not IsObj($oDoc) Then Return SetError($__LO_STATUS_INPUT_ERROR, 1, 0)
If Not IsObj($oSheet) Then Return SetError($__LO_STATUS_INPUT_ERROR, 2, 0)
$oSheets = $oDoc.Sheets()
If Not IsObj($oSheets) Then Return SetError($__LO_STATUS_PROCESSING_ERROR, 1, 0)
$sName = $oSheet.Name()
If Not IsString($sName) Then Return SetError($__LO_STATUS_PROCESSING_ERROR, 2, 0)
If ($sNewName = Null) Then
$sNewName = $sName & "_" & 2
If $oSheets.hasByName($sNewName) Then
$iCount = 2
While $oSheets.hasByName($sNewName)
$iCount += 1
$sNewName = $sName & "_" & $iCount
WEnd
EndIf
EndIf
If Not IsString($sNewName) Then Return SetError($__LO_STATUS_INPUT_ERROR, 3, 0)
If $oSheets.hasByName($sNewName) Then Return SetError($__LO_STATUS_INPUT_ERROR, 4, 0)
If ($iPosition = Null) Then $iPosition = $oSheets.Count()
If Not __LOCalc_IntIsBetween($iPosition, 0, $oSheets.Count()) Then Return SetError($__LO_STATUS_INPUT_ERROR, 5, 0)
$oSheets.copyByName($sName, $sNewName, $iPosition)
$oNewSheet = $oSheets.getByName($sNewName)
If Not IsObj($oNewSheet) Then Return SetError($__LO_STATUS_PROCESSING_ERROR, 3, 0)
Return SetError($__LO_STATUS_SUCCESS, 0, $oNewSheet)
EndFunc ;==>_LOCalc_SheetCopy
; #FUNCTION# ====================================================================================================================
; Name ..........: _LOCalc_SheetCreateCursor
; Description ...: Create a Sheet Cursor for an entire Sheet.
; Syntax ........: _LOCalc_SheetCreateCursor(ByRef $oSheet)
; Parameters ....: $oSheet - [in/out] an object. A Sheet object returned by a previous _LOCalc_SheetAdd, _LOCalc_SheetGetActive, _LOCalc_SheetCopy, or _LOCalc_SheetGetObjByName function.
; Return values .: Success: Object
; Failure: 0 and sets the @Error and @Extended flags to non-zero.
; --Input Errors--
; @Error 1 @Extended 1 Return 0 = $oSheet not an Object.
; --Initialization Errors--
; @Error 2 @Extended 1 Return 0 = Failed to create a Sheet Cursor.
; --Success--
; @Error 0 @Extended 0 Return Object = Success. Successfully created a Sheet Cursor, returning its Object.
; Author ........: donnyh13
; Modified ......:
; Remarks .......: A Sheet Cursor can be used in functions accepting a range. When created, the Cursor will have the entire Sheet selected.
; Related .......:
; Link ..........:
; Example .......: Yes
; ===============================================================================================================================
Func _LOCalc_SheetCreateCursor(ByRef $oSheet)
Local $oCOM_ErrorHandler = ObjEvent("AutoIt.Error", __LOCalc_InternalComErrorHandler)
#forceref $oCOM_ErrorHandler
Local $oSheetCursor
If Not IsObj($oSheet) Then Return SetError($__LO_STATUS_INPUT_ERROR, 1, 0)
$oSheetCursor = $oSheet.createCursor()
If Not IsObj($oSheetCursor) Then Return SetError($__LO_STATUS_INIT_ERROR, 1, 0)
Return SetError($__LO_STATUS_SUCCESS, 0, $oSheetCursor)
EndFunc ;==>_LOCalc_SheetCreateCursor
; #FUNCTION# ====================================================================================================================
; Name ..........: _LOCalc_SheetDetectiveClear
; Description ...: Clear all Detective marking arrows for a Sheet.
; Syntax ........: _LOCalc_SheetDetectiveClear(ByRef $oSheet)
; Parameters ....: $oSheet - [in/out] an object. A Sheet object returned by a previous _LOCalc_SheetAdd, _LOCalc_SheetGetActive, _LOCalc_SheetCopy, or _LOCalc_SheetGetObjByName function.
; Return values .: Success: 1
; Failure: 0 and sets the @Error and @Extended flags to non-zero.
; --Input Errors--
; @Error 1 @Extended 1 Return 0 = $oSheet not an Object.
; --Success--
; @Error 0 @Extended 0 Return 1 = Success. All Detective arrows were successfully cleared.
; Author ........: donnyh13
; Modified ......:
; Remarks .......:
; Related .......: _LOCalc_SheetDetectivePrecedent, _LOCalc_SheetDetectiveDependent, _LOCalc_SheetDetectiveTraceError, _LOCalc_SheetDetectiveInvalidData
; Link ..........:
; Example .......: Yes
; ===============================================================================================================================
Func _LOCalc_SheetDetectiveClear(ByRef $oSheet)
Local $oCOM_ErrorHandler = ObjEvent("AutoIt.Error", __LOCalc_InternalComErrorHandler)
#forceref $oCOM_ErrorHandler
If Not IsObj($oSheet) Then Return SetError($__LO_STATUS_INPUT_ERROR, 1, 0)
$oSheet.clearArrows()
Return SetError($__LO_STATUS_SUCCESS, 0, 1)
EndFunc ;==>_LOCalc_SheetDetectiveClear
; #FUNCTION# ====================================================================================================================
; Name ..........: _LOCalc_SheetDetectiveDependent
; Description ...: Show or Hide Dependent marking arrows for a Cell.
; Syntax ........: _LOCalc_SheetDetectiveDependent(ByRef $oCell[, $bShow = True])
; Parameters ....: $oCell - [in/out] an object. A Cell object returned by a previous _LOCalc_RangeGetCellByName, or _LOCalc_RangeGetCellByPosition function.
; $bShow - [optional] a boolean value. Default is True. If True, Dependent marking arrows will be added one level, if False, marking arrows will be removed one level.
; Return values .: Success: Boolean
; Failure: 0 and sets the @Error and @Extended flags to non-zero.
; --Input Errors--
; @Error 1 @Extended 1 Return 0 = $oCell not an Object.
; @Error 1 @Extended 2 Return 0 = $oCell not a Cell Object.
; @Error 1 @Extended 3 Return 0 = $bShow not a Boolean.
; --Processing Errors--
; @Error 3 @Extended 1 Return 0 = Failed to retrieve called Cell's Address.
; @Error 3 @Extended 2 Return 0 = Failed to process Show/Hide Dependent function.
; --Success--
; @Error 0 @Extended 0 Return Boolean = Success. Returns True if Dependents were marked/cleared one level, else false.
; Author ........: donnyh13
; Modified ......:
; Remarks .......: Each time that $bShow is called with True, another level of Dependents is marked with arrows.
; Related .......: _LOCalc_SheetDetectivePrecedent, _LOCalc_SheetDetectiveTraceError, _LOCalc_SheetDetectiveClear, _LOCalc_SheetDetectiveInvalidData
; Link ..........:
; Example .......: Yes
; ===============================================================================================================================
Func _LOCalc_SheetDetectiveDependent(ByRef $oCell, $bShow = True)
Local $oCOM_ErrorHandler = ObjEvent("AutoIt.Error", __LOCalc_InternalComErrorHandler)
#forceref $oCOM_ErrorHandler
Local $bReturn
Local $tCellAddress
If Not IsObj($oCell) Then Return SetError($__LO_STATUS_INPUT_ERROR, 1, 0)
If Not ($oCell.supportsService("com.sun.star.sheet.SheetCell")) Then Return SetError($__LO_STATUS_INPUT_ERROR, 2, 0) ; Only single cells supported.
If Not IsBool($bShow) Then Return SetError($__LO_STATUS_INPUT_ERROR, 1, 0)
$tCellAddress = $oCell.CellAddress()
If Not IsObj($tCellAddress) Then Return SetError($__LO_STATUS_PROCESSING_ERROR, 1, 0)
If $bShow Then
$bReturn = $oCell.Spreadsheet.showDependents($tCellAddress)
If Not IsBool($bReturn) Then Return SetError($__LO_STATUS_PROCESSING_ERROR, 2, 0)
Else
$bReturn = $oCell.Spreadsheet.hideDependents($tCellAddress)
If Not IsBool($bReturn) Then Return SetError($__LO_STATUS_PROCESSING_ERROR, 2, 0)
EndIf
Return SetError($__LO_STATUS_SUCCESS, 0, $bReturn)
EndFunc ;==>_LOCalc_SheetDetectiveDependent
; #FUNCTION# ====================================================================================================================
; Name ..........: _LOCalc_SheetDetectiveInvalidData
; Description ...: Mark all cells containing invalid data.
; Syntax ........: _LOCalc_SheetDetectiveInvalidData(ByRef $oSheet)
; Parameters ....: $oSheet - [in/out] an object. A Sheet object returned by a previous _LOCalc_SheetAdd, _LOCalc_SheetGetActive, _LOCalc_SheetCopy, or _LOCalc_SheetGetObjByName function.
; Return values .: Success: Boolean
; Failure: 0 and sets the @Error and @Extended flags to non-zero.
; --Input Errors--
; @Error 1 @Extended 1 Return 0 = $oSheet not an Object.
; --Processing Errors--
; @Error 3 @Extended 1 Return 0 = Failed to process Invalid Data function.
; --Success--
; @Error 0 @Extended 0 Return Boolean = Success. Returns True if invalid data was marked, else False.
; Author ........: donnyh13
; Modified ......:
; Remarks .......: Validity rules must be set up for Cell(s) before invalid data will be marked.
; Related .......: _LOCalc_RangeValidation, _LOCalc_RangeValidationSettings, _LOCalc_SheetDetectivePrecedent, _LOCalc_SheetDetectiveDependent, _LOCalc_SheetDetectiveTraceError, _LOCalc_SheetDetectiveClear
; Link ..........:
; Example .......: Yes
; ===============================================================================================================================
Func _LOCalc_SheetDetectiveInvalidData(ByRef $oSheet)
Local $oCOM_ErrorHandler = ObjEvent("AutoIt.Error", __LOCalc_InternalComErrorHandler)
#forceref $oCOM_ErrorHandler
Local $bReturn
If Not IsObj($oSheet) Then Return SetError($__LO_STATUS_INPUT_ERROR, 1, 0)
$bReturn = $oSheet.showInvalid()
If Not IsBool($bReturn) Then Return SetError($__LO_STATUS_PROCESSING_ERROR, 1, 0)
Return SetError($__LO_STATUS_SUCCESS, 0, $bReturn)
EndFunc ;==>_LOCalc_SheetDetectiveInvalidData
; #FUNCTION# ====================================================================================================================
; Name ..........: _LOCalc_SheetDetectivePrecedent
; Description ...: Show or Hide Precedent marking arrows for a Cell.
; Syntax ........: _LOCalc_SheetDetectivePrecedent(ByRef $oCell[, $bShow = True])
; Parameters ....: $oCell - [in/out] an object. A Cell object returned by a previous _LOCalc_RangeGetCellByName, or _LOCalc_RangeGetCellByPosition function.
; $bShow - [optional] a boolean value. Default is True. If True, Precedent marking arrows will be added one level, if False, marking arrows will be removed one level.
; Return values .: Success: Boolean
; Failure: 0 and sets the @Error and @Extended flags to non-zero.
; --Input Errors--
; @Error 1 @Extended 1 Return 0 = $oCell not an Object.
; @Error 1 @Extended 2 Return 0 = $oCell not a Cell Object.
; @Error 1 @Extended 3 Return 0 = $bShow not a Boolean.
; --Processing Errors--
; @Error 3 @Extended 1 Return 0 = Failed to retrieve called Cell's Address.
; @Error 3 @Extended 2 Return 0 = Failed to process Show/Hide Precedent function.
; --Success--
; @Error 0 @Extended 0 Return Boolean = Success. Returns True if precedents were marked/cleared one level, else false.
; Author ........: donnyh13
; Modified ......:
; Remarks .......: Each time that $bShow is called with True, another level of precedents is marked with arrows.
; Related .......: _LOCalc_SheetDetectiveDependent, _LOCalc_SheetDetectiveTraceError, _LOCalc_SheetDetectiveClear, _LOCalc_SheetDetectiveInvalidData
; Link ..........:
; Example .......: Yes
; ===============================================================================================================================
Func _LOCalc_SheetDetectivePrecedent(ByRef $oCell, $bShow = True)
Local $oCOM_ErrorHandler = ObjEvent("AutoIt.Error", __LOCalc_InternalComErrorHandler)
#forceref $oCOM_ErrorHandler
Local $bReturn
Local $tCellAddress
If Not IsObj($oCell) Then Return SetError($__LO_STATUS_INPUT_ERROR, 1, 0)
If Not ($oCell.supportsService("com.sun.star.sheet.SheetCell")) Then Return SetError($__LO_STATUS_INPUT_ERROR, 2, 0) ; Only single cells supported.
If Not IsBool($bShow) Then Return SetError($__LO_STATUS_INPUT_ERROR, 3, 0)
$tCellAddress = $oCell.CellAddress()
If Not IsObj($tCellAddress) Then Return SetError($__LO_STATUS_PROCESSING_ERROR, 1, 0)
If $bShow Then
$bReturn = $oCell.Spreadsheet.showPrecedents($tCellAddress)
If Not IsBool($bReturn) Then Return SetError($__LO_STATUS_PROCESSING_ERROR, 2, 0)
Else
$bReturn = $oCell.Spreadsheet.hidePrecedents($tCellAddress)
If Not IsBool($bReturn) Then Return SetError($__LO_STATUS_PROCESSING_ERROR, 2, 0)
EndIf
Return SetError($__LO_STATUS_SUCCESS, 0, $bReturn)
EndFunc ;==>_LOCalc_SheetDetectivePrecedent
; #FUNCTION# ====================================================================================================================
; Name ..........: _LOCalc_SheetDetectiveTraceError
; Description ...: Draw arrows from a Cell with errors to the cells causing the errors.
; Syntax ........: _LOCalc_SheetDetectiveTraceError(ByRef $oCell)
; Parameters ....: $oCell - [in/out] an object. A Cell object returned by a previous _LOCalc_RangeGetCellByName, or _LOCalc_RangeGetCellByPosition function.
; Return values .: Success: Boolean
; Failure: 0 and sets the @Error and @Extended flags to non-zero.
; --Input Errors--
; @Error 1 @Extended 1 Return 0 = $oCell not an Object.
; @Error 1 @Extended 2 Return 0 = $oCell not a Cell Object.
; --Processing Errors--
; @Error 3 @Extended 1 Return 0 = Failed to retrieve called Cell's Address.
; @Error 3 @Extended 2 Return 0 = Failed to process Trace Error function.
; --Success--
; @Error 0 @Extended 0 Return Boolean = Success. Returns True if Errors were marked, else False.
; Author ........: donnyh13
; Modified ......:
; Remarks .......:
; Related .......: _LOCalc_SheetDetectivePrecedent, _LOCalc_SheetDetectiveDependent, _LOCalc_SheetDetectiveClear, _LOCalc_SheetDetectiveInvalidData
; Link ..........:
; Example .......: Yes
; ===============================================================================================================================
Func _LOCalc_SheetDetectiveTraceError(ByRef $oCell)
Local $oCOM_ErrorHandler = ObjEvent("AutoIt.Error", __LOCalc_InternalComErrorHandler)
#forceref $oCOM_ErrorHandler
Local $bReturn
Local $tCellAddress
If Not IsObj($oCell) Then Return SetError($__LO_STATUS_INPUT_ERROR, 1, 0)
If Not ($oCell.supportsService("com.sun.star.sheet.SheetCell")) Then Return SetError($__LO_STATUS_INPUT_ERROR, 2, 0) ; Only single cells supported.
$tCellAddress = $oCell.CellAddress()
If Not IsObj($tCellAddress) Then Return SetError($__LO_STATUS_PROCESSING_ERROR, 1, 0)
$bReturn = $oCell.Spreadsheet.showErrors($tCellAddress)
If Not IsBool($bReturn) Then Return SetError($__LO_STATUS_PROCESSING_ERROR, 2, 0)
Return SetError($__LO_STATUS_SUCCESS, 0, $bReturn)
EndFunc ;==>_LOCalc_SheetDetectiveTraceError
; #FUNCTION# ====================================================================================================================
; Name ..........: _LOCalc_SheetExists
; Description ...: Check whether a Calc document has a Sheet with a specific name.
; Syntax ........: _LOCalc_SheetExists(ByRef $oDoc, $sName)
; Parameters ....: $oDoc - [in/out] an object. A Document object returned by a previous _LOCalc_DocOpen, _LOCalc_DocConnect, or _LOCalc_DocCreate function.
; $sName - a string value. The sheet name to check for.
; Return values .: Success: Boolean
; Failure: 0 and sets the @Error and @Extended flags to non-zero.
; --Input Errors--
; @Error 1 @Extended 1 Return 0 = $oDoc not an Object.
; @Error 1 @Extended 2 Return 0 = $sName not a String.
; --Processing Errors--
; @Error 3 @Extended 1 Return 0 = Failed to retrieve Sheets Object.
; --Success--
; @Error 0 @Extended 0 Return Boolean = Success. If the document contains a Sheet matching $sName, True is returned. Else False.
; Author ........: donnyh13
; Modified ......:
; Remarks .......:
; Related .......:
; Link ..........:
; Example .......: Yes
; ===============================================================================================================================
Func _LOCalc_SheetExists(ByRef $oDoc, $sName)
Local $oCOM_ErrorHandler = ObjEvent("AutoIt.Error", __LOCalc_InternalComErrorHandler)
#forceref $oCOM_ErrorHandler
Local $oSheets
If Not IsObj($oDoc) Then Return SetError($__LO_STATUS_INPUT_ERROR, 1, 0)
If Not IsString($sName) Then Return SetError($__LO_STATUS_INPUT_ERROR, 2, 0)
$oSheets = $oDoc.Sheets()
If Not IsObj($oSheets) Then Return SetError($__LO_STATUS_PROCESSING_ERROR, 1, 0)
If $oSheets.hasByName($sName) Then Return SetError($__LO_STATUS_Success, 0, True)
Return SetError($__LO_STATUS_SUCCESS, 0, False)
EndFunc ;==>_LOCalc_SheetExists
; #FUNCTION# ====================================================================================================================
; Name ..........: _LOCalc_SheetGetActive
; Description ...: Retrieve a Sheet object for the currently active Sheet.
; Syntax ........: _LOCalc_SheetGetActive(ByRef $oDoc)
; Parameters ....: $oDoc - [in/out] an object. A Document object returned by a previous _LOCalc_DocOpen, _LOCalc_DocConnect, or _LOCalc_DocCreate function.
; Return values .: Success: Object
; Failure: 0 and sets the @Error and @Extended flags to non-zero.
; --Input Errors--
; @Error 1 @Extended 1 Return 0 = $oDoc not an Object.
; --Processing Errors--
; @Error 3 @Extended 1 Return 0 = Failed to retrieve Active Sheet's Object.
; --Success--
; @Error 0 @Extended 0 Return Object = Success. Successfully retrieved the Active Sheet, returning its Object.
; Author ........: donnyh13
; Modified ......:
; Remarks .......:
; Related .......: _LOCalc_SheetGetObjByName
; Link ..........:
; Example .......: Yes
; ===============================================================================================================================
Func _LOCalc_SheetGetActive(ByRef $oDoc)
Local $oCOM_ErrorHandler = ObjEvent("AutoIt.Error", __LOCalc_InternalComErrorHandler)
#forceref $oCOM_ErrorHandler
Local $oSheet
If Not IsObj($oDoc) Then Return SetError($__LO_STATUS_INPUT_ERROR, 1, 0)
$oSheet = $oDoc.CurrentController.getActiveSheet()
If Not IsObj($oSheet) Then Return SetError($__LO_STATUS_PROCESSING_ERROR, 1, 0)
Return SetError($__LO_STATUS_SUCCESS, 0, $oSheet)
EndFunc ;==>_LOCalc_SheetGetActive
; #FUNCTION# ====================================================================================================================
; Name ..........: _LOCalc_SheetGetObjByName
; Description ...: Retrieve a Sheet Object for a specific Sheet by name.
; Syntax ........: _LOCalc_SheetGetObjByName(ByRef $oDoc, $sName)
; Parameters ....: $oDoc - [in/out] an object. A Document object returned by a previous _LOCalc_DocOpen, _LOCalc_DocConnect, or _LOCalc_DocCreate function.
; $sName - a string value. The sheet name to retrieve the Object for.
; Return values .: Success: Object
; Failure: 0 and sets the @Error and @Extended flags to non-zero.
; --Input Errors--
; @Error 1 @Extended 1 Return 0 = $oDoc not an Object.
; @Error 1 @Extended 2 Return 0 = $sName not a String.
; @Error 1 @Extended 3 Return 0 = Document does not contain a sheet with name called in $sName.
; --Processing Errors--
; @Error 3 @Extended 1 Return 0 = Failed to retrieve Sheets Object.
; @Error 3 @Extended 2 Return 0 = Failed to retrieve requested Sheet's object.
; --Success--
; @Error 0 @Extended 0 Return Object = Success. Returning requested Sheet's object.
; Author ........: donnyh13
; Modified ......:
; Remarks .......:
; Related .......: _LOCalc_SheetsGetNames
; Link ..........:
; Example .......: Yes
; ===============================================================================================================================
Func _LOCalc_SheetGetObjByName(ByRef $oDoc, $sName)
Local $oCOM_ErrorHandler = ObjEvent("AutoIt.Error", __LOCalc_InternalComErrorHandler)
#forceref $oCOM_ErrorHandler
Local $oSheet, $oSheets
If Not IsObj($oDoc) Then Return SetError($__LO_STATUS_INPUT_ERROR, 1, 0)
If Not IsString($sName) Then Return SetError($__LO_STATUS_INPUT_ERROR, 2, 0)
$oSheets = $oDoc.Sheets()
If Not IsObj($oSheets) Then Return SetError($__LO_STATUS_PROCESSING_ERROR, 1, 0)
If Not $oSheets.hasByName($sName) Then Return SetError($__LO_STATUS_INPUT_ERROR, 3, 0)
$oSheet = $oSheets.getByName($sName)
If Not IsObj($oSheet) Then Return SetError($__LO_STATUS_PROCESSING_ERROR, 2, 0)
Return SetError($__LO_STATUS_SUCCESS, 0, $oSheet)
EndFunc ;==>_LOCalc_SheetGetObjByName
; #FUNCTION# ====================================================================================================================
; Name ..........: _LOCalc_SheetGetObjByPosition
; Description ...: Retrieve a Sheet Object for a specific Sheet by position.
; Syntax ........: _LOCalc_SheetGetObjByPosition(ByRef $oDoc, $iPosition)
; Parameters ....: $oDoc - [in/out] an object. A Document object returned by a previous _LOCalc_DocOpen, _LOCalc_DocConnect, or _LOCalc_DocCreate function.
; $iPosition - an integer value. The 0 based position of the Sheet, to retrieve the Object for.
; Return values .: Success: Object
; Failure: 0 and sets the @Error and @Extended flags to non-zero.
; --Input Errors--
; @Error 1 @Extended 1 Return 0 = $oDoc not an Object.
; @Error 1 @Extended 2 Return 0 = $iPosition not an Integer, less than 0 or greater than number of Sheets contained in the document.
; --Processing Errors--
; @Error 3 @Extended 1 Return 0 = Failed to retrieve Sheets Object.
; @Error 3 @Extended 2 Return 0 = Failed to retrieve requested Sheet's object.
; --Success--
; @Error 0 @Extended 0 Return Object = Success. Returning requested Sheet's object.
; Author ........: donnyh13
; Modified ......:
; Remarks .......: The Sheet position aligns with the order they are displayed at the bottom of the document. 0 based.
; Related .......: _LOCalc_SheetsGetCount, _LOCalc_SheetGetObjByName
; Link ..........:
; Example .......: Yes
; ===============================================================================================================================
Func _LOCalc_SheetGetObjByPosition(ByRef $oDoc, $iPosition)
Local $oCOM_ErrorHandler = ObjEvent("AutoIt.Error", __LOCalc_InternalComErrorHandler)
#forceref $oCOM_ErrorHandler
Local $oSheet, $oSheets
If Not IsObj($oDoc) Then Return SetError($__LO_STATUS_INPUT_ERROR, 1, 0)
If Not __LOCalc_IntIsBetween($iPosition, 0, $oDoc.Sheets.Count() - 1) Then Return SetError($__LO_STATUS_INPUT_ERROR, 2, 0)
$oSheets = $oDoc.Sheets()
If Not IsObj($oSheets) Then Return SetError($__LO_STATUS_PROCESSING_ERROR, 1, 0)
$oSheet = $oSheets.getByIndex($iPosition)
If Not IsObj($oSheet) Then Return SetError($__LO_STATUS_PROCESSING_ERROR, 2, 0)
Return SetError($__LO_STATUS_SUCCESS, 0, $oSheet)
EndFunc ;==>_LOCalc_SheetGetObjByPosition
; #FUNCTION# ====================================================================================================================
; Name ..........: _LOCalc_SheetImport
; Description ...: Import a Sheet from another Document. L.O. 3.5 and up.
; Syntax ........: _LOCalc_SheetImport(ByRef $oSourceDoc, ByRef $oDestDoc, $sSheetName[, $bInsertAfter = False])
; Parameters ....: $oSourceDoc - [in/out] an object. The Document containing the desired Sheet. A Document object returned by a previous _LOCalc_DocOpen, _LOCalc_DocConnect, or _LOCalc_DocCreate function.
; $oDestDoc - [in/out] an object. The Document to Import the Sheet to. A Document object returned by a previous _LOCalc_DocOpen, _LOCalc_DocConnect, or _LOCalc_DocCreate function.
; $sSheetName - a string value. The Sheet's name to import from the Source Document.
; $bInsertAfter - [optional] a boolean value. Default is False. If True, the Sheet is inserted after the currently active Sheet. If False, the Sheet is inserted before the currently active Sheet.
; Return values .: Success: Object
; Failure: 0 and sets the @Error and @Extended flags to non-zero.
; --Input Errors--
; @Error 1 @Extended 1 Return 0 = $oSourceDoc not an Object.
; @Error 1 @Extended 2 Return 0 = $oDestDoc not an Object.
; @Error 1 @Extended 3 Return 0 = $sSheetName not a String.
; @Error 1 @Extended 4 Return 0 = Document called in $oSourceDoc does not have a Sheet with the name called in $sSheetName.
; @Error 1 @Extended 5 Return 0 = $bInsertAfter not a Boolean.
; --Processing Errors--
; @Error 3 @Extended 1 Return 0 = Failed to retrieve Destination Document's currently active Sheet's position.
; @Error 3 @Extended 2 Return 0 = Failed to import the Sheet.
; @Error 3 @Extended 3 Return 0 = Failed to retrieve new Sheet's Object.
; --Version Related Errors--
; @Error 7 @Extended 1 Return 0 = Current Libre Office Version less than 3.5.
; --Success--
; @Error 0 @Extended 0 Return Object = Success. Successfully imported the requested Sheet, returning the new Sheet's Object.
; Author ........: donnyh13
; Modified ......:
; Remarks .......:
; Related .......: _LOCalc_SheetLink
; Link ..........:
; Example .......: Yes
; ===============================================================================================================================
Func _LOCalc_SheetImport(ByRef $oSourceDoc, ByRef $oDestDoc, $sSheetName, $bInsertAfter = False)
Local $oCOM_ErrorHandler = ObjEvent("AutoIt.Error", __LOCalc_InternalComErrorHandler)
#forceref $oCOM_ErrorHandler
Local $iPosition, $iNewSheet
Local $oSheet
If Not __LOCalc_VersionCheck(3.5) Then Return SetError($__LO_STATUS_VER_ERROR, 1, 0)
If Not IsObj($oSourceDoc) Then Return SetError($__LO_STATUS_INPUT_ERROR, 1, 0)
If Not IsObj($oDestDoc) Then Return SetError($__LO_STATUS_INPUT_ERROR, 2, 0)
If Not IsString($sSheetName) Then Return SetError($__LO_STATUS_INPUT_ERROR, 3, 0)
If Not $oSourceDoc.Sheets.hasByName($sSheetName) Then Return SetError($__LO_STATUS_INPUT_ERROR, 4, 0)
If Not IsBool($bInsertAfter) Then Return SetError($__LO_STATUS_INPUT_ERROR, 5, 0)
$iPosition = $oDestDoc.CurrentController.getActiveSheet().RangeAddress.Sheet()
If Not IsInt($iPosition) Then Return SetError($__LO_STATUS_PROCESSING_ERROR, 1, 0)
$iPosition = ($bInsertAfter) ? ($iPosition + 1) : ($iPosition)
$iNewSheet = $oDestDoc.Sheets.importSheet($oSourceDoc, $sSheetName, $iPosition)
If Not IsInt($iNewSheet) Then Return SetError($__LO_STATUS_PROCESSING_ERROR, 2, 0)
$oSheet = $oDestDoc.Sheets.getByIndex($iNewSheet)
If Not IsObj($oSheet) Then Return SetError($__LO_STATUS_PROCESSING_ERROR, 3, 0)
Return SetError($__LO_STATUS_SUCCESS, 0, $oSheet)
EndFunc ;==>_LOCalc_SheetImport
; #FUNCTION# ====================================================================================================================
; Name ..........: _LOCalc_SheetIsActive
; Description ...: Check if a particular Sheet is the active Sheet.
; Syntax ........: _LOCalc_SheetIsActive(ByRef $oDoc, ByRef $oSheet)
; Parameters ....: $oDoc - [in/out] an object. A Document object returned by a previous _LOCalc_DocOpen, _LOCalc_DocConnect, or _LOCalc_DocCreate function.
; $oSheet - [in/out] an object. A Sheet object returned by a previous _LOCalc_SheetAdd, _LOCalc_SheetGetActive, _LOCalc_SheetCopy, or _LOCalc_SheetGetObjByName function.
; Return values .: Success: Boolean
; Failure: 0 and sets the @Error and @Extended flags to non-zero.
; --Input Errors--
; @Error 1 @Extended 1 Return 0 = $oDoc not an Object.
; @Error 1 @Extended 2 Return 0 = $oSheet not an Object.
; --Processing Errors--
; @Error 3 @Extended 1 Return 0 = Failed to retrieve Sheets Object.
; --Success--
; @Error 0 @Extended 0 Return Boolean = Success. If the called Sheet is the currently active sheet, True is returned. Else False.
; Author ........: donnyh13
; Modified ......:
; Remarks .......:
; Related .......: _LOCalc_SheetActivate
; Link ..........:
; Example .......: Yes
; ===============================================================================================================================
Func _LOCalc_SheetIsActive(ByRef $oDoc, ByRef $oSheet)
Local $oCOM_ErrorHandler = ObjEvent("AutoIt.Error", __LOCalc_InternalComErrorHandler)
#forceref $oCOM_ErrorHandler
Local $oSheet2
If Not IsObj($oDoc) Then Return SetError($__LO_STATUS_INPUT_ERROR, 1, 0)
If Not IsObj($oSheet) Then Return SetError($__LO_STATUS_INPUT_ERROR, 2, 0)
$oSheet2 = $oDoc.CurrentController.getActiveSheet()
If Not IsObj($oSheet2) Then Return SetError($__LO_STATUS_PROCESSING_ERROR, 1, 0)
If ($oSheet.AbsoluteName() = $oSheet2.AbsoluteName()) Then Return SetError($__LO_STATUS_SUCCESS, 0, True)
Return SetError($__LO_STATUS_SUCCESS, 0, False)
EndFunc ;==>_LOCalc_SheetIsActive
; #FUNCTION# ====================================================================================================================
; Name ..........: _LOCalc_SheetIsProtected
; Description ...: Check whether a Sheet is password protected or not.
; Syntax ........: _LOCalc_SheetIsProtected(ByRef $oSheet)
; Parameters ....: $oSheet - [in/out] an object. A Sheet object returned by a previous _LOCalc_SheetAdd, _LOCalc_SheetGetActive, _LOCalc_SheetCopy, or _LOCalc_SheetGetObjByName function.
; Return values .: Success: Boolean
; Failure: 0 and sets the @Error and @Extended flags to non-zero.
; --Input Errors--
; @Error 1 @Extended 1 Return 0 = $oSheet not an Object.
; --Processing Errors--
; @Error 3 @Extended 1 Return 0 = Failed to query Sheet's current protection status.
; --Success--
; @Error 0 @Extended 0 Return Boolean = Success. Successfully queried Sheet's protection status, returning a boolean indicating if the sheet is currently protected (True), or not (False).
; Author ........: donnyh13
; Modified ......:
; Remarks .......:
; Related .......: _LOCalc_SheetProtect, _LOCalc_SheetUnprotect
; Link ..........:
; Example .......: Yes
; ===============================================================================================================================
Func _LOCalc_SheetIsProtected(ByRef $oSheet)
Local $oCOM_ErrorHandler = ObjEvent("AutoIt.Error", __LOCalc_InternalComErrorHandler)
#forceref $oCOM_ErrorHandler
Local $bReturn
If Not IsObj($oSheet) Then Return SetError($__LO_STATUS_INPUT_ERROR, 1, 0)
$bReturn = $oSheet.isProtected()
If Not IsBool($bReturn) Then Return SetError($__LO_STATUS_PROCESSING_ERROR, 1, 0)
Return SetError($__LO_STATUS_SUCCESS, 0, $bReturn)
EndFunc ;==>_LOCalc_SheetIsProtected
; #FUNCTION# ====================================================================================================================
; Name ..........: _LOCalc_SheetLink
; Description ...: Create a new Sheet and Link to an external Sheet in another Document.
; Syntax ........: _LOCalc_SheetLink(ByRef $oSourceDoc, ByRef $oDestDoc, $sSheetName[, $iLinkMode = $LOC_SHEET_LINK_MODE_NORMAL[, $bInsertAfter = False]])
; Parameters ....: $oSourceDoc - [in/out] an object. The Document containing the desired Sheet. Must have been previously saved to a location. A Document object returned by a previous _LOCalc_DocOpen, _LOCalc_DocConnect, or _LOCalc_DocCreate function.
; $oDestDoc - [in/out] an object. The Document to Import the Sheet to. A Document object returned by a previous _LOCalc_DocOpen, _LOCalc_DocConnect, or _LOCalc_DocCreate function.
; $sSheetName - a string value. The Sheet's name to import from the Source Document.
; $iLinkMode - [optional] an integer value (0-2). Default is $LOC_SHEET_LINK_MODE_NORMAL. The content to link from the Sheet. See Constants $LOC_SHEET_LINK_MODE_* as defined in LibreOfficeCalc_Constants.au3.
; $bInsertAfter - [optional] a boolean value. Default is False. If True, the Sheet is inserted after the currently active Sheet. If False, the Sheet is inserted before the currently active Sheet.
; Return values .: Success: Object
; Failure: 0 and sets the @Error and @Extended flags to non-zero.
; --Input Errors--
; @Error 1 @Extended 1 Return 0 = $oSourceDoc not an Object.
; @Error 1 @Extended 2 Return 0 = $oDestDoc not an Object.
; @Error 1 @Extended 3 Return 0 = $sSheetName not a String.
; @Error 1 @Extended 4 Return 0 = $iLinkMode not an Integer, less than 0, or greater than 2. See Constants $LOC_SHEET_LINK_MODE_* as defined in LibreOfficeCalc_Constants.au3.
; @Error 1 @Extended 5 Return 0 = Document called in $oSourceDoc has no save location.
; @Error 1 @Extended 6 Return 0 = Document called in $oSourceDoc does not have a Sheet with the name called in $sSheetName.
; @Error 1 @Extended 7 Return 0 = $bInsertAfter not a Boolean.
; --Processing Errors--
; @Error 3 @Extended 1 Return 0 = Failed to Create a name for new Sheet in Destination Document.
; @Error 3 @Extended 2 Return 0 = Failed to retrieve Destination Document's currently active Sheet's position.
; @Error 3 @Extended 3 Return 0 = Failed to retrieve new Sheet's Object.
; --Success--
; @Error 0 @Extended 0 Return Object = Success. Successfully inserted and linked the new Sheet, returning the new Sheet's Object.
; Author ........: donnyh13
; Modified ......:
; Remarks .......:
; Related .......: _LOCalc_SheetImport
; Link ..........:
; Example .......: Yes
; ===============================================================================================================================
Func _LOCalc_SheetLink(ByRef $oSourceDoc, ByRef $oDestDoc, $sSheetName, $iLinkMode = $LOC_SHEET_LINK_MODE_NORMAL, $bInsertAfter = False)
Local $oCOM_ErrorHandler = ObjEvent("AutoIt.Error", __LOCalc_InternalComErrorHandler)
#forceref $oCOM_ErrorHandler
Local $sName
Local $iCount, $iPosition
Local $oSheet
If Not IsObj($oSourceDoc) Then Return SetError($__LO_STATUS_INPUT_ERROR, 1, 0)
If Not IsObj($oDestDoc) Then Return SetError($__LO_STATUS_INPUT_ERROR, 2, 0)
If Not IsString($sSheetName) Then Return SetError($__LO_STATUS_INPUT_ERROR, 3, 0)
If Not __LOCalc_IntIsBetween($iLinkMode, $LOC_SHEET_LINK_MODE_NONE, $LOC_SHEET_LINK_MODE_VALUE) Then Return SetError($__LO_STATUS_INPUT_ERROR, 4, 0)
If ($oSourceDoc.URL() = "") Then Return SetError($__LO_STATUS_INPUT_ERROR, 5, 0)
If Not $oSourceDoc.Sheets.hasByName($sSheetName) Then Return SetError($__LO_STATUS_INPUT_ERROR, 6, 0)
If Not IsBool($bInsertAfter) Then Return SetError($__LO_STATUS_INPUT_ERROR, 7, 0)
If $oDestDoc.Sheets.hasByName($sSheetName) Then
$sName = $sSheetName & "_2"
If $oDestDoc.Sheets.hasByName($sName) Then
$iCount = 2
While $oDestDoc.Sheets.hasByName($sName)
$iCount += 1
$sName = $sSheetName & "_" & $iCount
WEnd
EndIf
Else
$sName = $sSheetName
EndIf
If Not IsString($sName) Then Return SetError($__LO_STATUS_PROCESSING_ERROR, 1, 0)
$iPosition = $oDestDoc.CurrentController.getActiveSheet().RangeAddress.Sheet()
If Not IsInt($iPosition) Then Return SetError($__LO_STATUS_PROCESSING_ERROR, 2, 0)
$iPosition = ($bInsertAfter) ? ($iPosition + 1) : ($iPosition - 1)
$oDestDoc.Sheets.insertNewByName($sName, $iPosition)
$oSheet = $oDestDoc.Sheets.getByName($sName)
If Not IsObj($oSheet) Then Return SetError($__LO_STATUS_PROCESSING_ERROR, 3, 0)
$oSheet.link($oSourceDoc.URL(), $sSheetName, "", "", $iLinkMode)
Return SetError($__LO_STATUS_SUCCESS, 0, $oSheet)
EndFunc ;==>_LOCalc_SheetLink
; #FUNCTION# ====================================================================================================================
; Name ..........: _LOCalc_SheetLinkModify
; Description ...: Set or Retrieve the Linked settings of a Sheet.
; Syntax ........: _LOCalc_SheetLinkModify(ByRef $oSheet[, $oNewDoc = Null[, $sSheetName = Null[, $iLinkMode = Null]]])
; Parameters ....: $oSheet - [in/out] an object. A Sheet object returned by a previous _LOCalc_SheetAdd, _LOCalc_SheetGetActive, _LOCalc_SheetCopy, or _LOCalc_SheetGetObjByName function.
; $oNewDoc - [optional] an object. Default is Null. A New Document to link a new sheet from. A Document object returned by a previous _LOCalc_DocOpen, _LOCalc_DocConnect, or _LOCalc_DocCreate function.
; $sSheetName - [optional] a string value. Default is Null. The Sheet name to link to.
; $iLinkMode - [optional] an integer value (0-2). Default is Null. The content to link from the Sheet. See Constants $LOC_SHEET_LINK_MODE_* as defined in LibreOfficeCalc_Constants.au3.
; Return values .: Success: 1 or Array
; Failure: 0 and sets the @Error and @Extended flags to non-zero.
; --Input Errors--
; @Error 1 @Extended 1 Return 0 = $oSheet not an Object.
; @Error 1 @Extended 2 Return 0 = $oNewDoc not an Object.
; @Error 1 @Extended 3 Return 0 = $sSheetName not a String.
; @Error 1 @Extended 4 Return 0 = $iLinkMode not an Integer, less than 0, or greater than 2. See Constants $LOC_SHEET_LINK_MODE_* as defined in LibreOfficeCalc_Constants.au3.
; @Error 1 @Extended 5 Return 0 = Document called in $oNewDoc has no save location.
; @Error 1 @Extended 6 Return 0 = Document called in $oNewDoc does not have a Sheet with the name called in $sSheetName.
; @Error 1 @Extended 7 Return 0 = Document currently set as source does not contain a Sheet with the name as called in $sSheetName.
; --Processing Errors--
; @Error 3 @Extended 1 Return 0 = Failed to set $sSheetName, Sheet has not been linked before, and has no source document to find $sSheetName in.
; @Error 3 @Extended 2 Return 0 = Failed to open source document set for this Sheet.
; @Error 3 @Extended 3 Return 0 = Failed to set $iLinkMode, Sheet isn't currently linked.
; --Property Setting Errors--
; @Error 4 @Extended ? Return 0 = Some settings were not successfully set. Use BitAND to test @Extended for following values:
; | 1 = Error setting $oNewDoc
; | 2 = Error setting $sSheetName
; | 4 = Error setting $iLinkMode
; --Success--
; @Error 0 @Extended 0 Return 1 = Success. Settings were successfully set.
; @Error 0 @Extended 1 Return Array = Success. All optional parameters were set to Null, returning current settings in a 3 Element Array with values in order of function parameters.
; Author ........: donnyh13
; Modified ......:
; Remarks .......: Call this function with only the required parameters (or with all other parameters set to Null keyword), to get the current settings.
; Call any optional parameter with Null keyword to skip it.
; The Return for $oNewDoc is the File path of the linked Document.
; If you set $oNewDoc, you must set $sSheetName and $iLinkMode also.
; To unlink a Sheet, call $iLinkMode with $LOC_SHEET_LINK_MODE_NONE.
; Related .......: _LOCalc_SheetLink
; Link ..........:
; Example .......: Yes
; ===============================================================================================================================
Func _LOCalc_SheetLinkModify(ByRef $oSheet, $oNewDoc = Null, $sSheetName = Null, $iLinkMode = Null)
Local $oCOM_ErrorHandler = ObjEvent("AutoIt.Error", __LOCalc_InternalComErrorHandler)
#forceref $oCOM_ErrorHandler
Local $oSourceDoc
Local $iError = 0
Local $bClose = True
Local $avSheet[3]
If Not IsObj($oSheet) Then Return SetError($__LO_STATUS_INPUT_ERROR, 1, 0)
If __LOCalc_VarsAreNull($oNewDoc, $sSheetName, $iLinkMode) Then
__LOCalc_ArrayFill($avSheet, _LOCalc_PathConvert($oSheet.LinkUrl(), $LOC_PATHCONV_PCPATH_RETURN), $oSheet.LinkSheetName(), $oSheet.LinkMode())
Return SetError($__LO_STATUS_SUCCESS, 1, $avSheet)
EndIf
If ($oNewDoc <> Null) Then
If Not IsObj($oNewDoc) Then Return SetError($__LO_STATUS_INPUT_ERROR, 2, 0)
If Not IsString($sSheetName) Then Return SetError($__LO_STATUS_INPUT_ERROR, 3, 0)
If Not __LOCalc_IntIsBetween($iLinkMode, $LOC_SHEET_LINK_MODE_NONE, $LOC_SHEET_LINK_MODE_VALUE) Then Return SetError($__LO_STATUS_INPUT_ERROR, 4, 0)
If ($oNewDoc.URL() = "") Then Return SetError($__LO_STATUS_INPUT_ERROR, 5, 0)
If Not $oNewDoc.Sheets.hasByName($sSheetName) Then Return SetError($__LO_STATUS_INPUT_ERROR, 6, 0)
$oSheet.link($oSourceDoc.URL(), $sSheetName, "", "", $iLinkMode)
$iError = ($oSheet.LinkUrl() = $oNewDoc.URL()) ? ($iError) : (BitOR($iError, 1))
$iError = ($oSheet.LinkSheetName() = $sSheetName) ? ($iError) : (BitOR($iError, 2))
$iError = ($oSheet.LinkMode() = $iLinkMode) ? ($iError) : (BitOR($iError, 4))
EndIf
If ($sSheetName <> Null) Then
If Not IsString($sSheetName) Then Return SetError($__LO_STATUS_INPUT_ERROR, 3, 0)
If ($oSheet.LinkUrl() = "") Then Return SetError($__LO_STATUS_PROCESSING_ERROR, 1, 0)
$oSourceDoc = _LOCalc_DocOpen(_LOCalc_PathConvert($oSheet.LinkUrl(), $LOC_PATHCONV_PCPATH_RETURN), True, True)
If @error Then Return SetError($__LO_STATUS_PROCESSING_ERROR, 2, 0)
$bClose = (@extended = 2) ? (True) : (False)
If Not $oSourceDoc.Sheets.hasByName($sSheetName) Then Return SetError($__LO_STATUS_INPUT_ERROR, 7, $oSourceDoc.Close(True))
If $bClose Then $oSourceDoc.Close(True)
$oSheet.LinkSheetName = $sSheetName
$iError = ($oSheet.LinkSheetName() = $sSheetName) ? ($iError) : (BitOR($iError, 2))
EndIf
If ($iLinkMode <> Null) Then
If Not __LOCalc_IntIsBetween($iLinkMode, $LOC_SHEET_LINK_MODE_NONE, $LOC_SHEET_LINK_MODE_VALUE) Then Return SetError($__LO_STATUS_INPUT_ERROR, 4, 0)
If ($iLinkMode = $LOC_SHEET_LINK_MODE_NONE) Then
With $oSheet
.LinkUrl = ""
.LinkSheetName = ""
.LinkMode = $iLinkMode
EndWith
$iError = ($oSheet.LinkUrl() = "") ? ($iError) : (BitOR($iError, 1))
$iError = ($oSheet.LinkSheetName() = "") ? ($iError) : (BitOR($iError, 2))
$iError = ($oSheet.LinkMode() = $iLinkMode) ? ($iError) : (BitOR($iError, 4))
Else
If ($oSheet.LinkUrl() = "") Then Return SetError($__LO_STATUS_PROCESSING_ERROR, 3, 0)
$oSheet.LinkMode = $iLinkMode
$iError = ($oSheet.LinkMode() = $iLinkMode) ? ($iError) : (BitOR($iError, 4))
EndIf
EndIf
Return ($iError > 0) ? (SetError($__LO_STATUS_PROP_SETTING_ERROR, $iError, 0)) : (SetError($__LO_STATUS_SUCCESS, 0, 1))
EndFunc ;==>_LOCalc_SheetLinkModify
; #FUNCTION# ====================================================================================================================
; Name ..........: _LOCalc_SheetMove
; Description ...: Set or Retrieve a Sheet's position in the list of Sheets in a Calc Document.
; Syntax ........: _LOCalc_SheetMove(ByRef $oDoc, ByRef $oSheet[, $iPosition = Null])
; Parameters ....: $oDoc - [in/out] an object. A Document object returned by a previous _LOCalc_DocOpen, _LOCalc_DocConnect, or _LOCalc_DocCreate function.
; $oSheet - [in/out] an object. A Sheet object returned by a previous _LOCalc_SheetAdd, _LOCalc_SheetGetActive, _LOCalc_SheetCopy, or _LOCalc_SheetGetObjByName function.
; $iPosition - [optional] an integer value. Default is Null.The Position the move the Sheet to, 0 being the beginning.
; Return values .: Success: 1 or Integer
; Failure: 0 and sets the @Error and @Extended flags to non-zero.
; --Input Errors--
; @Error 1 @Extended 1 Return 0 = $oDoc not an Object.
; @Error 1 @Extended 2 Return 0 = $oSheet not an Object.
; @Error 1 @Extended 3 Return 0 = $iPosition not an Integer, less than 0 or greater than number of sheets contained in the document.
; --Processing Errors--
; @Error 3 @Extended 1 Return 0 = Failed to retrieve Sheet's name.
; @Error 3 @Extended 2 Return 0 = Failed to retrieve Sheets Object.
; --Success--
; @Error 0 @Extended 0 Return 1 = Success. Sheet was successfully moved.
; @Error 0 @Extended 0 Return Integer = Success. $iPosition called with Null, returning Sheet's current position.
; Author ........: donnyh13
; Modified ......:
; Remarks .......: Calling $iPosition with the number of Sheets in the Document will place the moved sheet at the end of the sheet list.
; Related .......: _LOCalc_SheetCopy
; Link ..........:
; Example .......: Yes
; ===============================================================================================================================
Func _LOCalc_SheetMove(ByRef $oDoc, ByRef $oSheet, $iPosition = Null)
Local $oCOM_ErrorHandler = ObjEvent("AutoIt.Error", __LOCalc_InternalComErrorHandler)
#forceref $oCOM_ErrorHandler
Local $oSheets
Local $sName
If Not IsObj($oDoc) Then Return SetError($__LO_STATUS_INPUT_ERROR, 1, 0)
If Not IsObj($oSheet) Then Return SetError($__LO_STATUS_INPUT_ERROR, 2, 0)
If ($iPosition = Null) Then Return SetError($__LO_STATUS_SUCCESS, 1, $oSheet.RangeAddress.Sheet())
$sName = $oSheet.Name()
If Not IsString($sName) Then Return SetError($__LO_STATUS_PROCESSING_ERROR, 1, 0)
$oSheets = $oDoc.Sheets()
If Not IsObj($oSheets) Then Return SetError($__LO_STATUS_PROCESSING_ERROR, 2, 0)
If Not __LOCalc_IntIsBetween($iPosition, 0, $oSheets.Count()) Then Return SetError($__LO_STATUS_INPUT_ERROR, 3, 0)