Reading 4 controllers at once?

[colejd]

Hi there!

I'm trying to make something that reads multiple GC controllers and then outputs as one HID device over USB, for use with a rhythm game. Do you foresee any issues with this @NicoHood? I see the GamecubeMultiSingleplayer example, but I'm hoping to read 4 controllers instead of 2 and I'm wondering if there are any hidden issues I'll run into.

Thanks!

[Skuzee]

You should be fine. I've read 4 controllers before. You'll need to read them one at a time, of course, since the sending the controller command and receiving the data is real-time assembly. Each send/receive takes about 1/3 millisecond per controller.

You'll need to send the data over serial as bytes (don't send the buttons individually). Each controller has 3 status bytes and 8 data bytes. It adds up fast and filling you serial buffer often will halt the program. I would suggest you use a device that has hardware serial because you might find that software serial may not keep up with a high polling rate.

You might run into an issue when you have at least one controller unplugged. Since the library waits ~70ms for a controller response. By default when you call controller.read() if the device is not connected, it tries to initialize the controller and waits for a timeout. So if you have an unplugged controller it will hang your program and you might notice a stutter in your polling.

Check out this recent issue about that: #51
Removing/shortening the timeout or only initializing/counting the number of controllers on program start would fix this issue.

[colejd]

Thanks for the detailed info @Skuzee! I'm pretty new at this, so please bear with me, haha. Two follow-up questions:

1. Do you have any recommendations for a device with hardware serial that's up to the task? I have an Arduino Mega 2560, and an Arduino Leonardo is coming in the mail.
2. What do you mean by sending over serial in terms of how I interact with this library? I was planning to follow the implementation in the HID example if that's sufficient.

Thank you 🙏

[Skuzee]

Thanks for the detailed info @Skuzee! I'm pretty new at this, so please bear with me, haha. Two follow-up questions:

1. Do you have any recommendations for a device with hardware serial that's up to the task? I have an Arduino Leonardo coming in the mail.

