- Added a CMake option called JAS_ENABLE_CMAKE_PACKAGE_CONFIG to enable

  CMake package config file generation.
- Fixed a bug in jpeglib.h header detection.

Author: mdadams

CMakeLists.txt

@@ -108,6 +108,8 @@ endif()
 
 option(JAS_PACKAGING "Enable packaging mode (e.g., disable RPATH)" OFF)
 
+option(JAS_ENABLE_CMAKE_PACKAGE_CONFIG "Enable CMake package config file generation" OFF)
+
 option(JAS_ENABLE_PIC "Enable position-independent code" ON)
 set(CMAKE_POSITION_INDEPENDENT_CODE ${JAS_ENABLE_PIC})
 
@@ -756,11 +758,13 @@ if(JAS_ENABLE_LIBJPEG)
 		# (e.g., stdio.h and stdint.h).  So, we cannot reliably use
 		# check_include_file here.
 		jas_get_includes_from_targets(CMAKE_REQUIRED_INCLUDES JPEG::JPEG)
+		message("JPEG include directories: ${CMAKE_REQUIRED_INCLUDES}")
 		check_c_source_compiles("
 			#include <stdio.h>
 			#include <stdint.h>
+			#include <stddef.h>
 			#include <jpeglib.h>
-			int main() {}
+			int main(void) {}
 		" JAS_HAVE_JPEGLIB_H)
 		if(JAS_HAVE_JPEGLIB_H)
 			set(JAS_HAVE_LIBJPEG 1)
@@ -875,3 +879,43 @@ install(FILES "${CMAKE_CURRENT_BINARY_DIR}/build/pkgconfig/jasper.pc"
   DESTINATION "${CMAKE_INSTALL_LIBDIR}/pkgconfig")
 
 install(FILES "README.md" DESTINATION "${CMAKE_INSTALL_DOCDIR}")
+
+################################################################################
+# CMake package config files for find_package(JasPer CONFIG ...)
+################################################################################
+
+if(JAS_ENABLE_CMAKE_PACKAGE_CONFIG)
+
+	include(CMakePackageConfigHelpers)
+
+	# Create a version file for the package.
+	write_basic_package_version_file(
+	  "${CMAKE_CURRENT_BINARY_DIR}/JasPerConfigVersion.cmake"
+	  VERSION ${JAS_VERSION}
+	  COMPATIBILITY AnyNewerVersion
+	)
+
+	# Configure the config file that downstream projects will include.
+	configure_package_config_file(
+	  "${CMAKE_CURRENT_SOURCE_DIR}/build/cmake/modules/JasPerConfig.cmake.in"
+	  "${CMAKE_CURRENT_BINARY_DIR}/JasPerConfig.cmake"
+	  INSTALL_DESTINATION "${CMAKE_INSTALL_LIBDIR}/cmake/JasPer"
+	)
+
+	# Export the targets.
+	install(EXPORT JasPerTargets
+	  FILE JasPerTargets.cmake
+	  NAMESPACE JasPer::
+	  DESTINATION "${CMAKE_INSTALL_LIBDIR}/cmake/JasPer"
+	)
+
+	# Install the config and version files.
+	install(FILES
+	  "${CMAKE_CURRENT_BINARY_DIR}/JasPerConfig.cmake"
+	  "${CMAKE_CURRENT_BINARY_DIR}/JasPerConfigVersion.cmake"
+	  DESTINATION "${CMAKE_INSTALL_LIBDIR}/cmake/JasPer"
+	)
+
+endif()
+
+################################################################################

build/build

@@ -125,6 +125,7 @@ enable_strict=1
 cmake_generator=
 enable_32bit=0
 enable_cxx=1
+enable_cmake_package_config=0
 
 while [ $# -gt 0 ]; do
 	option="$1"
@@ -144,6 +145,15 @@ while [ $# -gt 0 ]; do
 		cmake_generator="Ninja"
 		;;
 
+	--cmake-package-config)
+		shift 1
+		enable_cmake_package_config=1
+		;;
+	--no-cmake-package-config)
+		shift 1
+		enable_cmake_package_config=0
+		;;
+
 	--clean-build-dir)
 		shift 1
 		clean_build_dir=1
@@ -486,6 +496,14 @@ configure_opts=()
 configure_opts+=(-B"$build_dir")
 configure_opts+=(-H"$source_dir")
 
+#configure_opts+=(--trace-expand)
+
+if [ -n "$enable_cmake_package_config" ]; then
+	configure_opts+=(
+	  -D "JAS_ENABLE_CMAKE_PACKAGE_CONFIG=$enable_cmake_package_config"
+	)
+fi
+
 if [ -n "$cmake_generator" ]; then
 	configure_opts+=(-G "$cmake_generator")
 fi

build/cmake/modules/JasPerConfig.cmake.in

@@ -0,0 +1,5 @@
+@PACKAGE_INIT@
+
+set(JasPer_FOUND TRUE)
+
+include("${CMAKE_CURRENT_LIST_DIR}/JasPerTargets.cmake")

src/libjasper/CMakeLists.txt

@@ -168,6 +168,16 @@ add_library(libjasper ${libjasper_type}
 	${libjasper_ras_sources}
 )
 
+if(JAS_ENABLE_CMAKE_PACKAGE_CONFIG)
+	install(TARGETS libjasper
+	  EXPORT JasPerTargets
+	  ARCHIVE DESTINATION ${CMAKE_INSTALL_LIBDIR}
+	  LIBRARY DESTINATION ${CMAKE_INSTALL_LIBDIR}
+	  RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR}
+	  INCLUDES DESTINATION ${CMAKE_INSTALL_INCLUDEDIR}
+	)
+endif()
+
 # The JasPer include directories in the source and build tree must be included
 # before any other directories that may contain the include directory for an
 # already installed version of the JasPer library.