lib.systems: introduce cc, bintools, cxxlib, unwinderlib, and rtlib attributes

Author: RossComputerGuy

lib/systems/default.nix

@@ -66,7 +66,11 @@ let
   # `parsed` is inferred from args, both because there are two options with one
   # clearly preferred, and to prevent cycles. A simpler fixed point where the RHS
   # always just used `final.*` would fail on both counts.
-  elaborate = systemOrArgs: let
+  elaborate = systemOrArgs:
+    assert lib.assertMsg (!(lib.oldestSupportedReleaseIsAtLeast 2511 && systemOrArgs ? useLLVM)) "The useLLVM attribute has been deprecated in favor of the toolchain attributes.";
+    assert lib.assertMsg (!(lib.oldestSupportedReleaseIsAtLeast 2511 && systemOrArgs ? useArocc)) "The useArocc attribute has been deprecated in favor of the toolchain attributes.";
+    assert lib.assertMsg (!(lib.oldestSupportedReleaseIsAtLeast 2511 && systemOrArgs ? useZig)) "The useZig attribute has been deprecated in favor of the toolchain attributes.";
+    let
     allArgs = systemToAttrs systemOrArgs;
 
     # Those two will always be derived from "config", if given, so they should NOT
@@ -92,6 +96,21 @@ let
       isCompatible = _: throw "2022-05-23: isCompatible has been removed in favor of canExecute, refer to the 22.11 changelog for details";
       # Derived meta-data
       useLLVM = final.isFreeBSD || final.isOpenBSD;
+      useArocc = false;
+      useZig = false;
+
+      cc = if final.useLLVM || final.isDarwin then "clang"
+        else if final.useArocc then "arocc"
+        else if final.useZig then "zig"
+        else "gcc";
+
+      bintools = if final.useLLVM || final.useArocc || final.useZig || final.isDarwin then
+        "llvm"
+      else "gnu";
+
+      cxxlib =
+        /**/ if final.useLLVM || final.useArocc || final.useZig || final.isDarwin then "libcxx"
+        else "libstdcxx";
 
       libc =
         /**/ if final.isDarwin                then "libSystem"
@@ -112,15 +131,25 @@ let
         else if final.isNone                  then "newlib"
         # TODO(@Ericson2314) think more about other operating systems
         else                                     "native/impure";
+
+      unwinderlib =
+        /**/ if final.useLLVM || final.useArocc || final.useZig then "libunwind"
+        else if final.isDarwin then "libunwind-system"
+        else "libgcc_s";
+
+      rtlib =
+        /**/ if final.useLLVM || final.useArocc || final.useZig || final.isDarwin then "compiler-rt"
+        else "libgcc";
+
       # Choose what linker we wish to use by default. Someday we might also
       # choose the C compiler, runtime library, C++ standard library, etc. in
       # this way, nice and orthogonally, and deprecate `useLLVM`. But due to
       # the monolithic GCC build we cannot actually make those choices
       # independently, so we are just doing `linker` and keeping `useLLVM` for
       # now.
       linker =
-        /**/ if final.useLLVM or false      then "lld"
-        else if final.isDarwin              then "cctools"
+        /**/ if final.useLLVM then "lld"
+        else if final.isDarwin then "cctools"
         # "bfd" and "gold" both come from GNU binutils. The existence of Gold
         # is why we use the more obscure "bfd" and not "binutils" for this
         # choice.

lib/systems/examples.nix

