-
Notifications
You must be signed in to change notification settings - Fork 3
/
AstroTracker.ino
1411 lines (1297 loc) · 36.4 KB
/
AstroTracker.ino
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
833
834
835
836
837
838
839
840
841
842
843
844
845
846
847
848
849
850
851
852
853
854
855
856
857
858
859
860
861
862
863
864
865
866
867
868
869
870
871
872
873
874
875
876
877
878
879
880
881
882
883
884
885
886
887
888
889
890
891
892
893
894
895
896
897
898
899
900
901
902
903
904
905
906
907
908
909
910
911
912
913
914
915
916
917
918
919
920
921
922
923
924
925
926
927
928
929
930
931
932
933
934
935
936
937
938
939
940
941
942
943
944
945
946
947
948
949
950
951
952
953
954
955
956
957
958
959
960
961
962
963
964
965
966
967
968
969
970
971
972
973
974
975
976
977
978
979
980
981
982
983
984
985
986
987
988
989
990
991
992
993
994
995
996
997
998
999
1000
/*=============================================================================
======= INCLUDES =======
=============================================================================*/
#include <WiFi.h>
#include <WiFiClient.h>
#include <WebServer.h>
#include <Preferences.h>
/*=============================================================================
======= DEFINES & MACROS =======
=============================================================================*/
#define USE_GPS_MODULE
// day rotation times [ms]
#define SPEED_0_5X 172800000ul
#define LUNAR_DAY 89428329ul
#define SOLAR_DAY 86400000ul
#define SIDEREAL_DAY 86164091ul
#define SPEED_1_5X 57600000ul
#define SPEED_2X 43200000ul
#define SPEED_4X 21600000ul
// arc seconds
#define RA_SECONDS_360 (24ul * 60ul * 60ul) // 86400 sec
#define DEC_SECONDS_90 (90ul * 60ul * 60ul) // 324000 sec
#define DEC_SECONDS_270 (270ul * 60ul * 60ul) // 972000 sec
#define DEC_SECONDS_360 (360ul * 60ul * 60ul) // 1296000 sec
// gpios
#define STATUS_LED_PIN 2
#define RA_LED_PIN 0
#define DEC_LED_PIN 4
#define RA_PHASE1_PIN 12
#define RA_PHASE2_PIN 13
#define RA_PHASE3_PIN 14
#define RA_PHASE4_PIN 15
#define DEC_PHASE1_PIN 16
#define DEC_PHASE2_PIN 17
#define DEC_PHASE3_PIN 18
#define DEC_PHASE4_PIN 19
#define ONE_PPS_PIN 21
#define UART1_RX_PIN 22
#define UART1_TX_PIN 23
#define AUTOGUIDE_RA_M 26
#define AUTOGUIDE_RA_P 27
#define AUTOGUIDE_DEC_M 32
#define AUTOGUIDE_DEC_P 33
// CPU cores
#define CORE_PRO_CPU 0
#define CORE_APP_CPU 1
// task priorities and stack size
#define TASK_LOW_PRIO 2
#define TASK_HIGH_PRIO 3
#define TASK_STACK_SIZE 0x1000
// other
#define MAX_CLIENTS 3
#define ONE_PPS_SAMPLES 12
#define WEBPAGE_BUFFER_SIZE 3500
/*=============================================================================
======= CONSTANTS & TYPES =======
=============================================================================*/
const char* ssid = "ASTRO_TRACKER";
const char* password = "xxxxxxxx";
typedef struct
{
boolean ra_fast_tracking;
uint8_t ra_step;
uint32_t ra_old;
uint32_t ra_new;
uint32_t ra_actual;
uint32_t ra_steps;
uint32_t ra_steps_total;
uint8_t ra_dir;
uint8_t ra_east;
uint8_t ra_west;
uint8_t ra_speed; // 0 - off, 1 - sidereal, 2 - solar, 3 - lunar
boolean ra_corr_m;
boolean ra_corr_p;
boolean dec_fast_tracking;
uint8_t dec_step;
uint32_t dec_old;
uint32_t dec_new;
uint32_t dec_actual;
uint32_t dec_steps;
uint32_t dec_steps_total;
uint8_t dec_dir;
uint8_t dec_north;
uint8_t dec_south;
uint8_t dec_speed; // 0 - off, 1 - on
boolean dec_corr_m;
boolean dec_corr_p;
} radec_t;
/*=============================================================================
======= VARIABLES & MESSAGES & RESSOURCEN =======
=============================================================================*/
// non-volatile memory
static Preferences prefs;
// timers with timer critical section
static hw_timer_t *timer_normal = NULL;
static hw_timer_t *timer_fast = NULL;
static hw_timer_t *timer_corr[2] = {NULL};
static portMUX_TYPE timerMux = portMUX_INITIALIZER_UNLOCKED;
static uint64_t counter_normal;
static uint64_t counter_fast;
static uint64_t counter_corr[2];
// mutex for shared memory between tasks
static SemaphoreHandle_t sem_mutex;
// message queue between tasks
static QueueHandle_t msg_queue;
static char msg_buf[22];
// server stuff
static WebServer webserver(80);
static WiFiServer lx200server(4030);
// frequency measurement
static volatile uint8_t one_pps_sample_idx = 0;
static volatile uint64_t one_pps_samples[ONE_PPS_SAMPLES];
static uint64_t measured_frequency;
// current position, which is sent cyclic to the client
static char cur_pos_ra[9];
static char cur_pos_dec[10];
// parameterisation | Vixen MT-1 12V + GP | Bosch VMB 12V + EQ3
//---------------------------------------------------+----------------------+---------------------
static uint16_t mms; // motor max speed factor | 32 | 32
static uint16_t mst; // motor steps per full turn | 48 | 24
static uint32_t gdd; // gear box dividend | 1 | 384
static uint32_t gdr; // gear box divisor | 120 | 116375
static uint16_t wwr; // worm wheel ratio | 144 | 138
static uint32_t day_ms[8] = {SIDEREAL_DAY, SPEED_0_5X, LUNAR_DAY, SOLAR_DAY, SIDEREAL_DAY, SPEED_1_5X, SPEED_2X, SPEED_4X};
// math stuff
static volatile uint8_t hemisphere = 0; // 0 - northern hemisphere, 1 - southern hemisphere
static volatile radec_t radec;
static uint32_t ra_steps_360;
static uint32_t dec_steps_360;
static unsigned long time_now;
/*=============================================================================
======= PROTOTYPES OF PRIVATE METHODS =======
=============================================================================*/
static void web_server_task(void *parameter);
static void lx200_server_task(void *parameter);
static void process_commands_task(void *parameter);
static void current_pos_task(void *parameter);
static void httpHandleRoot(void);
static void parseCommand(char *req, char *resp);
static uint64_t calcAverageFrequency(void);
static void calcParameterisation(void);
static void calcRA2steps(void);
static void calcDEC2steps(void);
static void calcSteps2RA(uint32_t steps, uint32_t *ra);
static void calcSteps2DEC(uint32_t steps, uint32_t *dec);
static uint32_t stringToUnsigned(uint8_t *buf, uint8_t len);
static void stopSlewing(void);
static void gotoPosition(uint8_t *buf);
static void alignPosition(uint8_t *buf);
static void evalAutoguidePins(void);
/*=============================================================================
======= METHODS =======
=============================================================================*/
// 1.5x correction slewing (for RA+)
void IRAM_ATTR onTimerCorr0()
{
if ((radec.ra_corr_p == true) && (radec.ra_fast_tracking == false))
{
// RA motor off
REG_WRITE(GPIO_OUT_W1TC_REG, 0xful << RA_PHASE1_PIN);
if (radec.ra_speed > 0)
{
if (hemisphere == 0)
{
radec.ra_step ++;
}
else
{
radec.ra_step --;
}
REG_WRITE(GPIO_OUT_W1TS_REG, 1ul << ((radec.ra_step & 0x03) + RA_PHASE1_PIN));
}
// RA led on
digitalWrite(RA_LED_PIN, HIGH);
}
}
// 0.5x correction slewing (for RA-, Dec- and Dec+)
void IRAM_ATTR onTimerCorr1()
{
if ((radec.ra_corr_m == true) && (radec.ra_fast_tracking == false))
{
// RA motor off
REG_WRITE(GPIO_OUT_W1TC_REG, 0xful << RA_PHASE1_PIN);
if (radec.ra_speed > 0)
{
if (hemisphere == 0)
{
radec.ra_step ++;
}
else
{
radec.ra_step --;
}
REG_WRITE(GPIO_OUT_W1TS_REG, 1ul << ((radec.ra_step & 0x03) + RA_PHASE1_PIN));
}
// RA led on
digitalWrite(RA_LED_PIN, HIGH);
}
if ((radec.dec_corr_m == true) && (radec.dec_fast_tracking == false))
{
// DEC motor off
REG_WRITE(GPIO_OUT_W1TC_REG, 0xful << DEC_PHASE1_PIN);
if (radec.dec_speed > 0)
{
if (hemisphere == 0)
{
// slew down
radec.dec_step --;
}
else
{
// slew up
radec.dec_step ++;
}
REG_WRITE(GPIO_OUT_W1TS_REG, 1ul << ((radec.dec_step & 0x03) + DEC_PHASE1_PIN));
}
// DEC led on
digitalWrite(DEC_LED_PIN, HIGH);
}
if ((radec.dec_corr_p == true) && (radec.dec_fast_tracking == false))
{
// DEC motor off
REG_WRITE(GPIO_OUT_W1TC_REG, 0xful << DEC_PHASE1_PIN);
if (radec.dec_speed > 0)
{
if (hemisphere == 0)
{
// slew down
radec.dec_step ++;
}
else
{
// slew up
radec.dec_step --;
}
REG_WRITE(GPIO_OUT_W1TS_REG, 1ul << ((radec.dec_step & 0x03) + DEC_PHASE1_PIN));
}
// DEC led on
digitalWrite(DEC_LED_PIN, HIGH);
}
}
// normal slewing (only RA) interrupt service routine
void IRAM_ATTR onTimerNormal()
{
if ((radec.ra_corr_m == false) && (radec.ra_corr_p == false) && (radec.ra_fast_tracking == false))
{
// RA motor off
REG_WRITE(GPIO_OUT_W1TC_REG, 0xful << RA_PHASE1_PIN);
if (radec.ra_speed > 0)
{
if (hemisphere == 0)
{
radec.ra_step ++;
}
else
{
radec.ra_step --;
}
REG_WRITE(GPIO_OUT_W1TS_REG, 1ul << ((radec.ra_step & 0x03) + RA_PHASE1_PIN));
}
// RA led off
digitalWrite(RA_LED_PIN, LOW);
}
}
// fast slewing interrupt service routine
void IRAM_ATTR onTimerFast()
{
if (radec.ra_fast_tracking == true)
{
// RA motor off
REG_WRITE(GPIO_OUT_W1TC_REG, 0xful << RA_PHASE1_PIN);
if (radec.ra_east == 1)
{
if (hemisphere == 0)
{
// slew left
radec.ra_step --;
}
else
{
// slew right
radec.ra_step ++;
}
REG_WRITE(GPIO_OUT_W1TS_REG, 1ul << ((radec.ra_step & 0x03) + RA_PHASE1_PIN));
}
else if (radec.ra_west == 1)
{
if (hemisphere == 0)
{
// slew right
radec.ra_step ++;
}
else
{
// slew left
radec.ra_step --;
}
REG_WRITE(GPIO_OUT_W1TS_REG, 1ul << ((radec.ra_step & 0x03) + RA_PHASE1_PIN));
}
else if ((radec.ra_steps > 0ul) && (radec.ra_speed > 0))
{
if ((radec.ra_dir ^ hemisphere) == 0)
{
// slew left
radec.ra_step --;
}
else
{
// slew right
radec.ra_step ++;
}
REG_WRITE(GPIO_OUT_W1TS_REG, 1ul << ((radec.ra_step & 0x03) + RA_PHASE1_PIN));
radec.ra_steps --;
if (radec.ra_steps == 0ul)
{
radec.ra_actual = radec.ra_new;
radec.ra_old = radec.ra_new;
radec.ra_fast_tracking = false;
}
// RA led on
digitalWrite(RA_LED_PIN, HIGH);
}
else
{
// RA led off
digitalWrite(RA_LED_PIN, LOW);
}
}
if (radec.dec_fast_tracking == true)
{
// DEC motor off
REG_WRITE(GPIO_OUT_W1TC_REG, 0xful << DEC_PHASE1_PIN);
if (radec.dec_north == 1)
{
if (hemisphere == 0)
{
// slew up
radec.dec_step ++;
}
else
{
// slew down
radec.dec_step --;
}
REG_WRITE(GPIO_OUT_W1TS_REG, 1ul << ((radec.dec_step & 0x03) + DEC_PHASE1_PIN));
}
else if (radec.dec_south == 1)
{
if (hemisphere == 0)
{
// slew down
radec.dec_step --;
}
else
{
// slew up
radec.dec_step ++;
}
REG_WRITE(GPIO_OUT_W1TS_REG, 1ul << ((radec.dec_step & 0x03) + DEC_PHASE1_PIN));
}
else if ((radec.dec_steps > 0ul) && (radec.dec_speed > 0))
{
if ((radec.dec_dir ^ hemisphere) == 0)
{
// slew down
radec.dec_step --;
}
else
{
// slew up
radec.dec_step ++;
}
REG_WRITE(GPIO_OUT_W1TS_REG, 1ul << ((radec.dec_step & 0x03) + DEC_PHASE1_PIN));
radec.dec_steps --;
if (radec.dec_steps == 0ul)
{
radec.dec_actual = radec.dec_new;
radec.dec_old = radec.dec_new;
radec.dec_fast_tracking = false;
}
// DEC led on
digitalWrite(DEC_LED_PIN, HIGH);
}
else
{
// DEC led off
digitalWrite(DEC_LED_PIN, LOW);
}
}
else
{
// DEC led off
digitalWrite(DEC_LED_PIN, LOW);
}
}
// 1PPS interupt service routine
void IRAM_ATTR handleOnePPSinterrupt()
{
// with each second take a counter sample
if (one_pps_sample_idx < ONE_PPS_SAMPLES)
{
one_pps_samples[one_pps_sample_idx ++] = timerRead(timer_normal);
}
}
static uint64_t calcAverageFrequency(void)
{
uint64_t average = 0ull;
// start free running 64 bit counter with max. frequency (= 40MHz)
timer_normal = timerBegin(0, 2, true);
// configure Pin as Interrupt pin, falling edge, internal pull-up
pinMode(ONE_PPS_PIN, INPUT_PULLUP);
attachInterrupt(digitalPinToInterrupt(ONE_PPS_PIN), handleOnePPSinterrupt, FALLING);
// wait until all counter samples were taken
while (one_pps_sample_idx < ONE_PPS_SAMPLES);
// sampling done, detach from interrupt and stop the counter
detachInterrupt(digitalPinToInterrupt(ONE_PPS_PIN));
timerEnd(timer_normal);
// calculate the average counter frequency
for (one_pps_sample_idx = 1; one_pps_sample_idx < (ONE_PPS_SAMPLES - 1); one_pps_sample_idx ++)
{
average += (one_pps_samples[one_pps_sample_idx + 1] - one_pps_samples[one_pps_sample_idx]);
}
// rounding
average += ((ONE_PPS_SAMPLES - 2) / 2);
// average
average /= (ONE_PPS_SAMPLES - 2);
return average;
}
static void parseCommand(char *req, char *resp)
{
static char tgt_pos_ra[9];
static char tgt_pos_dec[10];
if ((NULL != req) && (NULL != resp))
{
// :GR# Get telescope right ascension (RA).
if (0 == strcmp (":GR#", req))
{
xSemaphoreTake( sem_mutex, portMAX_DELAY );
sprintf (resp, "%s#", cur_pos_ra);
xSemaphoreGive( sem_mutex );
}
// :GD# Get telescope declination (DEC).
if (0 == strcmp (":GD#", req))
{
xSemaphoreTake( sem_mutex, portMAX_DELAY );
sprintf (resp, "%s#", cur_pos_dec);
xSemaphoreGive( sem_mutex );
}
// :SrHH:MM:SS# Set target object right ascension (RA).
if (0 == strncmp (":Sr", req, 3))
{
memcpy (tgt_pos_ra, &req[3], 8);
tgt_pos_ra[8] = 0;
strcpy (resp, "1");
}
// :SdsDD*MM:SS# Set target object declination (DEC).
if (0 == strncmp (":Sd", req, 3))
{
memcpy (tgt_pos_dec, &req[3], 9);
tgt_pos_dec[9] = 0;
strcpy (resp, "1");
}
// :CM# Synchronizes the telescope's position with the currently selected database object's coordinates.
if (0 == strcmp (":CM#", req))
{
sprintf(msg_buf, ":CM%s%s#", tgt_pos_ra, tgt_pos_dec);
xQueueSend( msg_queue, msg_buf, portMAX_DELAY );
strcpy (resp, "#");
}
// :MS# Slew to target object
if (0 == strcmp (":MS#", req))
{
sprintf(msg_buf, ":MS%s%s#", tgt_pos_ra, tgt_pos_dec);
xQueueSend( msg_queue, msg_buf, portMAX_DELAY );
strcpy (resp, "0");
}
// :StsDD*MM# Set the current site latitude.
if (0 == strncmp (":St", req, 3))
{
strcpy(msg_buf, req);
xQueueSend( msg_queue, msg_buf, portMAX_DELAY );
strcpy (resp, "1");
}
// :SgDDD*MM# Set current site’s longitude.
if (0 == strncmp (":Sg", req, 3))
{
strcpy (resp, "1");
}
// :SGsHH.H# Set the number of hours added to local time to yield UTC.
if (0 == strncmp (":SG", req, 3))
{
strcpy (resp, "1");
}
// :SLHH:MM:SS# Set the local time.
if (0 == strncmp (":SL", req, 3))
{
strcpy (resp, "1");
}
// :SCMM/DD/YY# Change handbox date.
if (0 == strncmp (":SC", req ,3))
{
strcpy (resp, "1Updating Planetary Data # #");
}
// :Q# Halt all current slewing.
if (0 == strcmp (":Q#", req))
{
strcpy(msg_buf, ":Q#");
xQueueSend( msg_queue, msg_buf, portMAX_DELAY );
//Serial.println("Stop slewing");
resp[0] = 0;
}
// :Me# Move telescope east at current slew rate.
if (0 == strcmp (":Me#", req))
{
strcpy(msg_buf, ":Me#");
xQueueSend( msg_queue, msg_buf, portMAX_DELAY );
resp[0] = 0;
}
// :Mn# Move telescope north at current slew rate.
if (0 == strcmp (":Mn#", req))
{
strcpy(msg_buf, ":Mn#");
xQueueSend( msg_queue, msg_buf, portMAX_DELAY );
resp[0] = 0;
}
// :Ms# Move telescope south at current slew rate.
if (0 == strcmp (":Ms#", req))
{
strcpy(msg_buf, ":Ms#");
xQueueSend( msg_queue, msg_buf, portMAX_DELAY );
resp[0] = 0;
}
// :Mw# Move telescope west at current slew rate.
if (0 == strcmp (":Mw#", req))
{
strcpy(msg_buf, ":Mw#");
xQueueSend( msg_queue, msg_buf, portMAX_DELAY );
resp[0] = 0;
}
// :Qe# Halt eastward slews.
if (0 == strcmp (":Qe#", req))
{
strcpy(msg_buf, ":Qe#");
xQueueSend( msg_queue, msg_buf, portMAX_DELAY );
resp[0] = 0;
}
// :Qn# Halt northward slews.
if (0 == strcmp (":Qn#", req))
{
strcpy(msg_buf, ":Qn#");
xQueueSend( msg_queue, msg_buf, portMAX_DELAY );
resp[0] = 0;
}
// :Qs# Halt southward slews.
if (0 == strcmp (":Qs#", req))
{
strcpy(msg_buf, ":Qs#");
xQueueSend( msg_queue, msg_buf, portMAX_DELAY );
resp[0] = 0;
}
// :Qw# Halt westward slews.
if (0 == strcmp (":Qw#", req))
{
strcpy(msg_buf, ":Qw#");
xQueueSend( msg_queue, msg_buf, portMAX_DELAY );
resp[0] = 0;
}
// :RC# Set slew rate to centering rate (2nd slowest).
if (0 == strcmp (":RC#", req))
{
resp[0] = 0;
}
// :RG# Set slew rate to guiding rate (slowest).
if (0 == strcmp (":RG#", req))
{
resp[0] = 0;
}
// :RM# Set slew rate to find rate (2nd fastest).
if (0 == strcmp (":RM#", req))
{
resp[0] = 0;
}
// :RS# Set slew rate to max (fastest).
if (0 == strcmp (":RS#", req))
{
resp[0] = 0;
}
}
}
static void lx200_server_task(void *parameter)
{
static char request[50];
static char response[200];
static WiFiClient client[MAX_CLIENTS];
int i;
lx200server.begin();
for(;;)
{
delay(25);
// Sky Safari does not make a persistent connection, so each command query is managed as a single independent client
if (lx200server.hasClient())
{
for (i = 0; i < MAX_CLIENTS; i++)
{
// client is trying to connect, find free/disconnected spot
if (!client[i] || !client[i].connected())
{
if (client[i])
{
// disconnect client
client[i].stop();
}
client[i] = lx200server.available();
}
}
}
// check clients for data
for (i = 0; i < MAX_CLIENTS; i++)
{
if (client[i] && client[i].connected())
{
// get data from the client
while (client[i].available())
{
int n = client[i].available();
client[i].readBytes(request, n);
request[n] = 0;
parseCommand(request, response);
if (0 < strlen(response))
{
client[i].write(response, strlen(response));
}
}
}
}
}
}
static void calcRA2steps(void)
{
uint32_t steps1, steps2, steps_total1, steps_total2;
uint8_t dir1, dir2;
xSemaphoreTake( sem_mutex, portMAX_DELAY );
if (radec.ra_new >= radec.ra_old)
{
// northern hemisphere: left, southern hemisphere: right
steps1 = (((uint64_t)(radec.ra_new - radec.ra_old)) * ra_steps_360) / RA_SECONDS_360;
steps_total1 = steps1 - (steps1 * counter_fast) / (counter_normal + counter_fast);
dir1 = 0;
// northern hemisphere: right, southern hemisphere: left
steps2 = ra_steps_360 - steps1;
steps_total2 = steps2 + (steps2 * counter_fast) / (counter_normal - counter_fast);
dir2 = 1;
}
else
{
// northern hemisphere: right, southern hemisphere: left
steps1 = (((uint64_t)(radec.ra_old - radec.ra_new)) * ra_steps_360) / RA_SECONDS_360;
steps_total1 = steps1 + (steps1 * counter_fast) / (counter_normal - counter_fast);
dir1 = 1;
// northern hemisphere: left, southern hemisphere: right
steps2 = ra_steps_360 - steps1;
steps_total2 = steps2 - (steps2 * counter_fast) / (counter_normal + counter_fast);
dir2 = 0;
}
xSemaphoreGive( sem_mutex );
portENTER_CRITICAL(&timerMux);
if (steps_total1 < steps_total2)
{
radec.ra_steps = steps_total1;
radec.ra_dir = dir1;
}
else
{
radec.ra_steps = steps_total2;
radec.ra_dir = dir2;
}
radec.ra_steps_total = radec.ra_steps;
if (radec.ra_steps > 0)
{
radec.ra_fast_tracking = true;
}
portEXIT_CRITICAL(&timerMux);
}
static void calcSteps2RA(uint32_t steps, uint32_t *ra)
{
if (radec.ra_new >= radec.ra_old)
{
if (radec.ra_dir == 0)
{
*ra = radec.ra_old + (uint32_t)(((uint64_t)(radec.ra_steps_total - steps) * ((uint64_t)(radec.ra_new - radec.ra_old))) / ((uint64_t)radec.ra_steps_total));
}
else
{
*ra = (RA_SECONDS_360 + radec.ra_old - (uint32_t)(((uint64_t)(radec.ra_steps_total - steps) * ((uint64_t)(RA_SECONDS_360 - radec.ra_new + radec.ra_old))) / ((uint64_t)radec.ra_steps_total))) % RA_SECONDS_360;
}
}
else
{
if (radec.ra_dir == 0)
{
*ra = (RA_SECONDS_360 + radec.ra_old + (uint32_t)(((uint64_t)(radec.ra_steps_total - steps) * ((uint64_t)(RA_SECONDS_360 - radec.ra_old + radec.ra_new))) / ((uint64_t)radec.ra_steps_total))) % RA_SECONDS_360;
}
else
{
*ra = radec.ra_old - (uint32_t)(((uint64_t)(radec.ra_steps_total - steps) * ((uint64_t)(radec.ra_old - radec.ra_new))) / ((uint64_t)radec.ra_steps_total));
}
}
}
static void calcDEC2steps(void)
{
uint32_t steps_total;
uint8_t dir;
xSemaphoreTake( sem_mutex, portMAX_DELAY );
if (radec.dec_new >= radec.dec_old)
{
if ((radec.dec_new >= DEC_SECONDS_270) && (radec.dec_old <= DEC_SECONDS_90))
{
// down
steps_total = (((uint64_t)(DEC_SECONDS_360 - (radec.dec_new - radec.dec_old))) * dec_steps_360) / DEC_SECONDS_360;
dir = 0;
}
else
{
// up
steps_total = (((uint64_t)(radec.dec_new - radec.dec_old)) * dec_steps_360) / DEC_SECONDS_360;
dir = 1;
}
}
else
{
if ((radec.dec_new <= DEC_SECONDS_90) && (radec.dec_old >= DEC_SECONDS_270))
{
// up
steps_total = (((uint64_t)(DEC_SECONDS_360 - (radec.dec_old - radec.dec_new))) * dec_steps_360) / DEC_SECONDS_360;
dir = 1;
}
else
{
// down
steps_total = (((uint64_t)(radec.dec_old - radec.dec_new)) * dec_steps_360) / DEC_SECONDS_360;
dir = 0;
}
}
xSemaphoreGive( sem_mutex );
portENTER_CRITICAL(&timerMux);
radec.dec_steps = steps_total;
radec.dec_dir = dir;
radec.dec_steps_total = radec.dec_steps;
if (radec.dec_steps > 0)
{
radec.dec_fast_tracking = true;
}
portEXIT_CRITICAL(&timerMux);
}
static void calcSteps2DEC(uint32_t steps, uint32_t *dec)
{
if (radec.dec_new >= radec.dec_old)
{
if (radec.dec_dir == 0)
{
*dec = (DEC_SECONDS_360 + radec.dec_old - (uint32_t)(((uint64_t)(radec.dec_steps_total - steps) * ((uint64_t)(DEC_SECONDS_360 - radec.dec_new + radec.dec_old))) / ((uint64_t)radec.dec_steps_total))) % DEC_SECONDS_360;
}
else
{
*dec = radec.dec_old + (uint32_t)(((uint64_t)(radec.dec_steps_total - steps) * ((uint64_t)(radec.dec_new - radec.dec_old))) / ((uint64_t)radec.dec_steps_total));
}
}
else
{
if (radec.dec_dir == 0)
{
*dec = radec.dec_old - (uint32_t)(((uint64_t)(radec.dec_steps_total - steps) * ((uint64_t)(radec.dec_old - radec.dec_new))) / ((uint64_t)radec.dec_steps_total));
}
else
{
*dec = (DEC_SECONDS_360 + radec.dec_old + (uint32_t)(((uint64_t)(radec.dec_steps_total - steps) * ((uint64_t)(DEC_SECONDS_360 - radec.dec_old + radec.dec_new))) / ((uint64_t)radec.dec_steps_total))) % DEC_SECONDS_360;
}
}
}
static uint32_t stringToUnsigned(uint8_t *buf, uint8_t len)
{
uint32_t nbr = 0ul;
uint32_t f = 1ul;
uint8_t i;
for (i = 0; i < len; i ++)
{
nbr = nbr + f * (buf[len - i - 1] - '0');
f = f * 10ul;
}
return nbr;
}
static void stopSlewing(void)
{
uint32_t steps1, steps2, ra, dec;
portENTER_CRITICAL(&timerMux);
steps1 = radec.ra_steps;
steps2 = radec.dec_steps;
radec.ra_steps = 0;
radec.dec_steps = 0;
radec.ra_fast_tracking = false;
radec.dec_fast_tracking = false;
portEXIT_CRITICAL(&timerMux);
if ((steps1 > 0ul) && (radec.ra_steps_total > 0ul))
{
calcSteps2RA(steps1, &ra);
radec.ra_actual = ra;
}
if ((steps2 > 0ul) && (radec.dec_steps_total > 0ul))
{
calcSteps2DEC(steps2, &dec);
radec.dec_actual = dec;
}
radec.ra_old = radec.ra_actual;
radec.dec_old = radec.dec_actual;
}
static void gotoPosition(uint8_t *buf)
{
uint32_t raHr = (uint32_t)stringToUnsigned (buf + 3, 2);
uint32_t raMin = (uint32_t)stringToUnsigned (buf + 6, 2);
uint32_t raSec = (uint32_t)stringToUnsigned (buf + 9, 2);
uint32_t decDeg = (uint32_t)stringToUnsigned (buf + 12, 2);
uint32_t decMin = (uint32_t)stringToUnsigned (buf + 15, 2);
uint32_t decSec = (uint32_t)stringToUnsigned (buf + 18, 2);
radec.ra_new = raSec + 60ul * raMin + 3600ul * raHr; // 0 .. 86399
radec.dec_new = decSec + 60ul * decMin + 3600ul * decDeg; // 0 .. 323999
if (buf[11] == '-')
{
radec.dec_new = DEC_SECONDS_360 - radec.dec_new;
}
radec.ra_old = radec.ra_actual;
radec.dec_old = radec.dec_actual;
calcRA2steps();
calcDEC2steps();
}
static void alignPosition(uint8_t *buf)
{
uint32_t raHr = (uint32_t)stringToUnsigned (buf + 3, 2);
uint32_t raMin = (uint32_t)stringToUnsigned (buf + 6, 2);
uint32_t raSec = (uint32_t)stringToUnsigned (buf + 9, 2);
uint32_t decDeg = (uint32_t)stringToUnsigned (buf + 12, 2);
uint32_t decMin = (uint32_t)stringToUnsigned (buf + 15, 2);
uint32_t decSec = (uint32_t)stringToUnsigned (buf + 18, 2);
radec.ra_new = raSec + 60ul * raMin + 3600ul * raHr; // 0 .. 86399
radec.dec_new= decSec + 60ul * decMin + 3600ul * decDeg; // 0 .. 323999
if (buf[11] == '-')
{
radec.dec_new = DEC_SECONDS_360 - radec.dec_new;
}
radec.ra_actual = radec.ra_new;
radec.ra_old = radec.ra_new;
radec.dec_actual = radec.dec_new;
radec.dec_old = radec.dec_new;
// send immediately the actual position
xSemaphoreTake( sem_mutex, portMAX_DELAY );
memcpy (cur_pos_ra, &buf[3], 8);
cur_pos_ra[8] = 0;
xSemaphoreGive( sem_mutex );
xSemaphoreTake( sem_mutex, portMAX_DELAY );
memcpy (cur_pos_dec, &buf[11], 9);
cur_pos_dec[9] = 0;
xSemaphoreGive( sem_mutex );
}
static void process_commands_task(void *parameter)
{
uint8_t buf[22];
for(;;)
{
xQueueReceive( msg_queue, buf, portMAX_DELAY );
Serial.printf("> %s\n", buf);
if (0 == strncmp (":St", (char*)buf, 3))
{
portENTER_CRITICAL(&timerMux);
if (buf[3] == '-')
{
hemisphere = 1; // southern hemisphere
}
else
{
hemisphere = 0; // northern hemisphere
}
portEXIT_CRITICAL(&timerMux);
}
if (0 == strncmp (":CM", (char*)buf, 3))
{
alignPosition(buf);
}
if (0 == strncmp (":MS", (char*)buf, 3))
{
gotoPosition(buf);
}
if (0 == strncmp (":Q#", (char*)buf, 3))
{
stopSlewing();
}
if (0 == strncmp (":Me#", (char*)buf,4))
{
portENTER_CRITICAL(&timerMux);
radec.ra_east = 1;
radec.ra_fast_tracking = true;
portEXIT_CRITICAL(&timerMux);
}
if (0 == strncmp (":Mn#", (char*)buf,4))
{
portENTER_CRITICAL(&timerMux);
radec.dec_north = 1;
radec.dec_fast_tracking = true;
portEXIT_CRITICAL(&timerMux);
}
if (0 == strncmp (":Ms#", (char*)buf,4))
{
portENTER_CRITICAL(&timerMux);
radec.dec_south = 1;
radec.dec_fast_tracking = true;
portEXIT_CRITICAL(&timerMux);
}
if (0 == strncmp (":Mw#", (char*)buf,4))
{
portENTER_CRITICAL(&timerMux);
radec.ra_west = 1;
radec.ra_fast_tracking = true;
portEXIT_CRITICAL(&timerMux);
}
if (0 == strncmp (":Qe#", (char*)buf,4))
{
portENTER_CRITICAL(&timerMux);
radec.ra_east = 0;
radec.ra_fast_tracking = false;
portEXIT_CRITICAL(&timerMux);
}
if (0 == strncmp (":Qn#", (char*)buf,4))
{
portENTER_CRITICAL(&timerMux);
radec.dec_north = 0;