-
Notifications
You must be signed in to change notification settings - Fork 0
/
Keyboard.asm
402 lines (343 loc) · 7.37 KB
/
Keyboard.asm
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
; =========================================================
; Module: Keyboard
; =========================================================
; Description:
; Routines for handling an AT or PS/2 keyboard.
; Functions:
; Initialise: Detect, reset, initialise the mouse.
; Update: Read the status of the mouse and update
; variables.
; Variables:
; Position: Position of the mouse and scrollwheel.
; Status: Status of the buttons and mouse mode.
; =========================================================
.module Keyboard
; ---------------------------------------------------------
; GetScancode -> Retrieve a scancode from the keyboard.
; ---------------------------------------------------------
; Inputs: None.
; Outputs: z on success, nz on failure.
; a = scancode
; c = reset for press, set for release.
; s = set for extended key.
; Destroys: af, bc, de, hl
; ---------------------------------------------------------
GetScancode:
ld l,64
call AT.GetByte
ret nz
cp $E1
jr z,GetPauseScancode
cp $E0
jr nz,+
ld l,128|64
call AT.GetByte
ret nz
+: cp $F0
jr nz,+
inc l
call AT.GetByte
ret nz
+: ld h,a
push hl
pop af
ret
GetPauseScancode:
ld b,7
-: push bc
call AT.GetByte
pop bc
ret nz
djnz -
ld hl,64+$E1*256
push hl
pop af
ret
LayoutFileDescription = allocVar(2)
LayoutFile = allocVar(0)
LayoutFile.StandardTableSize = allocVar(2) ; Number of standard scancodes.
LayoutFile.ExtendedTableSize = allocVar(2) ; Number of extended scancodes.
LayoutFile.ModifiersLookup = allocVar(2) ; Address of modifier lookup list.
LayoutFile.ModifiersJumpTable = allocVar(2) ; Address of modifier jump table.
LayoutFile.StandardTableAddress = allocVar(2) ; Address of standard scancode table.
LayoutFile.ExtendedTableAddress = allocVar(2) ; Address of extended scancode table.
LayoutFile.KeyOffsetTable = allocVar(2) ; Address of key jump table.
LayoutFile.KeyDataTable = allocVar(2) ; Address of key data table.
LayoutFile.KeyTypeTable = allocVar(2) ; Address of the key type table.
LayoutFile.Size = allocVar(0) - LayoutFile
Status = allocVar(1)
LedState = allocVar(1)
OriginalScancode = allocVar(2)
; ---------------------------------------------------------
; LoadManualLayout -> Loads a keyboard layout definition.
; ---------------------------------------------------------
; Inputs: hl = address of layout definition data.
; Destroys: af, bc, de, hl, ix
; ---------------------------------------------------------
LoadManualLayout:
ld (OriginalScancode),hl ; Temp
ld de,LayoutFile
ld bc,LayoutFile.Size
ldir
ld (LayoutFileDescription),hl
ld ix,LayoutFile + 4
ld b,(LayoutFile.Size / 2) - 2
-: ld e,(ix+0) \ ld d,(ix+1)
ld hl,(OriginalScancode)
add hl,de
ld (ix+0),l \ ld (ix+1),h
inc ix \ inc ix
djnz -
xor a
ld (Status),a
ld (LedState),a
ret
; ---------------------------------------------------------
; ConvertScancode -> Convert a scancode to a key code.
; ---------------------------------------------------------
; Inputs: a = scancode.
; c = reset for press, set for release.
; s = set for extended key.
; Outputs: z on matched key.
; a = key code.
; c = reset for press, set for release.
; s = set for non-printable key.
; Destroys: af, bc, de, hl
; ---------------------------------------------------------
ConvertScancode:
push af
pop hl
ld (OriginalScancode),hl
ld hl,(LayoutFile.StandardTableAddress)
ld d,h \ ld e,l
ld bc,(LayoutFile.StandardTableSize)
jp p,+
ld hl,(LayoutFile.ExtendedTableAddress)
ld bc,(LayoutFile.ExtendedTableSize)
+
push bc
cpir
pop bc
ret nz
+
push hl
push hl
ld hl,(LayoutFile.StandardTableSize)
ld b,h \ ld c,l
ld hl,(LayoutFile.ExtendedTableSize)
add hl,bc
ld b,h \ ld c,l
pop hl
scf
sbc hl,bc
ld a,(hl)
pop hl
push af
scf
sbc hl,de
add hl,hl
ld de,(LayoutFile.KeyOffsetTable)
add hl,de
ld e,(hl) \ inc hl
ld a,(hl)
push af
and ~%11000000
ld d,a
add hl,de
; hl->key info block.
pop af
bit 7,a
jr z,IsNotModifier
bit 6,a
jr z,NotToggle
; This is a toggling modifier, e.g. Caps Lock.
ld a,(OriginalScancode)
bit 0,a
jr z,TogglePushed
ToggleReleased:
inc hl
ld a,(hl)
cpl
rlca \ rlca \ rlca \ rlca
ld e,a
ld a,(LedState)
and e
ld (LedState),a
jr IsNotModifier
TogglePushed
inc hl
ld a,(hl)
rlca \ rlca \ rlca \ rlca
ld e,a
ld a,(LedState)
ld d,a
and e
jr nz,IsNotModifier
ld a,d
or e
ld (LedState),a
dec hl
ld a,(Status)
xor (hl)
ld (Status),a
inc hl
ld a,(LedState)
xor (hl)
ld (LedState),a
ld a,$ED
call AT.SendSafeByte
ld a,(LedState)
and %111
call AT.SendSafeByte
inc hl
jr IsNotModifier
NotToggle
ld a,(OriginalScancode)
bit 0,a
jr nz,StatusOff
ld a,(Status)
or (hl)
jr +
StatusOff
ld a,(Status)
ld b,a
ld a,(hl)
cpl
and b
+: ld (Status),a
inc hl
IsNotModifier
ld a,(Status)
and (hl)
jr z,NoStatusModifiers
; Now we need to work out the index:
ld b,(hl)
push hl
push af
ld a,b
ld bc,0
ld hl,(LayoutFile.ModifiersLookup)
ld d,h \ ld e,l
cpir
dec hl
or a
sbc hl,de
add hl,hl
ld de,(LayoutFile.ModifiersJumpTable)
add hl,de
ld e,(hl)
inc hl
ld d,(hl)
add hl,de
ld d,h \ ld e,l
pop af
cpir
or a
sbc hl,de
ld d,h \ ld e,l
dec de
pop hl
add hl,de
NoStatusModifiers:
inc hl
ld a,(hl)
cp $FF
jr z,ExitNoKey
ld d,a
ld bc,(LayoutFile.KeyDataTable)
or a
sbc hl,bc
ld a,l
and 7
inc a
ld e,a
srl h \ rr l
srl h \ rr l
srl h \ rr l
ld bc,(LayoutFile.KeyTypeTable)
add hl,bc
ld a,(hl)
ld b,e
-: sla a
djnz -
; Carry = non-printable key.
ld a,(OriginalScanCode)
res 7,a ; S
jr nc,+
set 7,a
+:
set 6,a ; Z
ld e,a
push de
pop af
pop de
ret
ExitNoKey:
xor a
dec a
pop de
ret
; ---------------------------------------------------------
; GetKey -> Retrieves a key from the keyboard.
; ---------------------------------------------------------
; Inputs: None
; Outputs: z on valid key input.
; a = key code.
; c = reset for press, set for release.
; s = set for non-printable key.
; Destroys: af
; ---------------------------------------------------------
GetKey:
push hl
push bc
call GetScancode
jr nz,+
call ConvertScancode
+: pop bc
pop hl
ret
; .........................................................
; Equates for the non-printable key codes
; .........................................................
.module KeyCode
F1 = $00
F2 = $01
F3 = $02
F4 = $03
F5 = $04
F6 = $05
F7 = $06
F8 = $07
F9 = $08
F10 = $09
F11 = $0A
F12 = $0B
Up = $0C
Down = $0D
Left = $0E
Right = $0F
PageUp = $10
PageDown = $11
Insert = $12
PrintScreen = $13
Home = $14
End = $15
CtrlLeft = $16
CtrlRight = $17
Alt = $18
AltGr = $19
ShiftLeft = $1A
ShiftRight = $1B
WindowsLeft = $1C
WindowsRight = $1D
CapsLock = $1E
NumLock = $1F
ScrollLock = $20
Application = $21
Power = $22
Sleep = $23
Wake = $24
Escape = $25
Pause = $26
.endmodule
.endmodule