add source

Author: jorsn

README.md

@@ -0,0 +1,41 @@
+# flakegen
+
+In Nix flakes, inputs must be written as pure data, without function
+(see issues [NixOS/nix#3966](https://github.com/NixOS/nix/issues/3966)
+and [NixOS/nix#4945](https://github.com/NixOS/nix/issues/4945)).
+To generate inputs with the full power of the Nix language,
+one can create a template file, e.g. `flake.in.nix` and generate the
+`flake.nix` by evaluating and pretty-printing the `inputs` attribute.
+
+This flake is a convenience wrapper around that.
+
+
+## Usage
+
+To start using this, run
+```
+nix flake init -t github:jorsn/flakegen
+```
+
+This will create the files `flake.nix` and `flake.in.nix`.
+It will not overwrite existing files.
+After editing `flake.in.nix` as you like, run
+```
+nix run .#genflake flake.nix
+```
+to update the `flake.nix`.
+To preview the new `flake.nix` without replacing it, run the following:
+```
+nix run .#genflake
+```
+
+
+## Repair broken `flake.nix`
+
+You can repair a broken `flake.nix` by
+deleting `flake.nix` and running
+```
+nix flake init -t github:jorsn/flakegen
+nix run .#genflake flake.nix
+```
+as long as `flake.in.nix` works.

flake.nix

@@ -0,0 +1,73 @@
+{
+  description = "Flake inputs with the full power of Nixlang";
+
+  inputs.systems.url = "github:nix-systems/default";
+
+  outputs = { self, systems }: with builtins; with self.lib; {
+
+    templates.default = {
+      description = "Default template";
+      path = ./template;
+    };
+
+    __functor = _: path: let s = import systems; in { systems ? s, inputFile ?  "flake.in.nix", apps ? {}, ... }@outputAttrs:
+      {
+        nextFlake = flake path inputFile;
+        nextFlakeSource = flakeSource path inputFile;
+      }
+      // outputAttrs
+      // {
+        apps = self.lib.genAttrs (system:
+          { genflake = { type = "app"; program = ./genflake; }; }
+          // apps.${system} or {}
+        ) systems;
+      };
+    
+    lib = {
+
+      flake = path: inputFile: toFile "flake.nix" (flakeSource path inputFile);
+
+      flakeSource = path: inputFile:
+      let
+        attrs = import (path + "/${inputFile}");
+        attrs' = attrs // {
+          inputs = { flakegen.url = "github:jorsn/flakegen"; } // (attrs.inputs or {});
+          outputs = "<outputs>";
+        };
+      in "# Do not modify! This file is generated.\n\n"
+        + replaceStrings
+          [ "\"<outputs>\"" ] [ "inputs: inputs.flakegen ./. ((import ./${inputFile}).outputs inputs)" ]
+          (toPretty "" attrs')
+        ;
+
+      genAttrs = f: names:
+        listToAttrs (map (name: { inherit name; value = f name; }) names);
+
+      toPretty =
+        let
+          printChild = prefix: x:
+            let
+              names = attrNames x;
+            in 
+            if isAttrs x && length names == 1
+            then "." + head names + printChild prefix x.${head names}
+            else " = " + print prefix x
+            ;
+        
+          mapAttrsToList = f: attrs: attrValues (mapAttrs f attrs);
+          mapAttrsToLines = f: attrs: concatStringsSep "\n" (mapAttrsToList f attrs);
+          print = prefix: x:
+            if isString x
+            then "\"${x}\""
+            else if ! isAttrs x
+            then toString x
+            else let prefix' = prefix + "  "; in ''
+              {
+              ${mapAttrsToLines (n: v: prefix' + n + printChild prefix' v + ";") x}
+              ${prefix}}'';
+        in print;
+    };
+
+  };
+
+}

genflake

@@ -0,0 +1,7 @@
+#!/bin/sh
+
+if [ "$1" = '' ]; then
+  nix eval --raw .#nextFlakeSource
+else
+  cp $(nix eval --raw .#nextFlake) "$1"
+fi

template/flake.in.nix

@@ -0,0 +1,22 @@
+{
+
+  description = "The real nix file";
+
+  inputs = let
+    dep = url: { inherit url; inputs.nixpkgs.follows = "nixpkgs"; };
+  in {
+    # flakegen needn't be declared, here. It is automatically added when
+    # generating flake.nix.
+    nixlib.url = "github:nix-community/nixpkgs.lib";
+    nixpkgs.url = "github:NixOS/nixpkgs/nixos-unstable";
+    nix-darwin = (dep "github:LnL7/nix-darwin");
+    home-manager = (dep "github:nix-community/home-manager");
+  };
+
+  outputs = { nixpkgs, ... }@inputs: {
+    # you can write the outputs as usual. They will be called from the generated
+    # flake.nix.
+    packages.x86_64-linux.hello = nixpkgs.legacyPackages.x86_64-linux.hello;
+  };
+
+}

template/flake.nix

@@ -0,0 +1,9 @@
+# Do not modify! This file is generated.
+
+{
+  description = "A very basic flake";
+
+  inputs.flakegen.url = "github:jorsn/flakegen";
+
+  outputs = { flakegen, ... }: flakegen ./. {};
+}