interactive-complex-8.sparql

PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
PREFIX xsd: <http://www.w3.org/2001/XMLSchema#>
PREFIX sn: <http://www.ldbc.eu/ldbc_socialnet/1.0/data/>
PREFIX snvoc: <http://www.ldbc.eu/ldbc_socialnet/1.0/vocabulary/>
PREFIX sntag: <http://www.ldbc.eu/ldbc_socialnet/1.0/tag/>
PREFIX foaf: <http://xmlns.com/foaf/0.1/>
PREFIX dbpedia: <http://dbpedia.org/resource/>
PREFIX dbpedia-owl: <http://dbpedia.org/ontology/>

SELECT
    ?personId
    ?personFirstName
    ?personLastName
    ?commentCreationDate
    ?commentId
    ?commentContent
WHERE
{
    VALUES (?type) {(snvoc:Comment) (snvoc:Post)}
    ?rootPerson a snvoc:Person .
    ?rootPerson snvoc:id $personId .
    ?message snvoc:hasCreator ?rootPerson .
    ?message a ?type .
    ?comment a snvoc:Comment .
    ?comment snvoc:replyOf ?message .
    ?comment snvoc:creationDate ?commentCreationDate .
    ?comment snvoc:id ?commentId .
    ?comment snvoc:content ?commentContent .
    ?comment snvoc:hasCreator ?person .
    ?person snvoc:id ?personId .
    ?person snvoc:firstName ?personFirstName .
    ?person snvoc:lastName ?personLastName
}
ORDER BY DESC(?commentCreationDate) ?commentId
LIMIT 20