build.gradle

plugins {
    id 'java'
    id 'maven-publish'
    id 'com.github.johnrengelman.shadow' version '7.0.0'
    id 'edu.sc.seis.launch4j' version '2.5.0'
}

group 'com.github.LabyStudio'
version '2.5.5'

compileJava {
    sourceCompatibility = '1.8'
    targetCompatibility = '1.8'
}

repositories {
    mavenCentral()
}

dependencies {
    implementation 'com.google.code.gson:gson:2.8.6'
}

sourceSets {
    main {
        java {
            srcDir 'src/core/java'
            srcDir 'src/demo/java'
        }

        resources {
            srcDir 'src/core/resources'
            srcDir 'src/demo/resources'
        }
    }
}

launch4j {
    mainClassName = 'Start'
    icon = "${projectDir}/icons/icon.ico"
    outfile = 'DesktopModules.exe'
    copyConfigurable = []
    jarTask = project.tasks.shadowJar
}

jar {
    manifest {
        attributes 'Main-Class': 'Start'
    }
}

java {
    withSourcesJar()
    withJavadocJar()
}

build {
    dependsOn shadowJar
}

publishing {
    repositories {
        maven {
            name = "GitHubPackages"
            url = uri("https://maven.pkg.github.com/LabyStudio/DesktopModules")
            credentials {
                username = project.findProperty("gpr.user") ?: System.getenv("USERNAME")
                password = project.findProperty("gpr.key") ?: System.getenv("TOKEN")
            }
        }
    }
    publications {
        gpr(MavenPublication) {
            from(components.java)
        }
    }
}