Divergence between object property's domain and restrictions using it

[mereolog]

In general, if:

1. ?property rdfs:domain ?domain.
2. ?restriction owl:onProperty ?property.

then any (direct) subclass of ?restriction should be a subclass of ?domain.

This is dual to #179.

At the moment, there are not cases of this problem in IDMP Ontology.

The following query would identify all "future" problems of this type:

SELECT DISTINCT ?class ?property ?domain
WHERE
{
    ?property rdfs:domain ?domain.
    ?restriction rdf:type owl:Restriction.
    ?restriction owl:onProperty ?property.
    ?class rdfs:subClassOf ?restriction.
    {
        {
            ?restriction owl:someValuesFrom ?restrictingClass.
        }
        UNION
        {
            {
                {?restriction owl:minQualifiedCardinality ?cardinality.}
                UNION
                {?restriction owl:minCardinality ?cardinality.}
            }
            FILTER (?cardinality > 0)
        }
    }
    FILTER (ISIRI(?domain))
    
    FILTER NOT EXISTS
    {
        ?class rdfs:subClassOf* ?domain.
    }
}

This should probably be added to hygiene tests.

[ElisaKendall]

@merelog I'm ok if you add this test.