2. What do you mean by sending over serial in terms of how I interact with this library? I was planning to follow the implementation in the [HID example](https://github.com/NicoHood/Nintendo/blob/e4130ff38039f125d94c5aee7469724dd2965a56/examples/Gamecube/Gamecube_USB_HID/Gamecube_USB_HID.ino) if that's sufficient.

Thank you 🙏

Leonardo is an ATMEGA32U4 so it has internal hardware serial; you're all set. I also use a "Sparkfun pro micro" for my projects.

There are some projects that send each controller button individually as a separate byte. Sending the buttons one at a time can be a problem because it will increase the data you need to send 8 fold. I'm unfamiliar with how the HID library works, but it's probably fine. Just warning of a potential pitfall.

// This send each button separately as a byte  
Serial.write(data.report.a)   
Serial.write(data.report.b)  
Serial.write(data.report.x)  
Serial.write(data.report.y)
// etc

vs

// This sends 8 buttons as a single byte  
Serial.write(data.report.buttons0)

[colejd]

Gotcha, thank you. I think that tracks with the code I've hastily cobbled together here (which is only intended to work with DK Bongos so it only really cares about buttons for now):

/// Multi-bongo setup cobbled together from a few .ino files:
/// https://github.com/NicoHood/Nintendo/blob/master/examples/Gamecube/GamecubeMultiSingleplayer/GamecubeMultiSingleplayer.ino
/// https://github.com/NicoHood/Nintendo/blob/master/examples/Gamecube/Gamecube_USB_HID/Gamecube_USB_HID.ino

#include "HID-Project.h"
#include "Nintendo.h"

// Define Gamecube controllers
CGamecubeController GamecubeController1(4);
CGamecubeController GamecubeController2(5);
CGamecubeController GamecubeController3(6);
CGamecubeController GamecubeController4(7);

void setup()
{
  // Start debug serial
  Serial.begin(115200);
  Serial.println(F("Start"));

  // Sends a clean report to the host. This is important on any Arduino type.
  Gamepad.begin();
}


void loop()
{
  bool anyPortConnected = false;

  for (uint8_t option = 0; option < 4; option++)
  {
    // Only read a single controller between each gamecube poll. 
    // [colejd note: do I need this?]
    switch (option) {
      case 0:
        {
          if (!GamecubeController1.read()) {
            Serial.println(F("Error reading Gamecube controller 1."));
            delay(1000);
            return;
          }
          else {
            anyPortConnected = true;
          }
        }
        break;
      case 1:
        {
          if (!GamecubeController2.read()) {
            Serial.println(F("Error reading Gamecube controller 2."));
            delay(1000);
            return;
          }
          else {
            anyPortConnected = true;
          }
        }
        break;
      case 2:
        {
          if (!GamecubeController3.read()) {
            Serial.println(F("Error reading Gamecube controller 3."));
            delay(1000);
            return;
          }
          else {
            anyPortConnected = true;
          }
        }
        break;
      case 3:
        {
          if (!GamecubeController4.read()) {
            Serial.println(F("Error reading Gamecube controller 4."));
            delay(1000);
            return;
          }
          else {
            anyPortConnected = true;
          }
        }
        break;
    }

    // Get the data of each controller
    auto r1 = GamecubeController1.getReport();
    auto r2 = GamecubeController2.getReport();
    auto r3 = GamecubeController3.getReport();
    auto r4 = GamecubeController4.getReport();

    // Merge all controller data into one
    Gamecube_Data_t d = defaultGamecubeData;
    d.report.buttons0 |= r1.buttons0 | r2.buttons0 | r3.buttons0 | r4.buttons0;
    d.report.buttons1 |= r1.buttons1 | r2.buttons1 | r3.buttons1 | r4.buttons1;

    sendGamecubeReport(d.report);
    // delay a bit to not overload PC
    delay(10);
  }
  if (!anyPortConnected) {
    // Center gamepad on disconnect
    Gamepad.end();
    delay(1000);
  }
}

void sendGamecubeReport(Gamecube_Report_t &gc_report)
{
  // The two control sticks
  Gamepad.xAxis((gc_report.xAxis - 0x80) << 8);
  Gamepad.yAxis(~(gc_report.yAxis - 0x80) << 8); // y stick needs to be inverted
  Gamepad.rxAxis((gc_report.cxAxis - 0x80) << 8);
  Gamepad.ryAxis((gc_report.cyAxis - 0x80) << 8);

  // you can merge L/R (PS3 controller uses this methode too)
  // or you can also seperate the triggers
  // for Windows calibration comment out the l/r buttons below
  // (because l/r triggers the wizard)
  //Gamepad.zAxis(abs(gc_report.left - gc_report.right) - 0x80);
  Gamepad.zAxis(gc_report.left - 0x80);
  Gamepad.rzAxis(gc_report.right - 0x80);

  // D-Pad:
  if (gc_report.dup && gc_report.dright) {
    Gamepad.dPad1(GAMEPAD_DPAD_UP_RIGHT);
  }
  else if (gc_report.dup && gc_report.dleft) {
    Gamepad.dPad1(GAMEPAD_DPAD_UP_LEFT);
  }
  else if (gc_report.ddown && gc_report.dright) {
    Gamepad.dPad1(GAMEPAD_DPAD_DOWN_RIGHT);
  }
  else if (gc_report.ddown && gc_report.dleft) {
    Gamepad.dPad1(GAMEPAD_DPAD_DOWN_LEFT);
  }
  else if (gc_report.dup) {
    Gamepad.dPad1(GAMEPAD_DPAD_UP);
  }
  else if (gc_report.ddown) {
    Gamepad.dPad1(GAMEPAD_DPAD_DOWN);
  }
  else if (gc_report.dright) {
    Gamepad.dPad1(GAMEPAD_DPAD_RIGHT);
  }
  else if (gc_report.dleft) {
    Gamepad.dPad1(GAMEPAD_DPAD_LEFT);
  }

  // 8 Gamecube buttons
  Gamepad.buttons(0x00UL | (gc_report.buttons0 & 0x1F) | ((gc_report.buttons1 & 0x70) << 1));

  // You could add a zero value correction here or a minimum
  // for the left/right shoulder triggers but the os can
  // (and should) calibrate controllers very well.

  // Write the information to the PC
  Gamepad.write();
}