dot_setup

#!/usr/bin/env perl

=head1 NAME

dot_setup

=head1 DESCRIPTION

Create symlinks in home directory to files in directory which contains this
script.  Symlink names will be same as the target name, but with a C<.>
prepended.

Files to be linked to are listed as command line arguments.  If the name
C<USUAL> is given as an argument, that file in the target directory will be
opened, and each line in it will be added to the files specified on the command
line.

=cut

use strict;
use warnings;
use File::Compare;

my $use_exit = 0;
my $merge = 0;
my $home = $ENV{HOME};

# Get location of files from script location
my $src = $0;
# Convert relative path to absolute
$src = "$ENV{PWD}/$src" unless $src =~ m{^/};
# Eliminate useless references to "." directory
1 while $src =~ s{/\./}{/};
# Eliminate uses of ".."
1 while $src =~ s{/[^/]+/\.\./}{/};
# Remove script filename to get just dir name
$src =~ s{/[^/]+$}{};
# Copy of absolute for opening USUAL file
my $source = $src;
# Convert to being relative to home
$src =~ s{^$home/?}{};

my $added = 0;
my $conflicts = 0;
foreach my $f (@ARGV) {
	chomp $f;
	next if $f =~ /dot_setup/; # Never link this script

	if ($f eq '-m') { $merge = 1; next; }

	if ($f eq '-e') {
		$use_exit = 1;
		next;
	}

	# IF "USUAL" is used as name to link, actually each line in that file as a name to link
	if( $f =~ /USUAL/ ) {
		open USUAL, '<', "$source/$f" or die "Couldn't open '$source/$f': $!\n";
		push @ARGV, <USUAL>;
		close USUAL;
		next;
	}

	my $dest = ".$f"; # Name of link to use, relative to home directory
	$dest =~ s{/$}{}; # Remove trailing slash to avoid creating an empty directory where we want a symlink.

	# If the link is supposed to be in a subdirectory:
	# * Make sure the parent directories exist
	# * Adjust the symlink to go up to home before pointing to target
	my $parents = "";
	my $dirs = "";
	while( $dest =~ m{([^/]+/)}g ) {
		$dirs .= $1;
		$parents .= "../";
		unless ( -d "$home/$dirs" ) {
			mkdir "$home/$dirs" or die;
		}
	}

	$dest = "$ENV{HOME}/$dest"; # Convert destination to absolute path

	# Indicate what targets already exist and which are going to be created
	my $target = "$parents$src/$f";
	my $status = '!';
	if ( -l $dest ) {
		$status = '.' if readlink($dest) eq $target;
	}
	else {
		$status = '+' unless -e $dest;
	}

	if ($status eq '!') {
		foreach my $try (1,2) {
			if (compare($dest, $f)) {
				system "vimdiff", $dest, $f if $try == $merge;
			}
			else {
				$status = '=';
				last;
			}
		}
	}

	my $add = $status =~ /^[+=]$/;
	$added++ if $add;
	$conflicts++ if $status eq '!';

	print "$status $f\n";
	next unless $add;

	unlink $dest if $status eq '=';
	symlink $target => $dest or die "Couldn't create link $dest: $!";
}

if ($use_exit) {
	exit 2 if $conflicts;
	exit 1 if $added;
}