-
Notifications
You must be signed in to change notification settings - Fork 5
/
p_floor.pas
559 lines (518 loc) · 16.5 KB
/
p_floor.pas
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
//------------------------------------------------------------------------------
//
// FPCDoom - Port of Doom to Free Pascal Compiler
// Copyright (C) 1993-1996 by id Software, Inc.
// Copyright (C) 2004-2007 by Jim Valavanis
// Copyright (C) 2017-2022 by Jim Valavanis
//
// This program is free software; you can redistribute it and/or
// modify it under the terms of the GNU General Public License
// as published by the Free Software Foundation; either version 2
// of the License, or (at your option) any later version.
//
// This program is distributed in the hope that it will be useful,
// but WITHOUT ANY WARRANTY; without even the implied warranty of
// MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
// GNU General Public License for more details.
//
// You should have received a copy of the GNU General Public License
// along with this program; if not, write to the Free Software
// Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA
// 02111-1307, USA.
//
//------------------------------------------------------------------------------
// E-Mail: [email protected]
// Site : https://sourceforge.net/projects/fpcdoom/
//------------------------------------------------------------------------------
{$I FPCDoom.inc}
unit p_floor;
interface
uses
z_memory,
p_spec,
m_fixed,
r_defs,
s_sound,
sounds;
//==============================================================================
// T_MovePlane
//
// FLOORS
//
//==============================================================================
function T_MovePlane(sector: Psector_t; speed: fixed_t; dest: fixed_t;
crush: boolean; floorOrCeiling: integer; direction: integer): result_e;
//==============================================================================
//
// T_MoveFloor
//
//==============================================================================
procedure T_MoveFloor(floor: Pfloormove_t);
//==============================================================================
//
// EV_DoFloor
//
//==============================================================================
function EV_DoFloor(line: Pline_t; floortype: floor_e): integer;
//==============================================================================
//
// EV_BuildStairs
//
//==============================================================================
function EV_BuildStairs(line: Pline_t; _type: stair_e): integer;
implementation
uses
d_fpc,
doomdata,
p_map,
p_tick,
p_mobj_h,
p_setup,
r_data;
//==============================================================================
// T_MovePlane
//
// Move a plane (floor or ceiling) and check for crushing
//
//==============================================================================
function T_MovePlane(sector: Psector_t; speed: fixed_t; dest: fixed_t;
crush: boolean; floorOrCeiling: integer; direction: integer): result_e;
var
lastpos: fixed_t;
begin
case floorOrCeiling of
0:
begin
// FLOOR
if direction = -1 then
begin
// DOWN
if sector.floorheight - speed < dest then
begin
lastpos := sector.floorheight;
sector.floorheight := dest;
if P_ChangeSector(sector, crush) then
begin
sector.floorheight := lastpos;
P_ChangeSector(sector, crush);
end;
result := pastdest;
exit;
end
else
begin
lastpos := sector.floorheight;
sector.floorheight := sector.floorheight - speed;
if P_ChangeSector(sector, crush) then
begin
sector.floorheight := lastpos;
P_ChangeSector(sector, crush);
result := crushed;
exit;
end;
end;
end
else if direction = 1 then
begin
// UP
if sector.floorheight + speed > dest then
begin
lastpos := sector.floorheight;
sector.floorheight := dest;
if P_ChangeSector(sector, crush) then
begin
sector.floorheight := lastpos;
P_ChangeSector(sector, crush);
end;
result := pastdest;
exit;
end
else
begin
// COULD GET CRUSHED
lastpos := sector.floorheight;
sector.floorheight := sector.floorheight + speed;
if P_ChangeSector(sector, crush) then
begin
if crush then
begin
result := crushed;
exit;
end;
sector.floorheight := lastpos;
P_ChangeSector(sector, crush);
result := crushed;
exit;
end
end;
end;
end;
1:
begin
// CEILING
if direction = -1 then
begin
// DOWN
if sector.ceilingheight - speed < dest then
begin
lastpos := sector.ceilingheight;
sector.ceilingheight := dest;
if P_ChangeSector(sector, crush) then
begin
sector.ceilingheight := lastpos;
P_ChangeSector(sector, crush);
end;
result := pastdest;
exit;
end
else
begin
// COULD GET CRUSHED
lastpos := sector.ceilingheight;
sector.ceilingheight := sector.ceilingheight - speed;
if P_ChangeSector(sector, crush) then
begin
if crush then
begin
result := crushed;
exit;
end;
sector.ceilingheight := lastpos;
P_ChangeSector(sector, crush);
result := crushed;
exit;
end;
end;
end
else if direction = 1 then
begin
// UP
if sector.ceilingheight + speed > dest then
begin
lastpos := sector.ceilingheight;
sector.ceilingheight := dest;
if P_ChangeSector(sector, crush) then
begin
sector.ceilingheight := lastpos;
P_ChangeSector(sector, crush);
end;
result := pastdest;
exit;
end
else
begin
sector.ceilingheight := sector.ceilingheight + speed;
P_ChangeSector(sector, crush);
end;
end;
end;
end;
result := ok;
end;
//==============================================================================
// T_MoveFloor
//
// MOVE A FLOOR TO IT'S DESTINATION (UP OR DOWN)
//
//==============================================================================
procedure T_MoveFloor(floor: Pfloormove_t);
var
res: result_e;
begin
res := T_MovePlane(floor.sector, floor.speed, floor.floordestheight,
floor.crush, 0, floor.direction);
if leveltime and 7 = 0 then
S_StartSound(Pmobj_t(@floor.sector.soundorg), Ord(sfx_stnmov));
if res = pastdest then
begin
floor.sector.specialdata := nil;
if floor.direction = 1 then
begin
if floor._type = donutRaise then
begin
floor.sector.special := floor.newspecial;
floor.sector.floorpic := floor.texture;
end;
end
else if floor.direction = -1 then
begin
if floor._type = lowerAndChange then
begin
floor.sector.special := floor.newspecial;
floor.sector.floorpic := floor.texture;
end;
end;
P_RemoveThinker(@floor.thinker);
S_StartSound(Pmobj_t(@floor.sector.soundorg), Ord(sfx_pstop));
end;
end;
//==============================================================================
// EV_DoFloor
//
// HANDLE FLOOR TYPES
//
//==============================================================================
function EV_DoFloor(line: Pline_t; floortype: floor_e): integer;
var
secnum: integer;
i: integer;
sec: Psector_t;
floor: Pfloormove_t;
minsize: integer;
side: Pside_t;
begin
secnum := -1;
result := 0;
repeat
secnum := P_FindSectorFromLineTag(line, secnum);
if secnum < 0 then
exit;
sec := @sectors[secnum];
// ALREADY MOVING? IF SO, KEEP GOING...
if sec.specialdata <> nil then
continue;
// new floor thinker
result := 1;
floor := Z_Malloc(SizeOf(floormove_t), PU_LEVSPEC, nil);
ZeroMemory(floor, SizeOf(floormove_t));
P_AddThinker(@floor.thinker);
sec.specialdata := floor;
floor.thinker._function.acp1 := @T_MoveFloor;
floor._type := floortype;
floor.crush := false;
case floortype of
lowerFloor:
begin
floor.direction := -1;
floor.sector := sec;
floor.speed := FLOORSPEED;
floor.floordestheight := P_FindHighestFloorSurrounding(sec);
end;
lowerFloorToLowest:
begin
floor.direction := -1;
floor.sector := sec;
floor.speed := FLOORSPEED;
floor.floordestheight := P_FindLowestFloorSurrounding(sec);
end;
turboLower:
begin
floor.direction := -1;
floor.sector := sec;
floor.speed := FLOORSPEED * 4;
floor.floordestheight :=
P_FindHighestFloorSurrounding(sec);
if floor.floordestheight <> sec.floorheight then
floor.floordestheight := floor.floordestheight + 8 * FRACUNIT;
end;
raiseFloorCrush,
raiseFloor:
begin
if floortype = raiseFloorCrush then
floor.crush := true;
floor.direction := 1;
floor.sector := sec;
floor.speed := FLOORSPEED;
floor.floordestheight := P_FindLowestCeilingSurrounding(sec);
if floor.floordestheight > sec.ceilingheight then
floor.floordestheight := sec.ceilingheight;
if floortype = raiseFloorCrush then // if floor.crush then
floor.floordestheight := floor.floordestheight - 8 * FRACUNIT;
end;
raiseFloorTurbo:
begin
floor.direction := 1;
floor.sector := sec;
floor.speed := FLOORSPEED * 4;
floor.floordestheight := P_FindNextHighestFloor(sec, sec.floorheight);
end;
raiseFloorToNearest:
begin
floor.direction := 1;
floor.sector := sec;
floor.speed := FLOORSPEED;
floor.floordestheight := P_FindNextHighestFloor(sec, sec.floorheight);
end;
raiseFloor24:
begin
floor.direction := 1;
floor.sector := sec;
floor.speed := FLOORSPEED;
floor.floordestheight := floor.sector.floorheight + 24 * FRACUNIT;
end;
raiseFloor512:
begin
floor.direction := 1;
floor.sector := sec;
floor.speed := FLOORSPEED;
floor.floordestheight := floor.sector.floorheight + 512 * FRACUNIT;
end;
raiseFloor24AndChange:
begin
floor.direction := 1;
floor.sector := sec;
floor.speed := FLOORSPEED;
floor.floordestheight := floor.sector.floorheight + 24 * FRACUNIT;
sec.floorpic := line.frontsector.floorpic;
sec.special := line.frontsector.special;
end;
raiseToTexture:
begin
minsize := MAXINT;
floor.direction := 1;
floor.sector := sec;
floor.speed := FLOORSPEED;
for i := 0 to sec.linecount - 1 do
begin
if twoSided(secnum, i) <> 0 then
begin
side := getSide(secnum, i, 0);
if side.bottomtexture >= 0 then
if textureheight[side.bottomtexture] < minsize then
minsize := textureheight[side.bottomtexture];
side := getSide(secnum, i, 1);
if side.bottomtexture >= 0 then
if textureheight[side.bottomtexture] < minsize then
minsize := textureheight[side.bottomtexture];
end;
end;
floor.floordestheight := floor.sector.floorheight + minsize;
end;
lowerAndChange:
begin
floor.direction := -1;
floor.sector := sec;
floor.speed := FLOORSPEED;
floor.floordestheight := P_FindLowestFloorSurrounding(sec);
floor.texture := sec.floorpic;
for i := 0 to sec.linecount - 1 do
begin
if twoSided(secnum, i) <> 0 then
begin
side := getSide(secnum, i, 0);
if pDiff(side.sector, @sectors[0], SizeOf(side.sector^)) = secnum then
begin
sec := getSector(secnum, i, 1);
if sec.floorheight = floor.floordestheight then
begin
floor.texture := sec.floorpic;
floor.newspecial := sec.special;
break;
end;
end
else
begin
sec := getSector(secnum, i, 0);
if sec.floorheight = floor.floordestheight then
begin
floor.texture := sec.floorpic;
floor.newspecial := sec.special;
break;
end;
end;
end;
end;
end;
end;
until secnum < 0;
end;
//==============================================================================
// EV_BuildStairs
//
// BUILD A STAIRCASE!
//
//==============================================================================
function EV_BuildStairs(line: Pline_t; _type: stair_e): integer;
var
secnum: integer;
height: integer;
i: integer;
newsecnum: integer;
texture: integer;
ok: boolean;
sec: Psector_t;
tsec: Psector_t;
floor: Pfloormove_t;
stairsize: fixed_t;
speed: fixed_t;
begin
secnum := -1;
result := 0;
repeat
secnum := P_FindSectorFromLineTag(line, secnum);
if secnum < 0 then
exit;
sec := @sectors[secnum];
// ALREADY MOVING? IF SO, KEEP GOING...
if sec.specialdata <> nil then
continue;
// new floor thinker
result := 1;
floor := Z_Malloc(SizeOf(floormove_t), PU_LEVSPEC, nil);
ZeroMemory(floor, SizeOf(floormove_t));
P_AddThinker(@floor.thinker);
sec.specialdata := floor;
floor.thinker._function.acp1 := @T_MoveFloor;
floor.direction := 1;
floor.sector := sec;
floor._type := buildStair;
case _type of
build8:
begin
speed := FLOORSPEED div 4;
stairsize := 8 * FRACUNIT;
end;
turbo16:
begin
speed := FLOORSPEED * 4;
stairsize := 16 * FRACUNIT;
end;
else
begin
speed := 0;
stairsize := 0;
end;
end;
floor.speed := speed;
height := sec.floorheight + stairsize;
floor.floordestheight := height;
texture := sec.floorpic;
// Find next sector to raise
// 1. Find 2-sided line with same sector side[0]
// 2. Other side is the next sector to raise
repeat
ok := false;
for i := 0 to sec.linecount - 1 do
begin
if sec.lines[i].flags and ML_TWOSIDED = 0 then
continue;
tsec := sec.lines[i].frontsector;
newsecnum := pDiff(tsec, @sectors[0], SizeOf(sector_t));
if secnum <> newsecnum then
continue;
tsec := sec.lines[i].backsector;
newsecnum := pDiff(tsec, @sectors[0], SizeOf(sector_t));
if tsec.floorpic <> texture then
continue;
height := height + stairsize;
if tsec.specialdata <> nil then
continue;
sec := tsec;
secnum := newsecnum;
floor := Z_Malloc(SizeOf(floormove_t), PU_LEVSPEC, nil);
ZeroMemory(floor, SizeOf(floormove_t));
P_AddThinker(@floor.thinker);
sec.specialdata := floor;
floor.thinker._function.acp1 := @T_MoveFloor;
floor.direction := 1;
floor.sector := sec;
floor.speed := speed;
floor.floordestheight := height;
floor._type := buildStair;
ok := true;
break;
end;
until not ok;
until secnum < 0;
end;
end.