go is only meant to be used with 'bazel run', not as a tool

[Zemnmez]

I'm trying to run a tool that uses gocommand (oapi-codegen), and thus needs Go in path in a genrule (it's used with go:generate, so this makes sense).

See below script:

genrule(
    name = "gen_api",
    srcs = [
        "@com_github_openai_openai_openapi//:openapi.yaml",
        "codegen.yaml",
    ],
    outs = ["api.go"],
    cmd = """
	export PATH=$$(dirname $$(realpath $(location //bin/sh:go))):$$PATH


$(execpath //bin/host/oapi-codegen) \\
	-config $(location codegen.yaml) \\
	-o $(location api.go) \\
	 $(location @com_github_openai_openai_openapi//:openapi.yaml)
	""",
    tools = [
        "//bin/host/oapi-codegen",
        "//sh/bin:go",
    ],
)

I get the below error:

                fail("//go is only meant to be used with 'bazel run', not as a tool. " +
Error in fail: //go is only meant to be used with 'bazel run', not as a tool. If you need to use it as a tool (e.g. in a genrule), please open an issue at https://github.com/bazelbuild/rules_go/issues/new explaining your use case.

This works in CI because the CI runner has go installed , but I think it's a little strange to need to do that

[ellie-idb]

this is my super rough undocumented rule that I use to do this at $work:

load("@rules_go//go/private:context.bzl", "go_context")
load("@rules_go//go/private:providers.bzl", "GoInfo")

GO_TOOLCHAIN = Label("@rules_go//go:toolchain")
OAPI_CODEGEN_TOOL = Label("@com_github_oapi_codegen_oapi_codegen_v2//cmd/oapi-codegen:oapi-codegen")

def _go_oapi_codegen_impl(ctx):
  go = go_context(ctx, include_deprecated_properties = False)
  sdk = go.sdk

  inputs_direct = [ctx.file.source]
  inputs_transitive = [sdk.tools, sdk.headers, sdk.srcs]

  args = []
  args += ["-package", ctx.attr.package]
  args += ["-generate", ",".join(ctx.attr.generate)]
  args += [ctx.file.source.path]

  ctx.actions.run_shell(
    outputs = [ctx.outputs.out],
    inputs = depset(inputs_direct, transitive = inputs_transitive),
    tools = [
      ctx.file.codegen_tool,
      sdk.go,
    ],
    toolchain = GO_TOOLCHAIN,
    command = """
      export GOROOT=$(pwd)/{goroot} &&
      export PATH=$GOROOT/bin:$PATH &&
      {cmd} {args} > {out}
    """.format(
      goroot = sdk.root_file.dirname,
      cmd = "$(pwd)/" + ctx.file.codegen_tool.path,
      args = " ".join(args),
      out = ctx.outputs.out.path,
      mnemonic = "GoOpenApiSourceGen",
    )
  )

go_oapi_codegen = rule(
  _go_oapi_codegen_impl,
  attrs = {
    "source": attr.label(
      mandatory = True,
      allow_single_file = True,
    ),
    "out": attr.output(
      mandatory = True,
    ),
    "generate": attr.string_list(
      mandatory = False,
    ),
    "package": attr.string(

    ),
    "codegen_tool": attr.label(
      default = OAPI_CODEGEN_TOOL,
      allow_single_file = True,
      executable = True,
      cfg = "exec",
      mandatory = False,
    ),
    "_go_context_data": attr.label(
      default = "@rules_go//:go_context_data",
    ),
  },
  toolchains = [GO_TOOLCHAIN],
)

invoke this like so:

load("//bzl/oapi_codegen:defs.bzl", "go_oapi_codegen")

go_oapi_codegen(
    name = "client_gen",
    out = "client.gen.go",
    generate = [
        "models",
        "client",
    ],
    package = "client",
    source = "//backend/openapi:openapi_json",
)

[Zemnmez]

this is my super rough undocumented rule that I use to do this at $work:

load("@rules_go//go/private:context.bzl", "go_context")
load("@rules_go//go/private:providers.bzl", "GoInfo")

GO_TOOLCHAIN = Label("@rules_go//go:toolchain")
OAPI_CODEGEN_TOOL = Label("@com_github_oapi_codegen_oapi_codegen_v2//cmd/oapi-codegen:oapi-codegen")

def _go_oapi_codegen_impl(ctx):
  go = go_context(ctx, include_deprecated_properties = False)
  sdk = go.sdk

  inputs_direct = [ctx.file.source]
  inputs_transitive = [sdk.tools, sdk.headers, sdk.srcs]

  args = []
  args += ["-package", ctx.attr.package]
  args += ["-generate", ",".join(ctx.attr.generate)]
  args += [ctx.file.source.path]

  ctx.actions.run_shell(
    outputs = [ctx.outputs.out],
    inputs = depset(inputs_direct, transitive = inputs_transitive),
    tools = [
      ctx.file.codegen_tool,
      sdk.go,
    ],
    toolchain = GO_TOOLCHAIN,
    command = """
      export GOROOT=$(pwd)/{goroot} &&
      export PATH=$GOROOT/bin:$PATH &&
      {cmd} {args} > {out}
    """.format(
      goroot = sdk.root_file.dirname,
      cmd = "$(pwd)/" + ctx.file.codegen_tool.path,
      args = " ".join(args),
      out = ctx.outputs.out.path,
      mnemonic = "GoOpenApiSourceGen",
    )
  )

go_oapi_codegen = rule(
  _go_oapi_codegen_impl,
  attrs = {
    "source": attr.label(
      mandatory = True,
      allow_single_file = True,
    ),
    "out": attr.output(
      mandatory = True,
    ),
    "generate": attr.string_list(
      mandatory = False,
    ),
    "package": attr.string(

    ),
    "codegen_tool": attr.label(
      default = OAPI_CODEGEN_TOOL,
      allow_single_file = True,
      executable = True,
      cfg = "exec",
      mandatory = False,
    ),
    "_go_context_data": attr.label(
      default = "@rules_go//:go_context_data",
    ),
  },
  toolchains = [GO_TOOLCHAIN],
)

invoke this like so:

load("//bzl/oapi_codegen:defs.bzl", "go_oapi_codegen")

go_oapi_codegen(
    name = "client_gen",
    out = "client.gen.go",
    generate = [
        "models",
        "client",
    ],
    package = "client",
    source = "//backend/openapi:openapi_json",
)

This worked extremely well. Thank you.