DPM8600 Programmable PowerSupply

[SolarAux]

I have a small solar system (balcony solar) which is equipped with a battery . So that I can regulate the feed-in power, a programmable power supply (DPM8600) is connected between the inverter and the battery. This I would now like to control depending on the current demand. DPM8600 have a very simple serial protocol. I tried to get it running with a script similar to OBIS.
Here is my script:

D
B
->sensor53 r
M 1
+1,3,o,0,9600,Power
1,:01r33=0,@1,Temperature,C,PS_Temp,0
1,:01r00=0,@1000,Volt,V,PS_Volt,0
1,:01r01=0,@1000,Ampere,A,PS_Amp,0
1,:01r12=0,@1,ONOFF,,PS_OnOff,0

Unfortunately I don't get any response from the DPM8600. Has anyone been able to get this to work or can help me?

[radiergimmy]

I'm using this for my DPM8624

>D
Vmax=60 ;max value from specifications https://joy-it.net/en/products/JT-DPM8624
Cmax=24 ;max value from specifications https://joy-it.net/en/products/JT-DPM8624
v=0 ;store device voltage state (targeted)
V=0 ;store WebUI voltage state (targeted)
c=0 ;store device current state (targeted)
C=0 ;store WebUI current state (targeted)
sw=0 ;store device switch state
SW=0 ;store WebUI switch state
rV="01060000" ;ModBus register (voltage)
vV="" ;store hex value of V to append to rV
rC="01060001" ;ModBus register (current)
vC="" ;store hex value of C to append to rC
rSW="01060002000" ;ModBus register (switch)
vSW="" ;store hex value of SW to append to rSW

>B
smlj=0 ;disable publishing at MQTT teleperiod, on boot
->sensor53 r

>R
smlj=0 ;disable publishing at MQTT teleperiod, on reboot

>S
if upsecs>30
then
smlj=1 ;re-enable publishing at MQTT teleperiod, after boot
endif

>W
bu(SW "DPM ON" "DPM OFF") ;toggle switch via WebUI
nm(0.0 60.0 0.01 V "DPM out (V)" 200 2) ;set voltage output via WebUI
nm(0.0 24.0 0.01 C "DPM out (A)" 200 2) ;set current output via WebUI

>T
sw=DC#sSwitch ;load switch state from ModBus variable >M
v=DC#sVolt ;load voltage state from ModBus variable >M
c=DC#sCur ;load voltage state from ModBus variable >M

if ((chg[sw]>0) and (SW!=sw)) ;update WebUI based on physical input (switch)
then
  SW=sw
endif

if ((chg[v]>0) and (V!=v)) ;update WebUI based on physical input (voltage)
then
  V=v
endif

if ((chg[c]>0) and (C!=c)) ;update WebUI based on physical input (current)
then
  C=c
endif

if chg[V]>0 ;update ModBus register based on WebUI input (voltage)
then
  if V>Vmax ;prevent out of bound value (voltage max)
  then
    V=Vmax
  endif
  if V<0 ;prevent out of bound value (voltage min)
  then
    V=0
  endif
  vV=rV+sb(hx((V*100)) 4 4)
  sml(1 3 vV)
endif

if chg[C]>0 ;update ModBus register based on WebUI input (current)
then
  if C>Cmax ;prevent out of bound value (current max)
  then
    C=Cmax ;prevent out of bound value (current min)
  endif
  if C<0
  then
    C=0
  endif
  vC=rC+sb(hx((C*1000)) 4 4)
  sml(1 3 vC)
endif

