build.gradle

allprojects {
    apply plugin: "eclipse"
    apply plugin: "idea"

    repositories {
        mavenCentral()
        maven { url "https://oss.sonatype.org/content/repositories/releases/" }
    }
}

tasks.eclipse.doLast {
    delete ".project"
}

// DISABLES JAVADOC ULTRACHECKS IN JDK8
 if (JavaVersion.current().isJava8Compatible()) {
    allprojects {
      tasks.withType(Javadoc) {
        options.addStringOption('Xdoclint:none', '-quiet')
      }
    }
}

// UPLOADARCHIVES properties management
def ask(title){
	def console = System.console()
	def string
	
    if (console) {
        string = console.readLine(title)
    } else {
        logger.error "Cannot get console."
    }
    
    return new String(string)
}

def askPasswd(title){
	def console = System.console()
	def string
	
    if (console) {
        string = console.readPassword(title)
    } else {
        logger.error "Cannot get console."
    }
    
    return new String(string)
}

// Set build variables based on build type (release, continuous integration, development)
if(hasProperty("release")) {
    ext.sonatypeRepositoryUrl = "https://oss.sonatype.org/service/local/staging/deploy/maven2/"
	if(!hasProperty("sonatypeUsername"))
		ext.sonatypeUsername = ask('\nSonatype Username: ')
	
	if(!hasProperty("sonatypePassword"))
		ext.sonatypePassword = askPasswd('\nSonatype Password: ')
		
	if(!hasProperty("signing.keyId"))
    	ext."signing.keyId" = ask('\nKey Id: ')
    	
   	if(!hasProperty("signing.secretKeyRingFile"))
    	ext."signing.secretKeyRingFile" = ask('\nSecret Keyring file: ')
    	
    if(!hasProperty("signing.password"))
    	ext."signing.password" = askPasswd('\nKey Password: ')
} else if (hasProperty("ci")) {
    if(!version.endsWith("-SNAPSHOT"))
    	version += "-SNAPSHOT"
    
    ext.sonatypeRepositoryUrl = "https://oss.sonatype.org/content/repositories/snapshots/"
	if(!hasProperty("sonatypeUsername"))
		ext.sonatypeUsername = ask('\nSonatype Username: ')
	
	if(!hasProperty("sonatypePassword"))
		ext.sonatypePassword = askPasswd('\nSonatype Password: ')
}