running pct on host to modify container

[redpimpernel]

Hi,
I am trying to create containers and set them up for ansible-pull.
To do this, I need to install Ansible and drop a file on the container as it is provisioned by terraform.

I am trying to use a terraform local provisioner to run pct on the proxmox host and execute a command on the container.
I am getting an error /bin/sh/ 1: pct not found.

pct works if I call it manually from the web console. I am using username and password as the root user for the terraform provider.

Another local provisioner works which calls sleep to make sure the container comes up before the main provisioner is run.

does anyone know whats happening?

[redpimpernel]

sorry forgot to show my provisioner:

  provisioner "local-exec" {
    command = "pct list"
  }

I have also tried (same error)

  provisioner "local-exec" {
    command = "/usr/sbin/pct list"
    interpreter = [ "/bin/sh", "-c" ]
  }

I have also tried different combinations of the last provisioner, whether it has the full path to pct or not.

[loganmancuso]

I have done some work with bootstrapping containers, here is some sample code

resource "proxmox_virtual_environment_file" "bootstrap" {
  content_type = "snippets"
  datastore_id = "local"
  node_name    = local.node.name

  source_raw {
    file_name = "${var.instance.name}-bootstrap.sh"
    data      = templatefile(
      var.bootstrap.path,
      merge({ log = "${local.directories.log}/bootstrap.log" }, var.bootstrap.tokens)
    )
  }
}

this first resource creates a snippet file on the proxmox ve node. In my case it is a bash script that will be used to bootstrap the lxc with custom tooling. I use the template file to transform the bootstrap script with sensitive information and logging paths ect. In your case you can use data = <<EOT and write your ansible file right in your tf file.

resource "terraform_data" "bootstrap" {
  depends_on       = [proxmox_virtual_environment_container.instance]
  triggers_replace = [md5(file(var.bootstrap.path))]
  provisioner "remote-exec" {
    when = create
    inline = [
      # copy the bootstrap snippet to the container
      "pct push ${proxmox_virtual_environment_container.instance.id} /var/lib/vz/snippets/${proxmox_virtual_environment_file.bootstrap.file_name} ${local.bootstrap_home}",
      # execute the bootstrap script
      "pct exec ${proxmox_virtual_environment_container.instance.id} chmod u+x,g+x ${local.bootstrap_home}",
      "pct exec ${proxmox_virtual_environment_container.instance.id} ${local.bootstrap_home}"
    ]
    connection {
      type     = "ssh"
      user     = local.credentials_proxmox.username
      password = local.credentials_proxmox.password
      host     = local.node.ip
    }
  }
}

after that this resource executes some commands on the proxmox ve node to push and execute the script on the lxc. Proxmox provides a really handy pct command to push files to the container. In my case i push the snippet from the folder /var/lib/vz/snippet/{name of snippet} to the destination path in the lxc container. then pct exec to give the file execute permissions and then another pct exec to run the script.

[bpg]

Hi @redpimpernel!

Personally I don't use containers much, so can't share any insights on your set up. But the fact that you need to run pct on PVE host to do some configuration for containers seems quite out of ordinary.

I think VMs will be better suited for your use case. For VM you can define a cloud-init configuration that will be applied at the first VM boot up. In cloud-init you can adjust almost any aspect of the underlying OS, as well as execute any post-deployment actions. Installing and configuring Ansible is a pretty common task for cloud-init, so you can probably find an example out there that suits your needs.