Show the package name for which the error associated

In certain cases, it's unclear which package causes an error during shard installation.
These changes improves error and log messages by adding explicit package context.
When an error occurs, the log will now indicate which package triggered the failure.

Author: miry

spec/integration/install_spec.cr

@@ -855,7 +855,7 @@ describe "install" do
     with_shard(metadata) do
       ex = expect_raises(FailedCommand) { run "shards install --no-color" }
       ex.stdout.should contain <<-ERROR
-        E: Could not find executable "nonexistent"
+        E: Failed to install `executable_missing`: Could not find executable "nonexistent"
         ERROR
     end
   end

src/cli.cr

@@ -176,12 +176,19 @@ end
 begin
   Shards.run
 rescue ex : OptionParser::InvalidOption
-  Shards::Log.fatal { ex.message }
+  Shards::Log.fatal(exception: ex) { ex.message }
+  Shards::Log.trace { ex.inspect_with_backtrace }
   exit 1
 rescue ex : Shards::ParseError
   ex.to_s(STDERR)
   exit 1
+rescue ex : Shards::Package::Error
+  package = ex.package
+  Shards::Log.error(exception: ex) { "Failed to install `#{package.name}`: #{ex.message}" }
+  Shards::Log.trace { ex.inspect_with_backtrace }
+  exit 1
 rescue ex : Shards::Error
-  Shards::Log.error { ex.message }
+  Shards::Log.error(exception: ex) { ex.message }
+  Shards::Log.trace { ex.inspect_with_backtrace }
   exit 1
 end

src/logger.cr

@@ -30,8 +30,9 @@ module Shards
 
   FORMATTER = ::Log::Formatter.new do |entry, io|
     message = entry.message
-
+    package_name = entry.context[:package]?
     if @@colors
+      io << "[" << package_name.colorize(:blue).to_s << "] " if package_name && entry.severity <= ::Log::Severity::Debug
       io << if color = LOGGER_COLORS[entry.severity]?
         if idx = message.index(' ')
           message[0...idx].colorize(color).to_s + message[idx..-1]
@@ -42,7 +43,9 @@ module Shards
         message
       end
     else
-      io << entry.severity.label[0] << ": " << message
+      io << entry.severity.label[0] << ": "
+      io << "[" << package_name << "] " if package_name && entry.severity <= ::Log::Severity::Debug
+      io << message
     end
   end
 end

src/molinillo_solver.cr

@@ -61,7 +61,10 @@ module Shards
         end
         spawn do
           begin
-            dep.resolver.update_local_cache if dep.resolver.is_a? GitResolver
+            Log.with_context do
+              Log.context.set package: dep.name
+              dep.resolver.update_local_cache if dep.resolver.is_a? GitResolver
+            end
             ch.send(nil)
           rescue ex : Exception
             ch.send(ex)

src/package.cr

@@ -3,6 +3,14 @@ require "./helpers"
 
 module Shards
   class Package
+    class Error < Shards::Error
+      getter package
+
+      def initialize(message, @package : Package)
+        super message
+      end
+    end
+
     getter name : String
     getter resolver : Resolver
     getter version : Version
@@ -58,15 +66,20 @@ module Shards
     end
 
     def install
-      cleanup_install_directory
+      Log.with_context do
+        Log.context.set package: name
+        Log.context.set version: report_version
+
+        cleanup_install_directory
 
-      # install the shard:
-      resolver.install_sources(version, install_path)
+        # install the shard:
+        resolver.install_sources(version, install_path)
 
-      # link the project's lib path as the shard's lib path, so the dependency
-      # can access transitive dependencies:
-      unless resolver.is_a?(PathResolver)
-        install_lib_path
+        # link the project's lib path as the shard's lib path, so the dependency
+        # can access transitive dependencies:
+        unless resolver.is_a?(PathResolver)
+          install_lib_path
+        end
       end
 
       Shards.info.installed[name] = self
@@ -114,7 +127,7 @@ module Shards
       spec.executables.each do |name|
         exe_name = find_executable_file(Path[install_path], name)
         unless exe_name
-          raise Shards::Error.new("Could not find executable #{name.inspect}")
+          raise Shards::Package::Error.new("Could not find executable #{name.inspect}", package: self)
         end
         Log.debug { "Install #{exe_name}" }
         source = File.join(install_path, exe_name)

src/resolvers/git.cr

@@ -363,7 +363,10 @@ module Shards
 
     private def valid_repository?
       command = "git config --get remote.origin.mirror"
-      Log.debug { command }
+      Log.with_context do
+        Log.context.set package: name
+        Log.debug { command }
+      end
 
       output = Process.run(command, shell: true, output: :pipe, chdir: local_path) do |process|
         process.output.gets_to_end
@@ -437,7 +440,10 @@ module Shards
         raise Error.new("Error missing git command line tool. Please install Git first!")
       end
 
-      Log.debug { command }
+      Log.with_context do
+        Log.context.set package: name
+        Log.debug { command }
+      end
 
       output = capture ? IO::Memory.new : Process::Redirect::Close
       error = IO::Memory.new