Mario Kart Bike Controller

[WinstonPHz]

I have an interesting problem.
I think its a speed issue with my code so I might have to do the double Arduino Method.
The project: I am turning my bike into a Mario Kart DD controller, where pedaling hits the A button, and having small buttons close to the handle bars. The issue I am having is that the Arduino will work with the Mayflash GC Adaptor and Dolphin but not a GC console.
All the buttons work great for the GC Console, but the analog sticks do nothing.
I am using and Arduino Nano in hopes of getting it to be a small form factor to attach to my bike with relative ease.
I was able to read the data from a GC Controller and output it in a different line to the GC Console and still play the game so at this point its probably A speed issue. Any ideas on how to speed things up so I do not have to use 2?

#define pin_A   11
#define pin_B   2
#define pin_XU  3
#define pin_XD  4
#define pin_Z   5
#define pin_R   6
#define pin_CTR 7
#define pin_CSL 8
#define pin_S   9
#define An_X    A1
#define Dif     A2

// Define a Gamecube Controller and a Console
CGamecubeController GamecubeController1(7);
CGamecubeConsole GamecubeConsole1(8);
auto r1 = GamecubeController1.getReport();
int Dificulty = 1;
int cycles_on = 0;
int adj_factor = 1;

void setup()
{
  // Set up debug led
  setOrigin();
  // Start debug serial
  // Serial.begin(115200);
}

void pinSetup(){
  pinMode(pin_A, INPUT);
  pinMode(pin_B, INPUT_PULLUP);
  pinMode(pin_XU, INPUT_PULLUP);
  pinMode(pin_XD, INPUT_PULLUP);
  pinMode(pin_Z, INPUT_PULLUP);
  pinMode(pin_R, INPUT_PULLUP);
  pinMode(pin_S, INPUT_PULLUP);
  pinMode(An_X, INPUT);
  pinMode(Dif, INPUT);
  Dificulty = map(analogRead(Dif),0,1023,0,255);
}

void loop()
{
  // Changes the report
  ChangeReport();
  //print_gc_report(r1);
  GamecubeConsole1.write(r1);
}

void ChangeReport(){
  // Get the current report from the Controller
  if (!digitalRead(pin_B)){
    r1.b = 1;
  }else{
    r1.b = 0;
  }
  if (!digitalRead(pin_XU)){
    r1.x = 1;
    r1.yAxis = 230;
  }else if(!digitalRead(pin_XD)){
    r1.x = 1;
    r1.yAxis = 30;
  }else{
    r1.x = 0;
    r1.yAxis = 128;
  }
  if (!digitalRead(pin_Z)){
    r1.z = 1;
  }else{
    r1.z = 0;
  }
  if (!digitalRead(pin_R)){
    r1.r = 1;
  }else{
    r1.r = 0;
  }
  if (!digitalRead(pin_S)){
    r1.start = 1;
  }else{
    r1.start = 0;
  }
  if (!digitalRead(pin_A)){
    r1.a = 1;
  }else{
    r1.a = 0;
  }
  
//  if (!digitalRead(pin_A)){
//    cycles_on = Dificulty*adj_factor;
//  }
//  if (cycles_on > 0){
//    cycles_on -= 1;
//  }else{
//    cycles_on = 0;
//  }
  r1.xAxis = (uint8_t) map(analogRead(An_X),0,1023,30,225);
}

void setOrigin(){
  r1.dup = 0;
  r1.ddown = 0;
  r1.dright = 0;
  r1.dleft = 0;
  uint8_t value = 0x80;
  r1.xAxis = value;
  r1.yAxis = value;
  r1.cxAxis = value;
  r1.cyAxis = value;
  r1.left = value;
  r1.right = value; 
}

// Print out for debugging when things go awry
void print_gc_report(Gamecube_Report_t &gc_report)
{
  // Print device information
  // Prints the raw data from the controller

  Serial.print(F("S:"));
  Serial.print(gc_report.start);

  Serial.print(F(" Y:"));
  Serial.print(gc_report.y);

  Serial.print(F(" X:"));
  Serial.print(gc_report.x);
 
  Serial.print(F(" B:"));
  Serial.print(gc_report.b);

  Serial.print(F(" A:"));
  Serial.print(gc_report.a);

  Serial.print(F(" L:"));
  Serial.print(gc_report.l);
  Serial.print(F(" R:"));
  Serial.print(gc_report.r);
  Serial.print(F(" Z:"));
  Serial.print(gc_report.z);

  Serial.print(F("\txAxis:"));
  Serial.print(gc_report.xAxis);
  Serial.print(F(" yAxis:"));
  Serial.print(gc_report.yAxis);

  Serial.print(F(" L:"));
  Serial.print(gc_report.left);
  Serial.print(F(" R:"));
  Serial.print(gc_report.right);
  Serial.print(F(" Cycles on:"));
  Serial.print(cycles_on);
  Serial.println();
}```

[WinstonPHz]

Well, After looking at some other code I figured it out. The trick was to set the game cube data Like so:
Gamecube_Data_t r1 = defaultGamecubeData;
Instead of creating a controller then pre setting its values.
This made the GamecubeConsole.write(); Function to run a lot faster.

[NicoHood]

Also you can use direct port manipulation. digitalread is super slow for that usecase