-
Notifications
You must be signed in to change notification settings - Fork 0
/
CMakeLists.txt
93 lines (86 loc) · 3.85 KB
/
CMakeLists.txt
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
cmake_minimum_required(VERSION 3.11)
project(neosocksd
LANGUAGES C
HOMEPAGE_URL "https://github.com/hexian000/neosocksd")
function(get_git_version)
find_package(Git)
if(NOT GIT_FOUND)
return()
endif()
execute_process(
COMMAND ${GIT_EXECUTABLE} rev-parse --git-dir
RESULT_VARIABLE RESULT
OUTPUT_VARIABLE GIT_REPO
OUTPUT_STRIP_TRAILING_WHITESPACE)
if(RESULT)
return()
endif()
execute_process(
COMMAND ${GIT_EXECUTABLE} tag --points-at HEAD
OUTPUT_VARIABLE GIT_HEAD
OUTPUT_STRIP_TRAILING_WHITESPACE)
if("${GIT_HEAD}" STREQUAL "")
execute_process(
COMMAND ${GIT_EXECUTABLE} rev-parse --short HEAD
OUTPUT_VARIABLE GIT_HEAD
OUTPUT_STRIP_TRAILING_WHITESPACE)
set(GIT_HEAD "git-${GIT_HEAD}")
endif()
execute_process(COMMAND ${GIT_EXECUTABLE} update-index --refresh -q)
execute_process(
COMMAND ${GIT_EXECUTABLE} diff-index --quiet HEAD --
RESULT_VARIABLE RESULT)
if(RESULT)
set(PROJECT_VERSION_STRING "${GIT_HEAD}+" PARENT_SCOPE)
else()
set(PROJECT_VERSION_STRING "${GIT_HEAD}" PARENT_SCOPE)
endif()
endfunction(get_git_version)
if("${PROJECT_VERSION_STRING}" STREQUAL "")
set(PROJECT_VERSION_STRING "dev")
get_git_version()
endif()
message(STATUS "Project version: ${PROJECT_VERSION_STRING}")
include(CTest)
option(FORCE_POSIX "Build the core features using POSIX-compliant APIs only" OFF)
option(BUILD_STATIC "Build static executables, link everything statically" OFF)
option(LINK_STATIC_LIBS "Link against static libraries" OFF)
option(LINK_STATIC_LUA "Link against static liblua" ON)
option(ENABLE_SANITIZERS "Build with sanitizers" OFF)
option(ENABLE_SYSTEMD "Enable systemd integration" OFF)
option(ENABLE_RULESET "Enable ruleset scripting (requires Lua)" ON)
set(CMAKE_C_STANDARD 11)
set(CMAKE_C_STANDARD_REQUIRED ON)
if(CMAKE_C_COMPILER_ID STREQUAL "GNU")
if(ENABLE_SANITIZERS)
set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -fsanitize=address,leak,undefined -fstack-protector-all")
set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -fsanitize=address,leak,undefined -static-libasan -static-liblsan -static-libubsan")
endif()
set(CMAKE_C_FLAGS_RELEASE "${CMAKE_C_FLAGS_RELEASE} -ffile-prefix-map=${PROJECT_SOURCE_DIR}/= -flto=auto -ffat-lto-objects")
set(CMAKE_EXE_LINKER_FLAGS_RELEASE "${CMAKE_EXE_LINKER_FLAGS_RELEASE} -s -flto=auto -flto-partition=none")
set(CMAKE_C_FLAGS_RELWITHDEBINFO "${CMAKE_C_FLAGS_RELWITHDEBINFO} -flto=auto -ffat-lto-objects")
set(CMAKE_EXE_LINKER_FLAGS_RELWITHDEBINFO "${CMAKE_EXE_LINKER_FLAGS_RELWITHDEBINFO} -flto=auto -flto-partition=none")
if(BUILD_STATIC)
set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -static")
endif()
elseif(CMAKE_C_COMPILER_ID MATCHES "Clang")
if(ENABLE_SANITIZERS)
set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -fsanitize=address,leak,undefined -fstack-protector-all")
set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -fsanitize=address,leak,undefined -static-libsan")
endif()
set(CMAKE_C_FLAGS_RELEASE "${CMAKE_C_FLAGS_RELEASE} -ffile-prefix-map=${PROJECT_SOURCE_DIR}/= -flto")
set(CMAKE_EXE_LINKER_FLAGS_RELEASE "${CMAKE_EXE_LINKER_FLAGS_RELEASE} -s -flto")
if(BUILD_STATIC)
set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -static")
endif()
endif()
if(NOT FORCE_POSIX AND (CMAKE_SYSTEM_NAME STREQUAL "Linux" OR CMAKE_SYSTEM_NAME STREQUAL "Android"))
message(STATUS "Linux system: ${CMAKE_SYSTEM_NAME} ${CMAKE_SYSTEM_VERSION}")
list(APPEND CMAKE_REQUIRED_DEFINITIONS "-D_GNU_SOURCE")
set(TARGET_LINUX TRUE)
else()
message(STATUS "POSIX-compliant system: ${CMAKE_SYSTEM_NAME} ${CMAKE_SYSTEM_VERSION}")
list(APPEND CMAKE_REQUIRED_DEFINITIONS "-D_POSIX_C_SOURCE=200809L")
endif()
add_subdirectory(contrib)
add_subdirectory(src)