@@ -79,7 +79,7 @@ rec {
     androidNdkVersion = "26";
     libc = "bionic";
     useAndroidPrebuilt = false;
-    useLLVM = true;
+    toolchain = "llvm";
   };
 
   pogoplug4 = {
@@ -330,19 +330,19 @@ rec {
     config = "aarch64-w64-mingw32";
     libc = "ucrt";
     rust.rustcTarget = "aarch64-pc-windows-gnullvm";
-    useLLVM = true;
+    toolchain = "llvm";
   };
 
   # BSDs
 
   aarch64-freebsd = {
     config = "aarch64-unknown-freebsd";
-    useLLVM = true;
+    toolchain = "llvm";
   };
 
   x86_64-freebsd = {
     config = "x86_64-unknown-freebsd";
-    useLLVM = true;
+    toolchain = "llvm";
   };
 
   x86_64-netbsd = {
@@ -352,12 +352,12 @@ rec {
   # this is broken and never worked fully
   x86_64-netbsd-llvm = {
     config = "x86_64-unknown-netbsd";
-    useLLVM = true;
+    toolchain = "llvm";
   };
 
   x86_64-openbsd = {
     config = "x86_64-unknown-openbsd";
-    useLLVM = true;
+    toolchain = "llvm";
   };
 
   #
@@ -366,13 +366,13 @@ rec {
 
   wasi32 = {
     config = "wasm32-unknown-wasi";
-    useLLVM = true;
+    toolchain = "llvm";
   };
 
   wasm32-unknown-none = {
     config = "wasm32-unknown-none";
     rust.rustcTarget = "wasm32-unknown-unknown";
-    useLLVM = true;
+    toolchain = "llvm";
   };
 
   # Ghcjs

pkgs/build-support/cc-wrapper/default.nix

@@ -120,8 +120,8 @@ let
 
   useGccForLibs = useCcForLibs
     && libcxx == null
+    && targetPlatform.rtlib == "libgcc"
     && !targetPlatform.isDarwin
-    && !(targetPlatform.useLLVM or false)
     && !(targetPlatform.useAndroidPrebuilt or false)
     && !(targetPlatform.isiOS or false)
     && gccForLibs != null;
@@ -514,7 +514,7 @@ stdenvNoCC.mkDerivation {
     + optionalString (isClang
                       && targetPlatform.isLinux
                       && !(targetPlatform.useAndroidPrebuilt or false)
-                      && !(targetPlatform.useLLVM or false)
+                      && targetPlatform.rtlib == "libgcc"
                       && gccForLibs != null) (''
       echo "--gcc-toolchain=${gccForLibs}" >> $out/nix-support/cc-cflags
 

pkgs/by-name/al/alsa-lib/package.nix

@@ -25,7 +25,7 @@ stdenv.mkDerivation (finalAttrs: {
       # order to support apps with 32bit sound running on x86_64 architecture.
       ./alsa-plugin-conf-multilib.patch
     ]
-    ++ lib.optional (stdenv.hostPlatform.useLLVM or false)
+    ++ lib.optional (stdenv.hostPlatform.linker == "lld")
       # Fixes version script under LLVM, should be fixed in the next update.
       # Check if "pkgsLLVM.alsa-lib" builds on next version bump and remove this
       # if it succeeds.

pkgs/by-name/cl/cling/package.nix

@@ -27,7 +27,7 @@
 
   # Build with libc++ (LLVM) rather than stdlibc++ (GCC).
   # This is experimental and not all features work.
-  useLLVMLibcxx ? clangStdenv.hostPlatform.isDarwin,
+  useLLVMLibcxx ? clangStdenv.hostPlatform.cxxlib == "libcxx",
 }:
 
 let

pkgs/by-name/cy/cyrus_sasl/package.nix

@@ -74,7 +74,7 @@ stdenv.mkDerivation rec {
       "--enable-shared"
     ]
     ++ lib.optional enableLdap "--with-ldap=${openldap.dev}"
-    ++ lib.optionals (stdenv.targetPlatform.useLLVM or false) [
+    ++ lib.optionals (stdenv.hostPlatform.cc == "clang" && !stdenv.hostPlatform.isDarwin) [
       "--disable-sample"
       "CFLAGS=-DTIME_WITH_SYS_TIME"
     ];

pkgs/by-name/el/elfutils/package.nix

@@ -63,7 +63,7 @@ stdenv.mkDerivation rec {
     ++ lib.optionals stdenv.hostPlatform.isMusl [ ./musl-error_h.patch ]
     # Prevent headers and binaries from colliding which results in an error.
     # https://sourceware.org/pipermail/elfutils-devel/2024q3/007281.html
-    ++ lib.optional (stdenv.targetPlatform.useLLVM or false) ./cxx-header-collision.patch;
+    ++ lib.optional (stdenv.hostPlatform.cxxlib == "libcxx") ./cxx-header-collision.patch;
 
   postPatch =
     ''
@@ -94,7 +94,7 @@ stdenv.mkDerivation rec {
       bzip2
     ]
     ++ lib.optional enableDebuginfod pkg-config
-    ++ lib.optional (stdenv.targetPlatform.useLLVM or false) autoreconfHook;
+    ++ lib.optional (stdenv.hostPlatform.cxxlib == "libcxx") autoreconfHook;
   buildInputs =
     [
       zlib
@@ -128,7 +128,7 @@ stdenv.mkDerivation rec {
       # Versioned symbols are nice to have, but we can do without.
       (lib.enableFeature (!stdenv.hostPlatform.isMicroBlaze) "symbol-versioning")
     ]
-    ++ lib.optional (stdenv.targetPlatform.useLLVM or false) "--disable-demangler"
+    ++ lib.optional (stdenv.hostPlatform.unwinderlib == "libunwind") "--disable-demangler"
     ++ lib.optionals stdenv.cc.isClang [
       "CFLAGS=-Wno-unused-private-field"
       "CXXFLAGS=-Wno-unused-private-field"

pkgs/by-name/ke/kexec-tools/package.nix

@@ -19,13 +19,17 @@ stdenv.mkDerivation rec {
     sha256 = "sha256-Z7GsUDqt5FpU2wvHkiiogwo11dT4PO6TLP8+eoGkqew=";
   };
 
-  patches = [
-    # Use ELFv2 ABI on ppc64be
-    (fetchpatch {
-      url = "https://raw.githubusercontent.com/void-linux/void-packages/6c1192cbf166698932030c2e3de71db1885a572d/srcpkgs/kexec-tools/patches/ppc64-elfv2.patch";
-      sha256 = "19wzfwb0azm932v0vhywv4221818qmlmvdfwpvvpfyw4hjsc2s1l";
-    })
-  ] ++ lib.optional (stdenv.hostPlatform.useLLVM or false) ./fix-purgatory-llvm-libunwind.patch;
+  patches =
+    [
+      # Use ELFv2 ABI on ppc64be
+      (fetchpatch {
+        url = "https://raw.githubusercontent.com/void-linux/void-packages/6c1192cbf166698932030c2e3de71db1885a572d/srcpkgs/kexec-tools/patches/ppc64-elfv2.patch";
+        sha256 = "19wzfwb0azm932v0vhywv4221818qmlmvdfwpvvpfyw4hjsc2s1l";
+      })
+    ]
+    ++ lib.optional (
+      stdenv.hostPlatform.unwinderlib == "libunwind"
+    ) ./fix-purgatory-llvm-libunwind.patch;
 
   hardeningDisable = [
     "format"

pkgs/by-name/li/libseccomp/package.nix

@@ -37,7 +37,7 @@ stdenv.mkDerivation rec {
     util-linuxMinimal
     which
   ];
-  doCheck = !(stdenv.targetPlatform.useLLVM or false);
+  doCheck = stdenv.hostPlatform.cc != "clang";
 
   # Hack to ensure that patchelf --shrink-rpath get rids of a $TMPDIR reference.
   preFixup = "rm -rfv src";

pkgs/by-name/so/sourceHighlight/package.nix

@@ -62,7 +62,7 @@ stdenv.mkDerivation rec {
   nativeBuildInputs = [ updateAutotoolsGnuConfigScriptsHook ];
   buildInputs =
     [ boost ]
-    ++ lib.optional (stdenv.targetPlatform.useLLVM or false) (
+    ++ lib.optional (stdenv.hostPlatform.rtlib == "compiler-rt") (
       llvmPackages.compiler-rt.override {
         doFakeLibgcc = true;
       }
@@ -92,7 +92,7 @@ stdenv.mkDerivation rec {
     maintainers = with maintainers; [ SuperSandro2000 ];
   };
 }
-// lib.optionalAttrs (stdenv.targetPlatform.useLLVM or false) {
+// lib.optionalAttrs (stdenv.targetPlatform.rtlib == "libunwind") {
   # Force linking to "libgcc" so tests pass
   NIX_CFLAGS_COMPILE = "-lgcc";
 }