mashcode/flake.nix at main · Nirlep5252/mashcode · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
{
  inputs = {
    nixpkgs.url = "github:nixos/nixpkgs/nixos-unstable";
    systems.url = "github:nix-systems/default";
    devenv.url = "github:cachix/devenv";
    devenv.inputs.nixpkgs.follows = "nixpkgs";
  };

  nixConfig = {
    extra-trusted-public-keys = "devenv.cachix.org-1:w1cLUi8dv3hnoSPGAuibQv+f9TZLr6cv/Hm9XgU50cw=";
    extra-substituters = "https://devenv.cachix.org";
  };

  outputs = { self, nixpkgs, devenv, systems, ... } @ inputs:
    let
      forEachSystem = nixpkgs.lib.genAttrs (import systems);
    in
    {
      packages = forEachSystem (system: {
        devenv-up = self.devShells.${system}.default.config.procfileScript;
      });

      devShells = forEachSystem
        (system:
          let
            pkgs = nixpkgs.legacyPackages.${system};
          in
          {
            default = devenv.lib.mkShell {
              inherit inputs pkgs;
              modules = [
                {
                  # languages
                  languages.python = {
                    enable = true;
                    poetry = {
                      enable = true;
                      activate.enable = true;
                      install.enable = true;
                    };
                  };
                  languages.javascript = {
                    enable = true;
                    bun.enable = true;
                  };
                  languages.typescript.enable = true;

                  # postgres database
                  services.postgres = {
                    enable = true;
                    listen_addresses = "127.0.0.1";
                    port = 5432;
                  };

                  # dev processes
                  processes = {
                    dev-backend.exec = ''
                      cd $PWD/backend
                      poetry install --no-root
                      poetry run uvicorn main:app --reload
                    '';
                    dev-frontend.exec = ''
                      cd $PWD/frontend
                      bun i
                      bun dev
                    '';
                  };

                  enterShell = ''
                    # Error handler
                    error_handler() {
                      echo "💥 An error occurred while setting up the environment"
                      echo "🔥 Please check the logs above for more information"
                      echo "🚨 Activate the devenv shell again after fixing the error"
                      exit 1
                    }
                    trap 'error_handler $?' ERR

                    echo "🔧 Setting up the environment..."

                    # Judge0 dockers
                    echo "🦈 Initializing judge0 docker containers..."
                    docker compose up -d

                    echo "✨ Development environment is ready"
                    echo "🚀 Run 'devenv up' to start the services"
                    echo ""
                  '';
                }
              ];
            };
          });
    };
}