if ((chg[SW]>0) and (sw!=SW) ;update ModBus register based on WebUI input (switch)
then
  vSW=rSW+s(SW)
  sml(1 3 vSW)
endif

>M 1
+1,4,m,16,9600,DC,5,2,010300000001,010300010001,010300020001,010310010001,010310020001 ;ModBus register taken from JT-DPM86XX_Communication_protocol_2022-07-06.pdf provided by Joy-IT
1,010302SSssxxxx@i1:100,Voltage (set),V,sVolt,2
1,010302SSssxxxx@i2:1000,Current (set),A,sCur,2
1,010302SSssxxxx@i3:1,Switch (set),,sSwitch,0
1,010302SSssxxxx@i4:100,Voltage (disp),V,dVolt,2
1,010302SSssxxxx@i5:1000,Current (disp),A,vCur,2
#

[radiergimmy]

I'm using the following TTL-RS485 adapter and connected RX->GPIO4/D2, TX->GPIO5/D1 on my Wemos D1 (ESP8266):
https://www.amazon.de/gp/product/B08XLT21S6

[io-taster]

Hello radiergimmy,

i have tried your code on a esp32 with tasmota scripting. I dont have use any adapeter under configure modul i use GPIO 1 serbr tx and GPIO 3 serbr rx. On DPM8624 under 5 i use 1. And it works.
THX for your good Job!

[timm3012]

Hello
the solution from @io-taster seems to work for setting the values, but I don't see the current values.
How did you manage to declare more than five strings? As soon as I do it, I get an error. As far as I know, it's a known limitation of Tasmota Script!? The documentations says, that there is (maybe) a #DEFINE template to solve this. Do you have a solution @radiergimmy ?

[radiergimmy]

This depends on the memory size of your ESP chip. I'm using a Wemos D1 which has enough memory to store the code.
I've also compiled a custom Tasmota firmware by using the tasmocompiler: https://github.com/benzino77/tasmocompiler

Version: 12.1.0

#define USE_WEBSERVER
#define USE_SCRIPT
#define USE_SCRIPT_WEB_DISPLAY
#define USE_SML_M
#define USE_SML_SCRIPT_CMD

[io-taster]

Hello,
can you Compile me a tasmota bin for ESP32 with
#define USE_WEBSERVER
#define USE_SCRIPT
#define USE_SCRIPT_WEB_DISPLAY
#define USE_SML_M
#define USE_SML_SCRIPT_CMD

With benzino i have got a lot off errors

Thanks
Frank

[timm3012]

I'm using a ESP32 and used exactly the defines you mentioned. I still don't get it working with more than five strings. I'm using Visual Studio Code with PlatformIO.

[io-taster]

Can you Post me your bin?

[Gerri1]

@radiergimmy
Hello, does the script also run on an ESP8266 with Tasmota - Scripting?
In the Tasmota main view, nothing is displayed on mine!

[radiergimmy]

Yes, the script is running on a Wemos D1 mini with Tasmota scripting

[io-taster]

Hello,

can you describe us the structure of your plant? How do you record the consumption at the electricity meter? Who controls the values from the DPM8600? The Wemos D1 or a Raspberry Pi with iobroker? It would be nice if you could explain the setup in more detail.

Many greetings
Frank

[radiergimmy]

The overall power consumption is recorded via the Volkszaehler by Hichi, which like all other devices sends the data via MQTT.
The DPM itself along with an EPEver charge controller are connected to ~48V battery pack.
The EPEver is used for charging the battery pack by using the power of 4x ~400W solar panels.
The DPM is then used to discharge the battery pack by connecting it to an DC/AC microinverter.

Whole idea is based on https://youtu.be/yOcoux9IbzM
(video in German language).

Having everything connected via MQTT makes it independent from a specific management solution.

[io-taster]

With tasmota scripting can i set v and c over the Browser.
But i become no answer from DPM8600 .
Have you any idea?

[Gerri1]

@radiergimmy
In Visual Studio Code I had to enter the script like this because I got several compilation errors!

#ifndef USE_WEBSERVER
#define USE_WEBSERVER
#endif
#ifndef USE_SCRIPT
#define USE_SCRIPT
#endif
#ifndef USE_SCRIPT_WEB_DISPLAY
#define USE_SCRIPT_WEB_DISPLAY
#endif
#ifndef USE_SML_M
#define USE_SML_M
#endif
#ifndef USE_SML_SCRIPT_CMD
#define USE_SML_SCRIPT_CMD
#endif
#ifdef USE_RULES
#undef USE_RULES
#endif

It still doesn't show anything on the Tasmota main page. I can't really test it until I get the DPM8624. But normally the display should at least appear with zeros!

[timm3012]

It's working now. My TTL to RS485 converter was defective...

I had to do make a little change in the meter metrics to get the values displayed correct (count from 0 to 4):
>M 1 +1,4,m,16,9600,DC,5,2,010300000001,010300010001,010300020001,010310010001,010310020001 ;ModBus register taken from JT-DPM86XX_Communication_protocol_2022-07-06.pdf provided by Joy-IT 1,010302SSssxxxx@i0:100,Voltage (set),V,sVolt,2 1,010302SSssxxxx@i1:1000,Current (set),A,sCur,2 1,010302SSssxxxx@i2:1,Switch (set),,sSwitch,0 1,010302SSssxxxx@i3:100,Voltage (disp),V,dVolt,2 1,010302SSssxxxx@i4:1000,Current (disp),A,vCur,2 #

[Gerri1]

Hello,
I've been trying to find out why the script isn't running.
Under ">D" (declarations) I had commented out the last variable (vSW="" ;store hex value of SW to append to rSW) for testing and there were no more error messages! Apparently the ESP8266 can't handle more string variables!
Would that then run on an ESP32, or is there another way to solve the problem?
I found something else that must be the problem!

Up to 50 variables (45 numeric and 5 strings - this may be changed by setting a compilation #define directive)

[Gerri1]

I have now received my DPM8624. The values are also displayed in the Tasmota, but only partially in the ioBroker. The two values of voltage and current (display) remain zero, and you cannot change any values from the ioBroker!
@radiergimmy Do you have a solution?

[io-taster]

Hello Gerri,

I can help you with iobroker.
Do you use Tasmota scripting?
Is it an Esp 8266 or Esp32?
I think the easiest thing would be to make a phone call.
Send me your phone number by email: [email protected]
We should get this working together.

[Gerri1]

I think the problem is with the Tasmota firmware and not with the ioBroker!

[STE2k]

Hallo Ihr! I ve got the same problem. But I´m using NODE-Red. On the Tasmota-WebGUI everything works, (setting, reading) in console SENSORS show up also. But I dont know how to publish Current (sCur) or Voltage via MQTT.
I tried to use an inject to test and connected to a MQTT-Out with same topic (tasmota_BE0C80/SENSOR)

I have no clue in programming, maybe someone can help me. Or it is not possible to publish because on a subscribe topic it does not work?

[io-taster]

Hello ,

I can help you with iobroker.
Do you use Tasmota scripting?
Is it an Esp 8266 or Esp32?
I think the easiest thing would be to make a phone call.
Send me your phone number by email: [email protected]
We should get this working together.

[STE2k]

If anyone has an answer plz write in here, thx.

[STE2k]

Look at the screenshot of Gerri1. You can change Volt and Ampere and put the switch on and off. It is set directly after pressing enter.

[Gerri1]

Setting the values and displaying them on the Tasmota main page works "almost" well! Setting the values via the ioBroker (Sonoff Adapter) does not work at all. I can't try the MQTT adapter until the weekend. Tasmota recognizes what matters, but can't do anything with it! The connection via an RS485 - WLAN adapter, on the other hand, works perfectly!

[Gerri1]

You may have to change or add the register addresses to "06 Write a single register"!

[STE2k]

thats a good point, but how to set it via node-red

[barbudor]

ok so you will need to modify the script quite a bit because there is nothing already included in that script to receive new values from MQTT.
Scripting-Language is not my best skill so I can give some hints but that mostly all I can do

You will need to use that option (may erquires you to recompile Tasmota with that #define

USE_SCRIPT_SUB_COMMAND | enables invoking named script subroutines via the Console or MQTT

which will allow you to create new tasmota commands that will call a subroutine

That will allow you to create 2 subroutines:
#SETSCUR(c)
#SETSVOLT(v)
And you can call those routines by publishing from Node-RED to cmnd/tasmota_BE0C80/SETSCUR and cmnd/tasmota_BE0C80/SETSVOLT providing the target value as the payload of the MQTT message.
Your subroutine would then be called with the argument (cur/volt) set to the payload value
You then have to report the value into the Web page
I believe the following code would just do that

#SETSCUR(c)
C=c

#SETSVOLT(v)
V=v

Now what I'm unsure is what you need to do to have the value sent to the DPM device itself
It looks like this is this part of hte script that does it when the data is changed in the UI
So you can probably inspire yourself from that

  vV=rV+sb(hx((V*100)) 4 4)
  sml(1 3 vV)

Also the lines that are above this one that are clamping the values inside the min/max range may also be usefull

I hope this helps
Sorry for not having a ready solution

[Gerri1]

@barbudor
In the user_config_override.h I added the line USE_SCRIPT_SUB_COMMAND and created a .bin.
Under which script sections are the subroutines #SETSCUR(c)
and #SETSVOLT(v) inserted (e.g. >T) ?
Where are the lines marked in the following image inserted? I don't get anything from the ioBroker!

[STE2k]

anything new? Gerri1 do you have MQTT in -and output from DPM8624 via Script?

[Gerri1]

The DPM works wonderfully from Tasmota and the values are also transmitted to the ioBroker via MQTT. The problem is that I don't set the values for U / I / Switch in ioBroker or get them to Tasmota (DPM)!

[STE2k]

Yes, we need someone to do this mqtt in and out in script :) because of your comment with write and read registers I thought you already programmed this

[Gerri1]

I think the problem is with Tasmota (in the script). The transfer from ioBroker to Tasmota works, but according to the console, Tasmota can't do anything with it because it doesn't seem to know the variables from the outside!

[paeonya]

Hi everyone, I am trying to set this up.
I already get the data of power consumption via volkszähler/tasmota/WiFi.
Now I am struggling at the other end. I connected an rs485 to TTL bridge to the DPM and this to an esp8266.
I have absolutely no idea what I am doing because I lack the basics completely.
Does anybody have a hint where to start? I don't know if I connected the two modules correctly and next is I do not know which tasmota version I need (I just flashed the usual binary).
All the tutorials seem to start way beyond my knowledge level and I do not know how to trouble shoot this whole setup.
Merci, paeonya

[barbudor]

You first need to know the protocol for controlling the power supply
Then you would need to write a driver for it as it is unlikely you will manage to handle it with basic Serial Bridge

With esp8266 you have to write such driver in C
If you go for an ESP32 or ESP32c3 you can use the Berry language which could be easier

[Bettman66]

Here's something to test for the Sonoff adapter for ioBroker.
This needs to be added in the Tasmota firmware:

#define USE_SCRIPT_WEB_DISPLAY

#ifndef USE_SCRIPT
#define USE_SCRIPT
#define SUPPORT_MQTT_EVENT
#endif
#ifndef USE_SML_M
#define USE_SML_M
#define USE_SML_SCRIPT_CMD
#endif
#ifdef USE_RULES
#undef USE_RULES
#endif

>D
Vmax=60 ;max value from specifications https://joy-it.net/en/products/JT-DPM8624
Cmax=24 ;max value from specifications https://joy-it.net/en/products/JT-DPM8624
v=0 ;store device voltage state (targeted)
V=0 ;store WebUI voltage state (targeted)
c=0 ;store device current state (targeted)
C=0 ;store WebUI current state (targeted)
sw=0 ;store device switch state
SW=0 ;store WebUI switch state
rV="01060000" ;ModBus register (voltage)
vV="" ;store hex value of V to append to rV
rC="01060001" ;ModBus register (current)
vC="" ;store hex value of C to append to rC
rSW="01060002000" ;ModBus register (switch)
vSW="" ;store hex value of SW to append to rSW

>BS
+>subscribe V, cmnd/%topic%/tvolt
+>subscribe C, cmnd/%topic%/tampere
+>subscribe SW, cmnd/%topic%/tpow

>B
smlj=0 ;disable publishing at MQTT teleperiod, on boot
->sensor53 r

>R
smlj=0 ;disable publishing at MQTT teleperiod, on reboot

>S
if upsecs>30
then
smlj=1 ;re-enable publishing at MQTT teleperiod, after boot
endif

>W
bu(SW "DPM Ein" "DPM Aus") ;toggle switch via WebUI
nm(0.0 60.0 0.01 V "DPM Ausgang (V)" 200 2) ;set voltage output via WebUI
nm(0.0 24.0 0.01 C "DPM Ausgang (A)" 200 2) ;set current output via WebUI

>T
sw=DC#sSwitch ;load switch state from ModBus variable >M
v=DC#sVolt ;load voltage state from ModBus variable >M
c=DC#sCur ;load voltage state from ModBus variable >M


if ((chg[sw]>0) and (SW!=sw)) ;update WebUI based on physical input (switch)
then
  SW=sw
  +>publish stat/%topic%/RESULT {"tpow":%1sw%}
endif

if ((chg[v]>0) and (V!=v)) ;update WebUI based on physical input (voltage)
then
  V=v
  +>publish stat/%topic%/RESULT {"tvolt":%1v%}
endif

if ((chg[c]>0) and (C!=c)) ;update WebUI based on physical input (current)
then
  C=c
  +>publish stat/%topic%/RESULT {"tampere":%1c%}
endif

if chg[V]>0 ;update ModBus register based on WebUI input (voltage)
then
  if V>Vmax ;prevent out of bound value (voltage max)
  then
    V=Vmax
  endif
  if V<0 ;prevent out of bound value (voltage min)
  then
    V=0
  endif
  vV=rV+sb(hx((V*100)) 4 4)
  +>publish stat/%topic%/RESULT {"tvolt":%1V%}
  sml(1 3 vV)
endif

if chg[C]>0 ;update ModBus register based on WebUI input (current)
then
  if C>Cmax ;prevent out of bound value (current max)
  then
    C=Cmax ;prevent out of bound value (current min)
  endif
  if C<0
  then
    C=0
  endif
  vC=rC+sb(hx((C*1000)) 4 4)
  +>publish stat/%topic%/RESULT {"tampere":%1C%}
  sml(1 3 vC)
endif

if ((chg[SW]>0) and (sw!=SW) ;update ModBus register based on WebUI input (switch)
then
  vSW=rSW+s(SW)
  +>publish stat/%topic%/RESULT {"tpow":%1SW%}
  sml(1 3 vSW)
endif

>M 1
+1,3,m,16,9600,DC,1,2,010300000001,010300010001,010300020001,010310010001,010310020001 ;ModBus register taken from JT-DPM86XX_Communication_protocol_2022-07-06.pdf provided by Joy-IT
1,010302SSssxxxx@i0:100,Spannung (set),V,sVolt,2
1,010302SSssxxxx@i1:1000,Strom (set),A,sCur,2
1,010302SSssxxxx@i2:1,Ausgang (set),,sSwitch,0
1,010302SSssxxxx@i3:100,Spannung (disp),V,dVolt,2
1,010302SSssxxxx@i4:1000,Strom (disp),A,vCur,2
#

[MatheoM85]

Hello everyone first of all,

good work done here so far.

Maybe you can "share" a little more of your experience.

I can already change values via the web interface at Tasmota. But none of the 5 values are displayed in the web interface.
("DC voltage (set)" etc...
Do you have an idea what could be the reason?

Protocol is changed to ModBus and a RS485-TTL converter to an esp8266 on a NodeMCU board.
COM-Led on the DPM8624 is happily flashing and so is the TXD LED on the RS485 converter board. Only the RXD never flashes.

[Gerri1]

I was able to do everything with my script, except that the input via the ioBroker didn't work!

[Gamalinger]

Hello all,
could somebody help me please?
I get no information from DPM8624 there are only 0 and it is not possible to send some information.
The correct firmware should be installed and the code is inside my Node MCU ESP8266. Everything looks fine but it diplay only 0.
I have other devices connected to NodeRed and the most will be shown by Grafana. Inside NodeRed will be shown only 0 as well.

[nulleinspeisung]

Hi, i am doing the same thing just with the 8650. I have my ir-reader running and connected to a broker (raspi-mosquitto). I dont know how the scripts are working. Has the ir-reader-tasmota-script to send data to broker or is the dpm-tasmota-script already asking for this? Is there a final script for ir-reader? I Just use a simple code for displaying on webui.

[mjpalmowski]

I don't want to hijack this discussion, but for those that are struggeling with the set-up, I have written some very easy to run ESPHome YAML code for this Buck converter, it is for the 50A version, but the code can be adjusted easily. Hardware advice also here: