feat(multi-treasury): add RNSCommission contract and all related scripts (#222)

Author: tringuyenskymavis

script/20242406-migrate-auction-controller-treasury-and-deploy-rns-commission/20240624_MigrateAuctionAndControllerTreasuryAndDeployRNSCommission.s.sol

@@ -0,0 +1,74 @@
+// SPDX-License-Identifier: MIT
+pragma solidity ^0.8.19;
+
+import { RNSAuction, RNSAuctionDeploy } from "script/contracts/RNSAuctionDeploy.s.sol";
+import {
+  RONRegistrarController, RONRegistrarControllerDeploy
+} from "script/contracts/RONRegistrarControllerDeploy.s.sol";
+import { Contract } from "script/utils/Contract.sol";
+import { RNSCommission, RNSCommissionDeploy } from "script/contracts/RNSCommissionDeploy.s.sol";
+import { Migration } from "script/Migration.s.sol";
+
+contract Migration__20240624_MigrateAuctionAndControllerTreasuryAndDeployRNSCommission is Migration {
+  RNSAuction private _auction;
+  RONRegistrarController private _controller;
+  RNSCommission private _rnsCommission;
+  address private _defaultAdmin;
+
+  function run() public {
+    _controller = RONRegistrarController(loadContract(Contract.RONRegistrarController.key()));
+    _auction = RNSAuction(loadContract(Contract.RNSAuction.key()));
+
+    _rnsCommission = new RNSCommissionDeploy().run();
+    _defaultAdmin = 0x968D0Cd7343f711216817E617d3f92a23dC91c07;
+
+    vm.startBroadcast(_defaultAdmin);
+
+    _controller.setTreasury(payable(address(_rnsCommission)));
+    _auction.setTreasury(payable(address(_rnsCommission)));
+
+    vm.stopBroadcast();
+  }
+
+  function _postCheck() internal override {
+    _validateSendMoneyFromSenders();
+    _validateTreasuryAddress();
+    _validateCommissionInfo();
+  }
+
+  function _validateTreasuryAddress() internal logFn("_validateTreasuryAddress") {
+    address auctionTreasury = _auction.getTreasury();
+    address controllerTreasury = _controller.getTreasury();
+
+    assertEq(auctionTreasury, payable(address(_rnsCommission)));
+    assertEq(controllerTreasury, payable(address(_rnsCommission)));
+  }
+
+  function _validateCommissionInfo() internal logFn("_validateSetCommissionInfo") {
+    RNSCommission.Commission[] memory newCommission = new RNSCommission.Commission[](1);
+    newCommission[0].recipient = payable(makeAddr("Random"));
+    newCommission[0].ratio = 100_00;
+    newCommission[0].name = "Random";
+
+    vm.prank(_defaultAdmin);
+    _rnsCommission.setCommissions(newCommission);
+
+    assertEq(_rnsCommission.getCommissions().length, 1);
+    assertEq(_rnsCommission.getCommissions()[0].recipient, newCommission[0].recipient);
+  }
+
+  function _validateSendMoneyFromSenders() internal logFn("_validateSendMoneyFailFromSenders") {
+    vm.prank(address(_auction));
+    address(_rnsCommission).call{ value: 100 ether }("");
+
+    vm.prank(address(_controller));
+    address(_rnsCommission).call{ value: 100 ether }("");
+
+    assertEq(address(_rnsCommission).balance, 0 ether);
+
+    vm.prank(_defaultAdmin);
+    address(_rnsCommission).call{ value: 100 ether }("");
+
+    assertEq(address(_rnsCommission).balance, 100 ether);
+  }
+}

script/GeneralConfig.sol

@@ -17,6 +17,7 @@ contract GeneralConfig is BaseGeneralConfig {
     _mapContractName(Contract.OwnedMulticaller);
     _mapContractName(Contract.RNSReverseRegistrar);
     _mapContractName(Contract.RONRegistrarController);
+    _mapContractName(Contract.RNSCommission);
   }
 
   function _mapContractName(Contract contractEnum) internal {

script/Migration.s.sol

@@ -71,6 +71,22 @@ abstract contract Migration is BaseMigration {
       param.rnsUnified.protectedSettler = defaultAdmin;
       param.rnsUnified.gracePeriod = 90 days;
       param.rnsUnified.baseTokenURI = "https://metadata-rns.skymavis.one/saigon/";
+
+      // RNSCommission
+      param.rnsCommission.admin = defaultAdmin;
+      param.rnsCommission.commissionSetters = new address[](1);
+      param.rnsCommission.commissionSetters[0] = defaultAdmin;
+
+      param.rnsCommission.allowedSenders = new address[](2);
+
+      param.rnsCommission.treasuryCommission = new INSCommission.Commission[](2);
+      param.rnsCommission.treasuryCommission[0].recipient = payable(defaultAdmin);
+      param.rnsCommission.treasuryCommission[0].ratio = 70_00;
+      param.rnsCommission.treasuryCommission[0].name = "Sky Mavis";
+
+      param.rnsCommission.treasuryCommission[1].recipient = payable(defaultAdmin);
+      param.rnsCommission.treasuryCommission[1].ratio = 30_00;
+      param.rnsCommission.treasuryCommission[1].name = "Ronin";
     } else if (network() == DefaultNetwork.RoninMainnet.key()) {
       address duke = 0x0F68eDBE14C8f68481771016d7E2871d6a35DE11;
       address andy = 0xEd4A9F48a62Fb6FdcfB45Bb00C9f61D1A436E58C;

script/contracts/RNSCommissionDeploy.s.sol

@@ -0,0 +1,29 @@
+// SPDX-License-Identifier: MIT
+pragma solidity ^0.8.19;
+
+import { RNSCommission } from "@rns-contracts/RNSCommission.sol";
+import { ISharedArgument, Migration } from "script/Migration.s.sol";
+import { Contract } from "script/utils/Contract.sol";
+import { RONRegistrarController, RONRegistrarControllerDeploy } from "./RONRegistrarControllerDeploy.s.sol";
+import { Contract } from "script/utils/Contract.sol";
+import { RNSAuction, RNSAuctionDeploy } from "./RNSAuctionDeploy.s.sol";
+
+contract RNSCommissionDeploy is Migration {
+  function _defaultArguments() internal virtual override returns (bytes memory args) {
+    ISharedArgument.RNSCommissionParam memory param = config.sharedArguments().rnsCommission;
+    address[] memory allowedSenders;
+    allowedSenders = new address[](2);
+    allowedSenders[0] = param.allowedSenders[0] == address(0)
+      ? address(RNSAuction(loadContract(Contract.RNSAuction.key())))
+      : param.allowedSenders[0];
+    allowedSenders[1] = param.allowedSenders[1] == address(0)
+      ? address(RONRegistrarController(loadContract(Contract.RONRegistrarController.key())))
+      : param.allowedSenders[1];
+
+    args = abi.encodeCall(RNSCommission.initialize, (param.admin, param.treasuryCommission, allowedSenders));
+  }
+
+  function run() public virtual returns (RNSCommission) {
+    return RNSCommission(_deployProxy(Contract.RNSCommission.key()));
+  }
+}

script/interfaces/ISharedArgument.sol

@@ -11,6 +11,7 @@ import { RNSUnified } from "@rns-contracts/RNSUnified.sol";
 import { RNSDomainPrice } from "@rns-contracts/RNSDomainPrice.sol";
 import { RNSOperation } from "@rns-contracts/utils/RNSOperation.sol";
 import { OwnedMulticaller } from "@rns-contracts/utils/OwnedMulticaller.sol";
+import { RNSCommission, INSCommission } from "@rns-contracts/RNSCommission.sol";
 
 interface ISharedArgument is IGeneralConfig {
   struct NameCheckerParam {
@@ -86,6 +87,13 @@ interface ISharedArgument is IGeneralConfig {
     RNSReverseRegistrar rnsReverseRegistrar;
   }
 
+  struct RNSCommissionParam {
+    address admin;
+    address[] commissionSetters;
+    INSCommission.Commission[] treasuryCommission;
+    address[] allowedSenders;
+  }
+
   struct SharedParameter {
     NameCheckerParam nameChecker;
     OwnedMulticallerParam ownedMulticaller;
@@ -96,6 +104,7 @@ interface ISharedArgument is IGeneralConfig {
     RNSReverseRegistrarParam rnsReverseRegistrar;
     RNSUnifiedParam rnsUnified;
     RONRegistrarControllerParam ronRegistrarController;
+    RNSCommissionParam rnsCommission;
   }
 
   function sharedArguments() external view returns (SharedParameter memory param);

script/utils/Contract.sol

@@ -13,7 +13,8 @@ enum Contract {
   PublicResolver,
   OwnedMulticaller,
   RNSReverseRegistrar,
-  RONRegistrarController
+  RONRegistrarController,
+  RNSCommission
 }
 
 using { key, name } for Contract global;
@@ -32,5 +33,6 @@ function name(Contract contractEnum) pure returns (string memory) {
   if (contractEnum == Contract.OwnedMulticaller) return "OwnedMulticaller";
   if (contractEnum == Contract.RNSReverseRegistrar) return "RNSReverseRegistrar";
   if (contractEnum == Contract.RONRegistrarController) return "RONRegistrarController";
+  if (contractEnum == Contract.RNSCommission) return "RNSCommission";
   revert("Contract: Unknown contract");
 }

src/RNSCommission.sol

@@ -0,0 +1,120 @@
+// SPDX-License-Identifier: MIT
+pragma solidity ^0.8.19;
+
+import { Initializable } from "@openzeppelin/contracts/proxy/utils/Initializable.sol";
+import { AccessControlEnumerable } from "@openzeppelin/contracts/access/AccessControlEnumerable.sol";
+import { INSCommission } from "./interfaces/INSCommission.sol";
+import { RONTransferHelper } from "./libraries/transfers/RONTransferHelper.sol";
+
+contract RNSCommission is Initializable, AccessControlEnumerable, INSCommission {
+  /// @dev Constant representing the maximum percentage value (100%).
+  uint256 public constant MAX_PERCENTAGE = 100_00;
+  /// @dev Role for accounts that can send RON for this contract.
+  bytes32 public constant SENDER_ROLE = keccak256("SENDER_ROLE");
+
+  /// @dev Gap for upgradability.
+  uint256[50] private ____gap;
+  /// @dev Array of `Commission` structs that store commissions infomation.
+  Commission[] internal _commissionInfos;
+
+  constructor() {
+    _disableInitializers();
+  }
+
+  receive() external payable {
+    _fallback();
+  }
+
+  function initialize(address admin, Commission[] calldata commissionInfos, address[] calldata allowedSenders)
+    external
+    initializer
+  {
+    _setupRole(DEFAULT_ADMIN_ROLE, admin);
+
+    uint256 length = allowedSenders.length;
+    for (uint256 i; i < length; ++i) {
+      _setupRole(SENDER_ROLE, allowedSenders[i]);
+    }
+
+    _setCommissions(commissionInfos);
+  }
+
+  /// @inheritdoc INSCommission
+  function getCommissions() external view returns (Commission[] memory commissionInfos) {
+    return _commissionInfos;
+  }
+
+  /// @inheritdoc INSCommission
+  function setCommissions(Commission[] calldata commissionInfos) external onlyRole(DEFAULT_ADMIN_ROLE) {
+    _setCommissions(commissionInfos);
+  }
+
+  /// @inheritdoc INSCommission
+  function setCommissionInfo(uint256 commissionIdx, address payable newRecipient, string calldata newName)
+    external
+    onlyRole(DEFAULT_ADMIN_ROLE)
+  {
+    if (commissionIdx >= _commissionInfos.length) revert InvalidArrayLength();
+
+    _commissionInfos[commissionIdx].recipient = newRecipient;
+    _commissionInfos[commissionIdx].name = newName;
+    emit CommissionInfoUpdated(msg.sender, commissionIdx, newRecipient, newName);
+  }
+
+  /**
+   * @dev Helper method to allocate commission and take fee into recipient address.
+   */
+  function _allocateCommissionAndTransferToRecipient(uint256 ronAmount) internal {
+    if (ronAmount == 0) revert InvalidAmountOfRON();
+
+    uint256 length = _commissionInfos.length;
+    if (length == 0) revert InvalidArrayLength();
+
+    uint256 lastIdx = length - 1;
+    uint256 sumValue;
+
+    for (uint256 i; i < lastIdx; ++i) {
+      uint256 commissionAmount = _computePercentage(ronAmount, _commissionInfos[i].ratio);
+      sumValue += commissionAmount;
+
+      RONTransferHelper.safeTransfer(_commissionInfos[i].recipient, commissionAmount);
+      emit Distributed(_commissionInfos[i].recipient, commissionAmount);
+    }
+
+    // This code send the remaining RON to the last recipient.
+    if (sumValue < ronAmount) {
+      RONTransferHelper.safeTransfer(_commissionInfos[lastIdx].recipient, ronAmount - sumValue);
+      emit Distributed(_commissionInfos[lastIdx].recipient, ronAmount - sumValue);
+    }
+  }
+
+  function _setCommissions(Commission[] calldata commissionInfos) internal {
+    uint256 length = commissionInfos.length;
+    // commissionInfos[] can not be empty
+    if (length == 0) revert InvalidArrayLength();
+
+    delete _commissionInfos;
+
+    uint256 sum;
+
+    for (uint256 i; i < length; ++i) {
+      sum += commissionInfos[i].ratio;
+      _commissionInfos.push(commissionInfos[i]);
+    }
+
+    if (sum != MAX_PERCENTAGE) revert InvalidRatio();
+
+    emit CommissionsUpdated(msg.sender, commissionInfos);
+  }
+
+  // Calculate amount of money based on commission's ratio
+  function _computePercentage(uint256 value, uint256 percentage) internal pure virtual returns (uint256) {
+    return (value * percentage) / MAX_PERCENTAGE;
+  }
+
+  function _fallback() internal {
+    if (hasRole(SENDER_ROLE, msg.sender)) {
+      _allocateCommissionAndTransferToRecipient(msg.value);
+    }
+  }
+}

src/interfaces/INSCommission.sol

@@ -0,0 +1,60 @@
+// SPDX-License-Identifier: MIT
+pragma solidity ^0.8.19;
+
+interface INSCommission {
+  struct Commission {
+    address payable recipient;
+    uint256 ratio; // Values [0; 100_00] reflexes [0; 100%]
+    string name; // Commission's name
+  }
+
+  /// @dev Emitted when all the commission info is updated.
+  event CommissionsUpdated(address indexed updatedBy, Commission[] commissionInfos);
+  /// @dev Emitted when specific commission info is updated.
+  event CommissionInfoUpdated(
+    address indexed updatedBy, uint256 indexed commissionIdx, address payable newRecipient, string newName
+  );
+  /// @dev Emiited when transfer RON to commission's recipient.
+  event Distributed(address indexed recipient, uint256 commissionAmount);
+
+  /// @dev Revert when index is out of range
+  error InvalidArrayLength();
+  /// @dev Revert when ratio is invalid
+  error InvalidRatio();
+  /// @dev Revert when amount of RON is invalid
+  error InvalidAmountOfRON();
+
+  /**
+   * @dev Maximum commission percentage.
+   */
+  function MAX_PERCENTAGE() external pure returns (uint256);
+
+  /**
+   * @dev Returns the sender role.
+   */
+  function SENDER_ROLE() external pure returns (bytes32);
+
+  /**
+   * @dev Returns comissions information.
+   */
+  function getCommissions() external view returns (Commission[] memory commissionInfos);
+
+  /**
+   * @dev Sets all commission information
+   *
+   * Requirements:
+   * - The method caller is setter role.
+   * - The total ratio must be equal to 100%.
+   * Emits the event `CommissionsUpdated`.
+   */
+  function setCommissions(Commission[] calldata commissionInfos) external;
+
+  /**
+   * @dev Sets for specific commission information based on the `commissionIdx`.
+   *
+   * Requirements:
+   * - The method caller is setter role.
+   * Emits the event `CommissionInfoUpdated`.
+   */
+  function setCommissionInfo(uint256 commissionIdx, address payable newAddr, string calldata name) external;
+}