How to make a filter function for tags comparison?

[DominikMendel]

Hi!
I'd like to pass a filter function into vulpea-insert. Something as simple as If node's tag == "people".
Any help would be great! I know how to do it for Org-Roam but my function seems to not work for vulpea-insert.

[d12frosted]

Have you read the filter section under vulpea-insert? It has an example you can use as a starting point. Let me know if you need further help.

[DominikMendel]

Hi, yes I have! I'm still not too sure how to do the tag query comparison.
If you don't mind helping out.

[d12frosted]

Well, let's take a look at it together.

vulpea/vulpea.el

Lines 143 to 153 in e1ea848

	(defun vulpea-insert (&optional filter-fn)
	"Select a note and insert a link to it.
	Allows capturing new notes. After link is inserted,
	`vulpea-insert-handle-functions' are called with the inserted
	note as the only argument regardless involvement of capture
	process.
	FILTER-FN is the function to apply on the candidates, which takes
	as its argument a `vulpea-note'. Unless specified,
	`vulpea-insert-default-filter' is used."

So what you want to have is:

(vulpea-insert (lambda (note) SOME-PREDICATE))

And what SOME-PREDICATE would be? If you want to check if the note is tagged as people, I would start by looking at the vulpea-note definition first:

vulpea/vulpea-note.el

Lines 39 to 50 in e1ea848

	(cl-defstruct vulpea-note
	id
	path
	level
	title
	primary-title
	aliases
	tags
	links
	properties
	meta
	attach-dir)

So that means you can get tags from the note like this: (vulpea-note-tags note). Hence you can check if the list of tags contains "people":

(vulpea-insert (lambda (note) (seq-contains-p (vulpea-note-tags note) "people")))

Nice! But it turns out there is a shortcut for this in vulpea:

vulpea/vulpea-note.el

Lines 114 to 122 in e1ea848

	(cl-defmethod vulpea-note-tagged-all-p ((note vulpea-note) &rest tags)
	"Return non-nil if a NOTE is tagged by all of the TAGS."
	(let ((note-tags (vulpea-note-tags note)))
	(--all-p (-contains-p note-tags it) tags)))
	(cl-defmethod vulpea-note-tagged-any-p ((note vulpea-note) &rest tags)
	"Return non-nil if a NOTE is tagged by any of the TAGS."
	(let ((note-tags (vulpea-note-tags note)))
	(--any-p (-contains-p note-tags it) tags)))

So you can simplify the code like this:

(vulpea-insert (lambda (note) (vulpea-note-tagged-all-p note "people")))

If your collection is HUGE and you want to optimise vulpea-insert you can actually override vulpea-insert-default-candidates-source. It can be achieved by using specialised query functions and local bindings:

(defun my-vulpea-db-query-people (&optional filter)
  "Query people from `vulpea-db' and apply an optional FILTER."
  (seq-filter filter (vulpea-db-query-by-tags-every '("people"))))

(let ((vulpea-insert-default-candidates-source #'my-vulpea-db-query-people))
  (vulpea-insert))

Here you define a helper function to query notes tagged as 'people' using vulpea-db-query-by-tags-every (which gives tremendous performance boost when the subset you want to query is substantially smaller than whole db - see readme for more information) and then you bind it locally before executing vulpea-insert.

Hope that helps.

P.S. Was curious of ChatGPT can help with this task. It does the job quite well :)

[d12frosted]

BTW, you said that you know how to do it with Org Roam, but it doesn't work with Vulpea. Care to share what you have? Probably this is something I should've asked before sharing solution with you.

[DominikMendel]

Thank you for such a detailed and helpful response @d12frosted. Your prompted solution did work perfectly, thanks!

Previous I had this code defined :

(defun my/org-roam-filter-by-tag (tag-name)
  (lambda (node)
    (member tag-name (org-roam-node-tags node))))

(defun my/org-roam-find-people ()
  (interactive)
  ;; Select a project file to open, creating it if necessary
  (org-roam-node-find
   nil
   nil
   (my/org-roam-filter-by-tag "people")
   :templates org-roam-capture-templates))

So I thought if I just passed in my/org-roam-filter-by-tag into vulpea-insert it would work. But that is not the case.

P.S.
It's AMAZING how well of a job ChatGPT did. I never use it, and honestly this is probably the tipping point of me needing to use it. It would have reduced both of our time spent. So thank you for showing me that snippet! :)

[d12frosted]

(defun my/org-roam-filter-by-tag (tag-name)
  (lambda (node)
    (member tag-name (org-roam-node-tags node))))

You were so close. But of course org-roam-node-tags would not work on vulpea-note - I am pretty sure the error said something like #(vulpea-note ...) is not org-roam-node :)

[DominikMendel]

Ah that makes sense. Thanks for following up :)