build.gradle

buildscript {
    repositories {
        mavenCentral()
        maven {
            url 'https://plugins.gradle.org/m2/'
        }
    }
    dependencies {
        classpath('com.github.ben-manes:gradle-versions-plugin:0.29.0')
    }
}

subprojects {
    repositories {
        mavenCentral()
    }

    apply plugin: 'java-library'

    java {
        sourceCompatibility = JavaVersion.VERSION_11
        targetCompatibility = JavaVersion.VERSION_11

        withJavadocJar()
        withSourcesJar()
    }

    compileJava.dependsOn(processResources)

    compileJava {
        options.encoding = "UTF-8"
    }

    compileTestJava {
        options.encoding = "UTF-8"
    }

    apply plugin: 'maven-publish'
    publishing {
        publications {
            mavenJava(MavenPublication) {
                from components.java
                versionMapping {
                    usage('java-api') {
                        fromResolutionOf('runtimeClasspath')
                    }
                    usage('java-runtime') {
                        fromResolutionResult()
                    }
                }
                pom {
                    inceptionYear = '2019'
                    name = project.name
                    packaging = 'jar'
                    description = project.description
                    url = 'https://github.com/bottomless-archive-project/java-warc.git'

                    scm {
                        connection = 'git@github.com:bottomless-archive-project/java-warc.git'
                        developerConnection = 'git@github.com:bottomless-archive-project/java-warc.git'
                        url = 'https://github.com/bottomless-archive-project/java-warc.git'
                    }

                    licenses {
                        license {
                            name = 'Apache License 2.0'
                            url = 'https://opensource.org/licenses/Apache-2.0'
                        }
                    }

                    developers {
                        developer {
                            id = 'gyulalakatos'
                            name = 'Gyula Lakatos'
                            email = 'laxika91@gmail.com'
                        }
                    }
                }
            }
        }
        repositories {
            maven {
                url = 'https://oss.sonatype.org/service/local/staging/deploy/maven2/'
                allowInsecureProtocol = true
                credentials {
                    username ossrhUsername
                    password ossrhPassword
                }
            }
        }
    }

    apply plugin: 'signing'

    signing {
        sign publishing.publications.mavenJava
    }

    artifacts {
        archives javadocJar, sourcesJar
    }

    dependencies {
        implementation group: 'org.jetbrains', name: 'annotations', version: '22.0.0'

        compileOnly group: 'org.projectlombok', name: 'lombok', version: '1.18.20'
        annotationProcessor group: 'org.projectlombok', name: 'lombok', version: '1.18.20'
        testCompileOnly group: 'org.projectlombok', name: 'lombok', version: '1.18.20'
        testAnnotationProcessor group: 'org.projectlombok', name: 'lombok', version: '1.18.20'

        testImplementation group: 'org.slf4j', name: 'slf4j-simple', version: '1.7.32'
    }

    apply plugin: 'com.github.ben-manes.versions'
}