terraform project code

Author: kammana

.gitignore

@@ -0,0 +1,2 @@
+*.terraform*
+*.tfstate*

elb.tf

@@ -0,0 +1,35 @@
+# Create a new load balancer
+resource "aws_elb" "javahome-elb" {
+  name               = "javahome-elb"
+  # availability_zones = ["${var.azs}"]
+  subnets = ["${aws_subnet.public.*.id}"]
+  security_groups = ["${aws_security_group.webservers.id}"]
+  listener {
+    instance_port     = 80
+    instance_protocol = "http"
+    lb_port           = 80
+    lb_protocol       = "http"
+  }
+
+  health_check {
+    healthy_threshold   = 2
+    unhealthy_threshold = 2
+    timeout             = 3
+    target              = "HTTP:80/index.html"
+    interval            = 10
+  }
+
+  instances                   = ["${aws_instance.webservers.*.id}"]
+  cross_zone_load_balancing   = true
+  idle_timeout                = 100
+  connection_draining         = true
+  connection_draining_timeout = 300
+
+  tags {
+    Name = "javahome-terraform-elb"
+  }
+}
+
+output "elb-dns-name"{
+  value = "${aws_elb.javahome-elb.dns_name}"
+}

install_httpd.sh

@@ -0,0 +1,6 @@
+#! /bin/bash
+
+yum install httpd -y
+echo "<h1>Deployed by terraform </h1>" > /var/www/html/index.html
+chkconfig httpd on
+service httpd start

instances.tf

@@ -0,0 +1,13 @@
+resource "aws_instance" "webservers" {
+  count = "${length(var.subnets_cidr)}"
+  ami = "${var.webservers_ami}"
+  instance_type = "${var.instance_type}"
+  security_groups = ["${aws_security_group.webservers.id}"]
+  subnet_id = "${element(aws_subnet.public.*.id,count.index)}"
+  user_data = "${file("install_httpd.sh")}"
+
+  tags {
+    Name = "Server-${count.index}"
+  }
+
+}

provider.tf

@@ -0,0 +1,3 @@
+provider "aws" {
+  region = "${var.aws_region}"
+}

security-groups.tf

@@ -0,0 +1,19 @@
+resource "aws_security_group" "webservers" {
+  name        = "allow_http"
+  description = "Allow http inbound traffic"
+  vpc_id      = "${aws_vpc.javahome_vpc.id}"
+
+  ingress {
+    from_port   = 80
+    to_port     = 80
+    protocol    = "tcp"
+    cidr_blocks = ["0.0.0.0/0"]
+  }
+
+  egress {
+    from_port       = 0
+    to_port         = 0
+    protocol        = "-1"
+    cidr_blocks     = ["0.0.0.0/0"]
+  }
+}

variables.tf

@@ -0,0 +1,25 @@
+variable "aws_region" {
+  default = "us-west-2"
+}
+
+variable "vpc_cidr" {
+  default = "10.20.0.0/16"
+}
+
+variable "subnets_cidr" {
+  type    = "list"
+  default = ["10.20.1.0/24", "10.20.2.0/24"]
+}
+
+variable "azs" {
+  type    = "list"
+  default = ["us-west-2a", "us-west-2b"]
+}
+
+variable "webservers_ami" {
+  default = "ami-e689729e"
+}
+
+variable "instance_type" {
+  default = "t2.micro"
+}

vpc.tf

@@ -0,0 +1,54 @@
+# VPC for our applications
+
+resource "aws_vpc" "javahome_vpc" {
+  cidr_block = "${var.vpc_cidr}"
+
+  tags {
+    Name = "JavaHomeVPC"
+  }
+}
+
+# Create Internet Gateway and attach it to javahome_vpc
+
+resource "aws_internet_gateway" "javahome_igw" {
+  vpc_id = "${aws_vpc.javahome_vpc.id}"
+
+  tags {
+    Name = "main"
+  }
+}
+
+# Build subnets for our VPCs
+resource "aws_subnet" "public" {
+  count             = "${length(var.subnets_cidr)}"
+  vpc_id            = "${aws_vpc.javahome_vpc.id}"
+  availability_zone = "${element(var.azs,count.index)}"
+  cidr_block        = "${element(var.subnets_cidr,count.index)}"
+  map_public_ip_on_launch = true
+  tags {
+    Name = "Subnet-${count.index +1}"
+  }
+}
+
+# Create Route table, attache Internet Gateway and associate with public subnets
+
+
+resource "aws_route_table" "public_rt" {
+  vpc_id = "${aws_vpc.javahome_vpc.id}"
+
+  route {
+    cidr_block = "0.0.0.0/0"
+    gateway_id = "${aws_internet_gateway.javahome_igw.id}"
+  }
+  tags {
+    Name = "PublicRT"
+  }
+}
+
+# Attach route table with public subnets
+
+resource "aws_route_table_association" "a" {
+  count = "${length(var.subnets_cidr)}"
+  subnet_id      = "${element(aws_subnet.public.*.id, count.index)}"
+  route_table_id = "${aws_route_table.public_rt.id}"
+}