CMake: mimic folder hierarchy with source_group for MSVC

git-svn-id: svn+ssh://svn.code.sf.net/p/supertuxkart/code/main/trunk@10973 178a84e3-b1eb-0310-8ba1-8eac791a3b58

Author: undef-in-ed

CMakeLists.txt

@@ -103,9 +103,14 @@ else()
 endif()
 
 
-# Provides list of source files in STK_SOURCES
+# Provides list of source and header files (STK_SOURCES and STK_HEADERS)
 include(sources.cmake)
 
+# Generate source groups useful for MSVC project explorer
+include(cmake/SourceGroupFunctions.cmake)
+source_group_hierarchy(STK_SOURCES STK_HEADERS)
+
+
 if(APPLE)
     # icon files to copy in the bundle
     set(OSX_ICON_FILES ${PROJECT_SOURCE_DIR}/src/ide/Xcode/stk.icns)
@@ -138,7 +143,7 @@ else()
     add_definitions(-DSUPERTUXKART_DATADIR=\"${CMAKE_INSTALL_PREFIX}/share/games/supertuxkart\")
 
     # Build the final executable
-    add_executable(supertuxkart ${STK_SOURCES})
+    add_executable(supertuxkart ${STK_SOURCES} ${STK_HEADERS})
 	if(CYGWIN)
 	    target_link_libraries(supertuxkart pthread)
     elseif(UNIX)

cmake/SourceGroupFunctions.cmake

@@ -0,0 +1,27 @@
+# Generate source groups which mimic the original folder hierarchy.
+# This is mainly useful for MSVC's project explorer
+# - SRCS list of source files
+# - HDRS list of header files
+function(source_group_hierarchy SRCS HDRS)
+    foreach(source_file ${${SRCS}})
+        source_group_file(${source_file} "Source Files\\")
+    endforeach()
+
+    foreach(header_file ${${HDRS}})
+        source_group_file(${header_file} "Header Files\\")
+    endforeach()
+endfunction()
+
+# Determine source_group depending on file path
+# - FILE path to a file (header or source)
+# - GROUP_PREFIX prefix for group name
+function(source_group_file file group_prefix)
+    get_filename_component(file_path ${file} PATH)
+    if(${file_path} STREQUAL "src")
+        source_group("${group_prefix}" FILES ${file})
+    else()
+        string(REGEX REPLACE "^src/(.*)$" "\\1" group_name ${file_path})
+        string(REPLACE "/" "\\\\" group_name ${group_name})
+        source_group("${group_prefix}${group_name}" FILES ${file})
+    endif()
+endfunction()