Merge pull request #1 from jjerphan/chore/cmake-setup

chore: Add a minimal `cmake(1)` setup

Author: JohanMabille

CMakeLists.txt

@@ -1,10 +1,113 @@
-cmake_minimum_required (VERSION 3.26)
+cmake_minimum_required (VERSION 3.16)
 
-project (semimap VERSION 1.0.0)
+project (semimap)
 
-set(CMAKE_CXX_FLAGS_RELEASE -Ofast -march=native)
+set(SEMIMAP_INCLUDE_DIR ${CMAKE_CURRENT_SOURCE_DIR}/include)
 
-add_executable(semimap_test test.cpp)
+# By default, we build in Release mode.
+if(NOT CMAKE_BUILD_TYPE)
+    set(CMAKE_BUILD_TYPE "Release" CACHE STRING "" FORCE)
+endif()
 
-# Set C++ standard for all targets
-set_property(TARGET semimap_test PROPERTY CXX_STANDARD 17)
+# Versioning
+# ==========
+
+file(
+    STRINGS "${SEMIMAP_INCLUDE_DIR}/semimap/semimap.h" semimap_version_defines
+    REGEX "#define SEMIMAP_VERSION_(MAJOR|MINOR|PATCH)"
+)
+
+foreach(ver ${semimap_version_defines})
+    if(ver MATCHES "#define SEMIMAP_VERSION_(MAJOR|MINOR|PATCH) +([^ ]+)$")
+        set(SEMIMAP_VERSION_${CMAKE_MATCH_1} "${CMAKE_MATCH_2}" CACHE INTERNAL "")
+    endif()
+endforeach()
+
+set(
+    ${PROJECT_NAME}_VERSION
+    ${SEMIMAP_VERSION_MAJOR}.${SEMIMAP_VERSION_MINOR}.${SEMIMAP_VERSION_PATCH}
+)
+
+message(STATUS "semimap v${${PROJECT_NAME}_VERSION}")
+
+
+# Build
+# =====
+
+set(
+    SEMIMAP_HEADERS
+    ${SEMIMAP_INCLUDE_DIR}/semimap/semimap.h
+)
+
+add_library(semimap INTERFACE)
+
+target_include_directories(
+    semimap INTERFACE
+    $<BUILD_INTERFACE:${SEMIMAP_INCLUDE_DIR}>
+    $<INSTALL_INTERFACE:include>
+)
+
+set_target_properties(
+    semimap PROPERTIES
+    PUBLIC_HEADER "${SEMIMAP_HEADERS}"
+)
+
+target_compile_features(semimap INTERFACE cxx_std_17)
+
+# TODO: add test suite
+
+
+# Installation
+# ============
+
+include(GNUInstallDirs)
+include(CMakePackageConfigHelpers)
+
+install(
+    TARGETS semimap
+    EXPORT ${PROJECT_NAME}-targets
+    PUBLIC_HEADER DESTINATION ${CMAKE_INSTALL_INCLUDEDIR}/${PROJECT_NAME}
+)
+
+# Makes the project importable from the build directory
+export(
+    EXPORT ${PROJECT_NAME}-targets
+    FILE "${CMAKE_CURRENT_BINARY_DIR}/${PROJECT_NAME}-Targets.cmake"
+)
+
+set(
+    SEMIMAP_CMAKECONFIG_INSTALL_DIR "${CMAKE_INSTALL_LIBDIR}/cmake/${PROJECT_NAME}"
+    CACHE STRING "install path for semimapConfig.cmake"
+)
+
+configure_package_config_file(
+    ${PROJECT_NAME}Config.cmake.in
+    ${CMAKE_CURRENT_BINARY_DIR}/${PROJECT_NAME}Config.cmake
+    INSTALL_DESTINATION ${SEMIMAP_CMAKECONFIG_INSTALL_DIR}
+)
+
+# semimap is header-only and does not depend on the architecture.
+# Remove CMAKE_SIZEOF_VOID_P from semimapConfigVersion.cmake so that an
+# architecture-independent semimapConfig.cmake is generated.
+set(_SEMIMAP_CMAKE_SIZEOF_VOID_P ${CMAKE_SIZEOF_VOID_P})
+unset(CMAKE_SIZEOF_VOID_P)
+
+write_basic_package_version_file(
+    ${CMAKE_CURRENT_BINARY_DIR}/${PROJECT_NAME}ConfigVersion.cmake
+    VERSION ${${PROJECT_NAME}_VERSION}
+    COMPATIBILITY AnyNewerVersion
+    ARCH_INDEPENDENT
+)
+
+set(CMAKE_SIZEOF_VOID_P ${_SEMIMAP_CMAKE_SIZEOF_VOID_P})
+install(
+    FILES
+        ${CMAKE_CURRENT_BINARY_DIR}/${PROJECT_NAME}Config.cmake
+        ${CMAKE_CURRENT_BINARY_DIR}/${PROJECT_NAME}ConfigVersion.cmake
+    DESTINATION ${SEMIMAP_CMAKECONFIG_INSTALL_DIR}
+)
+install(
+    EXPORT ${PROJECT_NAME}-targets
+    FILE ${PROJECT_NAME}Targets.cmake
+    DESTINATION ${SEMIMAP_CMAKECONFIG_INSTALL_DIR}
+)

semimap.h renamed to include/semimap/semimap.h

@@ -72,6 +72,10 @@
   Twitter: @hogliux
 */
 
+#define SEMIMAP_VERSION_MAJOR 1
+#define SEMIMAP_VERSION_MINOR 0
+#define SEMIMAP_VERSION_PATCH 0
+
 #include <cstring>
 #include <memory>
 #include <new>
@@ -386,4 +390,4 @@ class map {
 
 #undef semi_branch_expect
 
-} // namespace semi
+} // namespace semi

semimapConfig.cmake.in

@@ -0,0 +1,14 @@
+# semimap cmake module
+#
+# This module defines the following variables in your project::
+#
+#  SEMIMAP_FOUND - set to true if semimap is found
+#  SEMIMAP_INCLUDE_DIRS - include directories for semimap
+#  SEMIMAP_LIBRARY - empty
+
+@PACKAGE_INIT@
+
+if(NOT TARGET @PROJECT_NAME@)
+    include("${CMAKE_CURRENT_LIST_DIR}/@[email protected]")
+    get_target_property(@PROJECT_NAME@_INCLUDE_DIRS @PROJECT_NAME@ INTERFACE_INCLUDE_DIRECTORIES)
+endif()