Start commons new send command

Author: addshore

examples/modules/comms/new-send.toit

@@ -0,0 +1,45 @@
+import lightbug.devices as devices
+import lightbug.services as services
+import lightbug.messages as messages
+import log
+
+// A simple application that sets up a Lightbug device and starts sending messages
+// Demonstrates both synchronous and asynchronous message sending.
+main:
+  log.set-default (log.default.with-level log.INFO-LEVEL)
+
+  // RtkHandheld2 is a Lightbug device that uses I2C, and is pre-configured
+  // Do not send an open or heartbeat messages
+  device := devices.RtkHandheld2 --open=false
+
+  while true:
+    /**
+    Send an asynchronous message to open the device.
+    The call to send is non-blocking, and the callback will be called when the response is received within the --timeout
+    */
+    log.info "Calling send-new (async)..."
+    latch := device.comms.send-new messages.Open.msg --async --callback=:: |result|
+      if result and result.msg-ok:
+        log.info "Device opened successfully (async): $result"
+      else if result:
+        log.error "Failed to open device (async): $result.msg-status"
+      else:
+          log.error "Failed to open device (async), no response received"
+    log.info "Called send-new (async), waiting for response..."
+
+    // We don't have to wait for this, but we will do it anyway, so we don't conflict with the sync example below
+    latch.get
+
+    /**
+    Send a synchronous message to open the device.
+    This will block until the response is received or the --timeout is reached.
+    */
+    log.info "Calling send-new (sync)..."
+    result := device.comms.send-new messages.Open.msg
+    if result and result.msg-ok:
+      log.info "Device opened successfully (sync): $result"
+    else if result:
+      log.error "Failed to open device (sync): $result.msg-status"
+    else:
+        log.error "Failed to open device (sync), no response received"
+    log.info "Called send-new (sync)..."

src/modules/comms/comms.toit

@@ -240,6 +240,7 @@ class Comms:
       sendSwitching_ outbox_.receive --now=true
       yield // on each message sent
 
+
   // Send a message, and possibly do advanced things before after and during sending
   send msg/protocol.Message
       --now/bool = false // Should it be send now, of via the outbox
@@ -297,6 +298,46 @@ class Comms:
       return latch
     return null
 
+  send-new msg/protocol.Message
+      --flush/bool = false
+      --timeout/Duration = (Duration --s=60) -> protocol.Message?:
+    // Ensure the message has a known message id
+    if not (msg.header.data.has-data protocol.Header.TYPE-MESSAGE-ID):
+      msg.header.data.add-data-uint32 protocol.Header.TYPE-MESSAGE-ID msgIdGenerator.next
+
+    logger_.with-level log.DEBUG-LEVEL:
+      logger_.debug "SEND: $(msg)"
+
+    latch := monitor.Latch
+    latchForMessage[msg.msgId] = latch
+    waitTimeouts[msg.msgId] = Time.now + timeout
+
+    sendSwitching_ msg --now=flush
+
+    return latch.get
+
+  send-new msg/protocol.Message --async 
+      --callback/Lambda? = null
+      --flush/bool = false
+      --timeout/Duration = (Duration --s=60) -> monitor.Latch?:
+    // Ensure the message has a known message id
+    if not (msg.header.data.has-data protocol.Header.TYPE-MESSAGE-ID):
+      msg.header.data.add-data-uint32 protocol.Header.TYPE-MESSAGE-ID msgIdGenerator.next
+
+    logger_.with-level log.DEBUG-LEVEL:
+      logger_.debug "SEND: $(msg)"
+
+    latch := monitor.Latch
+    latchForMessage[msg.msgId] = latch
+    waitTimeouts[msg.msgId] = Time.now + timeout
+
+    sendSwitching_ msg --now=flush
+
+    if callback:
+      task::
+        callback.call latch.get
+    return latch
+
   // Send directly, or via the outbox
   sendSwitching_ msg/protocol.Message --now/bool?=false:
     // TODO don't call this on both the outbox and regular paths, as it is messy
@@ -358,7 +399,7 @@ class Comms:
 
           // Remove the timeout key, complete the latch, and remove all callbacks
           waitTimeouts.remove key
-          latchForMessage[key].set false // false currently means timeout?
+          latchForMessage[key].set null // null, indicating there was no message received before the timeout
           latchForMessage.remove key
           lambdasForBadAck.remove key
           lambdasForGoodAck.remove key

src/protocol/message.toit

@@ -62,6 +62,9 @@ class Message:
   if header.data.has-data Header.TYPE_MESSAGE_STATUS: return header.data.get-data-intn Header.TYPE_MESSAGE_STATUS
   return null
 
+ msg-ok -> bool:
+  return header.data.has-data Header.TYPE_MESSAGE_STATUS and (header.data.get-data-intn Header.TYPE_MESSAGE_STATUS) <= Header.STATUS_OK
+
  msg-status-id status/int -> bool:
   return header.data.has-data Header.TYPE_MESSAGE_STATUS and (header.data.get-data-intn Header.TYPE_MESSAGE_STATUS) == status