-
Notifications
You must be signed in to change notification settings - Fork 0
/
moonInjection.ks
166 lines (133 loc) · 4.7 KB
/
moonInjection.ks
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
@LAZYGLOBAL OFF.
runOncePath("math/math").
runOncePath("basix").
function getInitialMoonInjectionManeuver {
parameter targetMoon.
// For moons with circular or close to circular orbits.
local transferDeltaV is calculateDeltaVToAltitude(targetMoon:obt:semiMajorAxis - targetMoon:body:radius, time:seconds + eta:periapsis).
local burnTime is getEstimatedBurnTime(transferDeltaV).
local transferSma is (targetMoon:obt:semiMajorAxis + orbit:semiMajorAxis) / 2.
local transferTime is getOrbitalPeriod(body, transferSma) / 2.
local ejectionAngle is getEjectionAngleToMoon(targetMoon, transferTime) + getAngularSize(targetMoon:radius, targetMoon:obt:semiMajorAxis).
local currentAnge is getOrbitAngleBetweenAt(targetMoon, ship, body, time:seconds).
if currentAnge < 0 {
set currentAnge to 360 + currentAnge.
}
if currentAnge < ejectionAngle {
set currentAnge to 360 + currentAnge.
}
local deltaAngle is currentAnge - ejectionAngle.
local ejectionEta is ship:obt:period / 360 * deltaAngle.
if ejectionEta < burnTime / 2 + 30 {
set ejectionEta to ship:obt:period + ejectionEta.
}
local correctionAngle is 360 / targetMoon:obt:period * ejectionEta.
local correctionEta is ship:obt:period / 360 * correctionAngle.
local m_time is time:seconds + ejectionEta + correctionEta.
local moonAltitudeAtIntersectionTime is targetMoon:body:AltitudeOf(positionAt(targetMoon, m_time + transferTime)).
set transferDeltaV to calculateDeltaVToAltitude(moonAltitudeAtIntersectionTime, m_time).
return node(m_time, 0, 0, transferDeltaV).
}
function improveInjectionManeuver {
parameter targetMoon.
parameter mnv.
parameter targetLevel.
parameter minP.
parameter maxP.
addManeuverToFlightPlan(mnv).
local precision is getManeuverPrecisionMetres().
if not mnv:orbit:hasNextPatch {
print "There is no next patch.".
}
else if mnv:orbit:nextPatch:body <> targetMoon {
print "Intersecting with wrong moon.".
}
else if abs(mnv:orbit:nextPatch:periapsis - targetLevel) < precision and abs(mnv:orbit:nextPatch:inclination) < 90 {
// Maneuver is good
}
else {
local minMag is getManeuverPrecisionDeltaV().
local bigNumber is targetMoon:soiRadius.
local originalP is mnv:prograde.
local hiP is originalP.
local lowP is originalP.
if mnv:orbit:nextPatch:periapsis > targetLevel {
set hiP to maxP.
}
else {
set lowP to minP.
}
local bestPrograde is mnv:prograde.
local bestPrecision is bigNumber.
print "Adjusting maneuver burn (deltaV - moon periapsis):".
until hiP - lowP < minMag {
local midP is (hiP + lowP) / 2.
set mnv:prograde to midP.
local level is bigNumber.
if mnv:orbit:hasNextPatch and mnv:orbit:nextPatch:body = targetMoon {
set level to mnv:orbit:nextPatch:periapsis.
if abs(mnv:orbit:nextPatch:inclination) > 90 {
set level to -level - 2 * targetMoon:radius.
}
}
else if midP > originalP {
// Bigger than original burn - past target moon.
set level to -bigNumber - 2 * targetMoon:radius.
}
print " " + round(midP, 4) + " - " + round(level, 3).
local currentPrecision is abs(level - targetLevel).
if (currentPrecision < bestPrecision)
{
set bestPrecision to currentPrecision.
set bestPrograde to midP.
}
if currentPrecision < precision {
set hiP to midP.
set lowP to midP.
}
else if level > targetLevel {
set lowP to midP.
}
else {
set hiP to midP.
}
}
set mnv:prograde to bestPrograde.
}
removeManeuverFromFlightPlan(mnv).
return mnv.
}
function waitForMoonOrbitPlaneToLaunch {
parameter targetMoon.
parameter bufferTime is 0.
if abs(targetMoon:obt:inclination) < 0.01 { // Same plane and orbit orientation
return 0.
}
else if abs(targetMoon:obt:inclination - 180) < 0.01 { // Same plane, opposite orientation
return 180.
}
print "Target orbit inclination: " + targetMoon:obt:inclination.
local inclination is abs(targetMoon:obt:inclination). // We are working with ascending node
local ascendLongitude is targetMoon:obt:longitudeOfAscendingNode - body:rotationAngle.
local ascendPeriodAngle is ascendLongitude - ship:longitude.
until ascendPeriodAngle >= 0 {
set ascendPeriodAngle to ascendPeriodAngle + 360.
}
until ascendPeriodAngle <= 360 {
set ascendPeriodAngle to ascendPeriodAngle - 360.
}
if ascendPeriodAngle > 180 {
set ascendPeriodAngle to ascendPeriodAngle - 180.
set inclination to -inclination.
}
if ascendPeriodAngle > 0 {
print "Waiting for target orbit plane".
local ascendEta is body:rotationPeriod * ascendPeriodAngle / 360 - bufferTime.
local ascendTime is time:seconds + ascendEta.
print "Launch Eta: " + ascendEta.
warpTo(ascendTime - 2).
wait until time:seconds >= ascendTime.
}
print "Target inclination: " + inclination.
return inclination.
}